DocumentaçãoSeções
Referência MQL5Biblioteca PadrãoGráficos personalizadosCHistogramChart 

CHistogramChart

Classe para construir histogramas.

Descrição

Nesta classe são implementados todos os métodos de trabalho com construção de histogramas. Com sua ajuda é definida a largura das colunas e configurado o trabalho com grandes quantidades de dados. São incluídos os métodos para trabalhar com preenchimento de gradiente para as colunas dos histogramas, o que permite uma visualização clara dos dados.

ccanvas_histogramchart

O código da imagem acima está abaixo.

Declaração

   class CHistogramChart : public CChartCanvas

Cabeçalho

   #include <Canvas\Charts\HistogramChart.mqh>

Hierarquia de herança

  CCanvas

      CChartCanvas

          CHistogramChart

Métodos de classe

Método

Ação

Gradient

Define um sinalizador que indica se as colunas do histograma terão preenchimento de gradiente.

BarGap

Define o valor de recuo a partir da origem das coordenadas do histograma.

BarMinSize

Define a largura mínima das colunas do histograma.

BarBorder

Define um sinalizador que indica se necessário renderizar a borda de cada coluna.

Create

Método virtual que cria um recurso gráfico.                                      

SeriesAdd

Adiciona uma nova série de dados.

SeriesInsert

Insere a série de dados no gráfico.

SeriesUpdate

Atualiza a série de dados no gráfico.

SeriesDelete

Remove a série de dados no gráfico.

ValueUpdate

Atualiza o valor do elemento numa determinada série.

DrawData

Método virtual que desenha um histograma para uma determinada série.

DrawBar

Desenha uma coluna de histograma sob a forma de um retângulo preenchido.

GradientBrush

Cria um pincel para um preenchimento de gradiente.                                    

Métodos herdados da classe CCanvas

CreateBitmap, CreateBitmap, CreateBitmapLabel, CreateBitmapLabel, Attach, Attach, Destroy, ChartObjectName, ResourceName, Width, Height, Update, Resize, Erase, PixelGet, PixelSet, LineVertical, LineHorizontal, Line, Polyline, Polygon, Rectangle, Triangle, Circle, Ellipse, Arc, Arc, Arc, Pie, Pie, FillRectangle, FillTriangle, FillPolygon, FillCircle, FillEllipse, Fill, Fill, PixelSetAA, LineAA, PolylineAA, PolygonAA, TriangleAA, CircleAA, EllipseAA, LineWu, PolylineWu, PolygonWu, TriangleWu, CircleWu, EllipseWu, LineThickVertical, LineThickHorizontal, LineThick, PolylineThick, PolygonThick, PolylineSmooth, PolygonSmooth, FontSet, FontNameSet, FontSizeSet, FontFlagsSet, FontAngleSet, FontGet, FontNameGet, FontSizeGet, FontFlagsGet, FontAngleGet, TextOut, TextWidth, TextHeight, TextSize, GetDefaultColor, TransparentLevelSet, LoadFromFile, LineStyleGet, LineStyleSet

Métodos herdados da classe CChartCanvas

ColorBackground, ColorBackground, ColorBorder, ColorBorder, ColorText, ColorText, ColorGrid, ColorGrid, MaxData, MaxData, MaxDescrLen, MaxDescrLen, AllowedShowFlags, ShowFlags, ShowFlags, IsShowLegend, IsShowScaleLeft, IsShowScaleRight, IsShowScaleTop, IsShowScaleBottom, IsShowGrid, IsShowDescriptors, IsShowPercent, ShowLegend, ShowScaleLeft, ShowScaleRight, ShowScaleTop, ShowScaleBottom, ShowGrid, ShowDescriptors, ShowValue, ShowPercent, LegendAlignment, Accumulative, VScaleMin, VScaleMin, VScaleMax, VScaleMax, NumGrid, NumGrid, VScaleParams, DataOffset, DataOffset, DataTotal, DescriptorUpdate, ColorUpdate

Exemplo

//+------------------------------------------------------------------+
//|                                         HistogramChartSample.mq5 |
//|                   Copyright 2009-2017, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright   "2009-2017, MetaQuotes Software Corp."
#property link        "http://www.mql5.com"
#property description "Example of using histogram"
//---
#include <Canvas\Charts\HistogramChart.mqh>
//+------------------------------------------------------------------+
//| inputs                                                           |
//+------------------------------------------------------------------+
input bool Accumulative=true;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
int OnStart(void)
  {
   int k=100;
   double arr[10];
//--- create chart
   CHistogramChart chart;
   if(!chart.CreateBitmapLabel("SampleHistogramChart",10,10,600,450))
     {
      Print("Error creating histogram chart: ",GetLastError());
      return(-1);
     }
   if(Accumulative)
     {
      chart.Accumulative();
      chart.VScaleParams(20*k*10,-10*k*10,20);
     }
   else
      chart.VScaleParams(20*k,-10*k,20);
   chart.ShowValue(true);
   chart.ShowScaleTop(false);
   chart.ShowScaleBottom(false);
   chart.ShowScaleRight(false);
   chart.ShowLegend();
   for(int j=0;j<5;j++)
     {
      for(int i=0;i<10;i++)
        {
         k=-k;
         if(k>0)
            arr[i]=k*(i+10-j);
         else
            arr[i]=k*(i+10-j)/2;
        }
      chart.SeriesAdd(arr,"Item"+IntegerToString(j));
     }
//--- play with values
   while(!IsStopped())
     {
      int i=rand()%5;
      int j=rand()%10;
      k=rand()%3000-1000;
      chart.ValueUpdate(i,j,k);
      Sleep(200);
     }
//--- finish
   chart.Destroy();
   return(0);
  }