ObjectCreate

bool  ObjectCreate(
   long         chart_id,      // çizelge tanımlayıcısı
   string       name,          // nesne ismi
   ENUM_OBJECT  type,          // nesne tipi
   sub_window   nwin,          // pencere indisi
   datetime     time1,         // ilk tutturma noktasının zaman koordinatı
   double       price1,        // ilk tutturma noktasının fiyat koordinatı
  ... 
   datetime     timeN=0,       // N-inci tutturma noktasının zaman koordinatı
   double       priceN=0,      // N-inci tutturma noktasının fiyat koordinatı
  ... 
   datetime     time30=0,      // 30-uncu tutturma noktasının zaman koordinatı
   double       price30=0      // 30-uncu tutturma noktasının fiyat koordinatı
   );

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property script_show_inputs
 
#define   OBJ_NAME   "TestObjectCreate"            // nesne adı
#define   OBJ_X      40                            // nesnenin X koordinatı
#define   OBJ_Y      40                            // nesnenin Y koordinatı
#define   OBJ_WIDTH  300                           // nesne genişliği
#define   OBJ_HEIGHT 200                           // nesne yüksekliği
#define   WND        0                             // grafik alt penceresi
 
input ENUM_OBJECT InpObjectToCreate =  OBJ_VLINE;  /* Object type to create   */ // grafik üzerinde çizilecek nesne türü
 
struct SPoint                                      // çapa noktası yapısı
  {
   double   price;
   datetime time;
  };
 
SPoint   ExtAnchorPoints[5];                       // grafiksel nesnenin çapa noktalarının dizisi
long     ExtChartID;                               // kimlik
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- mevcut çubuk sayısını kontrol et
   int bars=Bars(_Symbol,_Period);
   if(bars<7)
     {
      PrintFormat("The number of available bars (%d) is not enough to create some graphical objects",bars);
      return;
     }
//--- mevcut grafik kimliği
   ExtChartID=ChartID();
 
//--- önceden oluşturulmuş nesneyi sil
   ObjectDelete(ExtChartID, OBJ_NAME);
 
//--- beş çapa noktası belirle (zaman/fiyat)
   SetAnchorPointsData();
 
//--- çapa noktalarının fiyatı/zamanı
   datetime tm0=ExtAnchorPoints[0].time;
   double   pr0=ExtAnchorPoints[0].price;
   datetime tm1=ExtAnchorPoints[1].time;
   double   pr1=ExtAnchorPoints[1].price;
   datetime tm2=ExtAnchorPoints[2].time;
   double   pr2=ExtAnchorPoints[2].price;
   datetime tm3=ExtAnchorPoints[3].time;
   double   pr3=ExtAnchorPoints[3].price;
   datetime tm4=ExtAnchorPoints[4].time;
   double   pr4=ExtAnchorPoints[4].price;
   
//--- nesne başarıyla oluşturulduysa, kalan parametrelerini ayarla:
   if(ObjectCreate(ExtChartID,OBJ_NAME,InpObjectToCreate,WND,tm0,pr0,tm1,pr1,tm2,pr2,tm3,pr3,tm4,pr4))
     {
      //--- nesneyi seçilebilir hale getir ve seç
      ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTABLE, true);
      ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTED, true);
      
      //--- grafik koordinatlarına göre konumlandırılmış nesneler için
      ENUM_OBJECT obj=InpObjectToCreate;
      if(obj==OBJ_LABEL || obj==OBJ_BUTTON || obj==OBJ_CHART || obj==OBJ_BITMAP_LABEL || obj==OBJ_EDIT || obj==OBJ_RECTANGLE_LABEL)
        {
         //--- nesne koordinatlarını ayarla
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XDISTANCE,OBJ_X);
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YDISTANCE,OBJ_Y);
         //--- nesne boyutunu ayarla
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XSIZE,OBJ_WIDTH); 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YSIZE,OBJ_HEIGHT);
        }
      //--- değişiklikleri göstermek için grafiği güncelle
      ChartRedraw(ExtChartID);
     }
  }
//+------------------------------------------------------------------+
//| Nesne çapa noktaları dizisini doldur                             |
//+------------------------------------------------------------------+
void SetAnchorPointsData(void)
  {
//--- sol çapa noktası çubuğu (indeksi 0)
   int bar_first=(int)ChartGetInteger(ExtChartID,CHART_FIRST_VISIBLE_BAR)-1;
   
//--- ilk çapa noktasının (indeksi 0) fiyatını/zamanını ayarla
   ExtAnchorPoints[0].price=iOpen(_Symbol,_Period,bar_first);
   ExtAnchorPoints[0].time =iTime(_Symbol,_Period,bar_first);
   
//--- 1 - 3 indeksli çapa noktalarının fiyatını/zamanını ayarla
   int distance=(int)round(bar_first/4);  // çapa noktaları arasındaki çubuk cinsinden mesafe
   for(int i=1;i<4;i++)
     {
      ExtAnchorPoints[i].price=iOpen(_Symbol,_Period,bar_first-i*distance);
      ExtAnchorPoints[i].time =iTime(_Symbol,_Period,bar_first-i*distance);
     }
   
//--- son çapa noktasının (indeksi 4) fiyatını/zamanını ayarla
   ExtAnchorPoints[4].price=iOpen(_Symbol,_Period,1);
   ExtAnchorPoints[4].time =iTime(_Symbol,_Period,1);
  }