//--- açıklama
#property description "Script, \"Andrews Dirgeni\" grafiksel nesnesini çizer."
#property description "Tutturma (çapa) noktası koordinatları, çizelge penceresi"
#property description "boyutunun yüzdesi şeklinde ayarlanır."
//--- betiğin çalıştırılması sırasında giriş parametreleri penceresini göster
#property script_show_inputs
//--- betiğin giriş parametreleri
input string InpName="Pitchfork"; // Dirgenin (üçlü çizginin) ismi
input int InpDate1=14; // 1-inci noktanın tarihi, %
input int InpPrice1=40; // 1-inci noktanın fiyatı, %
input int InpDate2=18; // 2-inci noktanın tarihi, %
input int InpPrice2=50; // 2-inci noktanın fiyatı, %
input int InpDate3=18; // 3-üncü noktanın tarihi, %
input int InpPrice3=30; // 3-üncü noktanın fiyatı, %
input color InpColor=clrRed; // Dirgen rengi
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // Dirgenin stili
input int InpWidth=1; // Dirgen çizgilerinin kalınlığı
input bool InpBack=false; // Arkaplan nesnesi
input bool InpSelection=true; // Taşıma için vurgula
input bool InpRayLeft=false; // Dirgenin sola doğru sürekliliği
input bool InpRayRight=false; // Dirgenin sağa doğru sürekliliği
input bool InpHidden=true; // Nesne listesinde gizle
input long InpZOrder=0; // Fare tıklaması için öncelik
//+------------------------------------------------------------------+
//| Andrews Dirgenini verilen koordinatlarda oluştur |
//+------------------------------------------------------------------+
bool PitchforkCreate(const long chart_ID=0, // çizelge kimliği
const string name="Pitchfork", // dirgen ismi
const int sub_window=0, // alt pencere indisi
datetime time1=0, // ilk nokta zamanı
double price1=0, // ilk nokta fiyatı
datetime time2=0, // ikinci nokta zamanı
double price2=0, // ikinci nokta fiyatı
datetime time3=0, // üçüncü nokta zamanı
double price3=0, // üçüncü nokta fiyatı
const color clr=clrRed, // dirgen çizgilerinin rengi
const ENUM_LINE_STYLE style=STYLE_SOLID, // dirgen çizgilerinin stili
const int width=1, // dirgen çizgilerinin kalınlığı
const bool back=false, // arka-plan çizimi
const bool selection=true, // taşıma için vurgula
const bool ray_left=false, // dirgenin sola doğru sürekliliği
const bool ray_right=false, // dirgenin sağa doğru sürekliliği
const bool hidden=true, // nesne listesinde gizle
const long z_order=0) // fare tıklaması için öncelik
{
//--- ayarlanmamışsa, tutturma noktası koordinatlarını ayarla
ChangeChannelEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- hata değerini sıfırla
ResetLastError();
//--- Andrews Dirgenini verilen koordinatlarda oluştur
if(!ObjectCreate(chart_ID,name,OBJ_PITCHFORK,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": \"Andrews Dirgeni\" oluşturulamadı! Hata kodu = ",GetLastError());
return(false);
}
//--- rengi ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- çizgi stilini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- çizgilerin genişliğini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- ön-planda (false) veya arkaplanda (true) göster
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- taşıma için vurgulama modunu etkinleştir (true) veya devre dışı bırak (false)
//--- ObjectCreate fonksiyonu ile bir nesne oluşturulurken,
//--- nesne ön tanımlı olarak vurgulanamaz veya taşınamaz. Bu yöntemin içinde, parametre için ön tanımlı olarak 'true' değerinin
//--- seçilmesi, nesnenin vurgulanmasını ve taşınmasını mümkün kılar
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- dirgenin sola doğru sürekli gösterimi modunu etkinleştir (true) veya devre dışı bırak (false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- dirgenin sağa doğru sürekli gösterimi modunu etkinleştir (true) veya devre dışı bırak (false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- nesne listesinde grafiksel nesnenin adını sakla (true) veya göster (false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- çizelge üzerinde fare tıklaması olayının alınması için özellik ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Andrews Çatalının seviyelerini ve parametrelerini ayarla |
//+------------------------------------------------------------------+
bool PitchforkLevelsSet(int levels, // seviye çizgilerinin sayısı
double &values[], // seviye çizgilerinin değeri
color &colors[], // seviye çizgilerinin rengi
ENUM_LINE_STYLE &styles[], // seviye çizgilerinin stili
int &widths[], // seviye çizgilerinin kalınlığı
const long chart_ID=0, // çizelge tanımlayıcı
const string name="Pitchfork") // dirgen ismi
{
//--- dizi büyüklüklerini ayarla
if(levels!=ArraySize(colors) || levels!=ArraySize(styles) ||
levels!=ArraySize(widths) || levels!=ArraySize(widths))
{
Print(__FUNCTION__,": dizi uzunluğu seviyelerin sayısıyla örtüşmüyor, hata!");
return(false);
}
//--- seviyelerin sayısını ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELS,levels);
//--- seviyelerin özeliklerini döngü içinde ayarla
for(int i=0;i<levels;i++)
{
//--- seviye değeri
ObjectSetDouble(chart_ID,name,OBJPROP_LEVELVALUE,i,values[i]);
//--- seviye rengi
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELCOLOR,i,colors[i]);
//--- seviye stili
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELSTYLE,i,styles[i]);
//--- seviye genişliği
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELWIDTH,i,widths[i]);
//--- seviye açıklaması
ObjectSetString(chart_ID,name,OBJPROP_LEVELTEXT,i,DoubleToString(100*values[i],1));
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Adrews Dirgeninin tutturma noktasını taşı |
//+------------------------------------------------------------------+
bool PitchforkPointChange(const long chart_ID=0, // çizelge kimliği
const string name="Pitchfork", // kanal ismi
const int point_index=0, // tutturma noktası indisi
datetime time=0, // tutturma noktası zaman koordinatı
double price=0) // tutturma noktası fiyat koordinatı
{
//--- noktanın pozisyonu belirlenmemişse, noktayı Bid (alış) fiyatı olan mevcut çubuğa taşı
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- hata değerini sıfırla
ResetLastError();
//--- tutturma noktasını taşı
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": tutturma noktasının taşınması başarısız! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Andrews Dirgenini sil |
//+------------------------------------------------------------------+
bool PitchforkDelete(const long chart_ID=0, // çizelge kimliği
const string name="Pitchfork") // kanal ismi
{
//--- hata değerini sıfırla
ResetLastError();
//--- kanalı sil
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": \"Andrews Dirgeni\" silinemedi! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+----------------------------------------------------------------------+
//| Andrews Dirgeninin tutturma noktası değerlerini kontrol et ve |
//| boş olanlar için varsayılan değerleri ayarla |
//+----------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,double &price1,datetime &time2,
double &price2,datetime &time3,double &price3)
{
//--- ikinci (sağ üst) noktanın zamanı ayarlanmamışsa, mevcut çubuk üstünde olacak
if(!time2)
time2=TimeCurrent();
//--- İkinci noktanın fiyatı ayarlanmamışsa, Bid (alış) değerini alacak
if(!price2)
price2=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- İlk noktanın (sol) zamanı ayarlanmamışsa, ikinciden 9 çubuk sonra olacak
if(!time1)
{
//--- son 10 çubuğun açılış zamanını alacak bir dizi
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- ilk noktayı ikinciden 9 çubuk sonraya ayarla
time1=temp[0];
}
//--- ilk noktanın fiyatı ayarlanmamışsa, ikincinin 200 puan altına yerleştir
if(!price1)
price1=price2-200*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- üçüncü noktanın zamanı ayarlanmamışsa, ikinci noktaya karşılık gelecek
if(!time3)
time3=time2;
//--- üçüncü noktanın fiyatı ayarlanmamışsa, ilkinin 200 puan aşağısına konumla
if(!price3)
price3=price1-200*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- giriş parametrelerinin doğruluğunu kontrol et
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Hata! Hatalı giriş parametresi değerleri!");
return;
}
//--- çizelge penceresindeki görünür çubukların sayısı
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- fiyat dizisi büyüklüğü
int accuracy=1000;
//--- nesnenin tutturma noktası konumunu değiştirmek için kullanılacak
//--- tarih ve fiyat değerlerinin saklanacağı diziler
datetime date[];
double price[];
//--- bellek tahsisi
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- tarih dizisini doldur
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Zaman değerlerinin kopyalanması başarısız oldu! Hata kodu = ",GetLastError());
return;
}
//--- fiyat dizisini değerlerle doldur
//--- çizelgedeki en yüksek ve en düşük değerleri bul
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- fiyatlar için bir değişim birimini tanımla ve diziyi doldur
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- Andrews Dirgenini çizmek için noktaları tanımla
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- dirgeni oluştur
if(!PitchforkCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- çizelgeyi yenile ve 1 saniye bekle
ChartRedraw();
Sleep(1000);
//--- şimdi, dirgenin tutturma noktasını taşı
//--- döngü sayacı
int v_steps=accuracy/10;
//--- ilk tutturma noktasını taşı
for(int i=0;i<v_steps;i++)
{
//--- bir sonraki değeri kullan
if(p1>1)
p1-=1;
//--- tutturma noktasını taşı
if(!PitchforkPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- döngü sayacı
int h_steps=bars/8;
//--- üçüncü tutturma noktasını taşı
for(int i=0;i<h_steps;i++)
{
//--- bir sonraki değeri kullan
if(d3<bars-1)
d3+=1;
//--- tutturma noktasını taşı
if(!PitchforkPointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
//--- çizelgeyi yenile
ChartRedraw();
// 0.05 saniyelik gecikme
Sleep(50);
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- döngü sayacı
v_steps=accuracy/10;
//--- ikinci tutturma noktasını taşı
for(int i=0;i<v_steps;i++)
{
//--- bir sonraki değeri kullan
if(p2>1)
p2-=1;
//--- tutturma noktasını taşı
if(!PitchforkPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- dirgeni çizelgeden sil
PitchforkDelete(0,InpName);
ChartRedraw();
//--- 1 saniyelik gecikme
Sleep(1000);
//---
}
|
