ObjectCreate

bool  ObjectCreate(
  long        chart_id,      // チャート識別子
  string      name,          // オブジェクト名
  ENUM_OBJECT type,          // オブジェクトの型
  sub_window   nwin,          // ウィンドウインデックス
  datetime    time1,        // 1 番目のアンカーポイントの時間
  double      price1,        // 1 番目のアンカーポイントの価格
  ...
  datetime    timeN=0,      // N 番目のアンカーポイントの時間
  double      priceN=0,      // N 番目のアンカーポイントの価格
  ...
  datetime    time30=0,      // 30番目のアンカーポイントの時間
  double      price30=0      // 30番目のアンカーポイントの価格
  );

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link     "https://www.mql5.com"
#property version   "1.00"
 
#property script_show_inputs
 
#define   OBJ_NAME   "TestObjectCreate"           // オブジェクト名
#define   OBJ_X     40                           // オブジェクトのX座標
#define   OBJ_Y     40                           // オブジェクトのY座標
#define   OBJ_WIDTH 300                           // オブジェクトの幅
#define   OBJ_HEIGHT 200                           // オブジェクトの高さ
#define   WND       0                             // チャートサブウィンドウ
 
input ENUM_OBJECT InpObjectToCreate = OBJ_VLINE;  /* Object type to create   */ // チャートに描画するオブジェクトの型
 
struct SPoint                                     // アンカーポイントの構造体
 {
  double   price;
  datetime time;
 };
 
SPoint   ExtAnchorPoints[5];                       // グラフィックオブジェクトのアンカーポイントの配列
long     ExtChartID;                               // ID
 
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                              |
//+------------------------------------------------------------------+
void OnStart()
 {
//--- 利用可能なバーの数を確認する
  int bars=Bars(_Symbol,_Period);
  if(bars<7)
    {
    PrintFormat("The number of available bars (%d) is not enough to create some graphical objects",bars);
    return;
    }
//--- 現在のチャートID
  ExtChartID=ChartID();
 
//--- 以前に作成されたオブジェクトを削除する
  ObjectDelete(ExtChartID, OBJ_NAME);
 
//--- 5つのアンカーポイントを設定する（時刻/価格）
  SetAnchorPointsData();
 
//--- アンカーポイントの価格/時刻
  datetime tm0=ExtAnchorPoints[0].time;
  double   pr0=ExtAnchorPoints[0].price;
  datetime tm1=ExtAnchorPoints[1].time;
  double   pr1=ExtAnchorPoints[1].price;
  datetime tm2=ExtAnchorPoints[2].time;
  double   pr2=ExtAnchorPoints[2].price;
  datetime tm3=ExtAnchorPoints[3].time;
  double   pr3=ExtAnchorPoints[3].price;
  datetime tm4=ExtAnchorPoints[4].time;
  double   pr4=ExtAnchorPoints[4].price;
 
//--- オブジェクトが正常に作成された場合、残りのパラメータを設定する
  if(ObjectCreate(ExtChartID,OBJ_NAME,InpObjectToCreate,WND,tm0,pr0,tm1,pr1,tm2,pr2,tm3,pr3,tm4,pr4))
    {
    //--- オブジェクトを選択可能にして選択する
    ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTABLE, true);
    ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTED, true);
     
    //--- チャート座標で配置されたオブジェクト用
    ENUM_OBJECT obj=InpObjectToCreate;
    if(obj==OBJ_LABEL || obj==OBJ_BUTTON || obj==OBJ_CHART || obj==OBJ_BITMAP_LABEL || obj==OBJ_EDIT || obj==OBJ_RECTANGLE_LABEL)
       {
        //--- オブジェクト座標を設定する
        ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XDISTANCE,OBJ_X);
        ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YDISTANCE,OBJ_Y);
        //--- オブジェクトサイズを設定する
        ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XSIZE,OBJ_WIDTH);
        ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YSIZE,OBJ_HEIGHT);
       }
    //--- チャートを更新して変更を表示する
    ChartRedraw(ExtChartID);
    }
 }
//+------------------------------------------------------------------+
//| オブジェクトアンカーポイントの配列を埋める                                     |
//+------------------------------------------------------------------+
void SetAnchorPointsData(void)
 {
//--- 左側のアンカーポイントバー（インデックス0）
  int bar_first=(int)ChartGetInteger(ExtChartID,CHART_FIRST_VISIBLE_BAR)-1;
 
//--- 最初のアンカーポイント（インデックス0）の価格/時刻を設定する
  ExtAnchorPoints[0].price=iOpen(_Symbol,_Period,bar_first);
  ExtAnchorPoints[0].time =iTime(_Symbol,_Period,bar_first);
 
//--- インデックス1~3のアンカーポイントの価格/時刻を設定する
  int distance=(int)round(bar_first/4); // アンカーポイント間の距離（バー単位）
  for(int i=1;i<4;i++)
    {
    ExtAnchorPoints[i].price=iOpen(_Symbol,_Period,bar_first-i*distance);
    ExtAnchorPoints[i].time =iTime(_Symbol,_Period,bar_first-i*distance);
    }
 
//--- 最後のアンカーポイント（インデックス4）の価格/時刻を設定する
  ExtAnchorPoints[4].price=iOpen(_Symbol,_Period,1);
  ExtAnchorPoints[4].time =iTime(_Symbol,_Period,1);
 }