#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define OBJ_NAME "TestObjectGetDouble" // nesne adı
#define WND 0 // grafik alt penceresi
#define EXT " (%$)" // fiyat değerlerini seviyelerde görüntülemek için biçim dizgesi
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- mevcut grafik kimliği, grafik sembolü ve sembol basamağı
long chart_id= ChartID();
string symbol = ChartSymbol(chart_id);
int digits = (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
//--- görünür grafiğin en yüksek ve en düşük fiyatlarında “Fibonacci seviyeleri” grafiksel nesnesi oluştur
if(!CreateFibo(chart_id))
return;
//--- nesne seviyesi sayısı
int total=(int)ObjectGetInteger(chart_id, OBJ_NAME, OBJPROP_LEVELS);
double value =0;
double price0=0;
double price1=0;
//--- çapa noktası fiyatları
price0=ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_PRICE, 0);
price1=ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_PRICE, 1);
//--- nesne seviyelerinin sayısına göre bir döngü içinde
for(int i=0; i<total; i++)
{
//--- mevcut seviye için ayarlanan değeri al
ResetLastError();
if(!ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_LEVELVALUE, i, value))
{
Print("ObjectGetDouble() failed. Error ", GetLastError());
return;
}
//--- nesnenin en yüksek ve en düşük bağlanma fiyatlarını ve fiyat değeri cinsinden aralarındaki mesafeyi al
double max=fmax(price0, price1);
double min=fmin(price0, price1);
double range=max-min;
//--- nesnenin mevcut seviyesi için fiyat değerini hesapla
double level_price=min+range*value;
//--- seviye için rengi, grafiğin hem koyu hem de açık arka planlarında görülebilecek şekilde ayarla
ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_LEVELCOLOR, i, clrRed);
//--- fiyat değerinin seviye değeriyle birlikte görüntülenmesi için seviye için bir biçim dizgesi ayarla
string level_text=ObjectGetString(chart_id, OBJ_NAME, OBJPROP_LEVELTEXT, i);
if(StringFind(level_text, EXT)<0)
{
level_text+=EXT;
ObjectSetString(chart_id, OBJ_NAME, OBJPROP_LEVELTEXT, i, level_text);
}
//--- seviye numarasını ve verilerini - seviye değeri ve fiyatı - günlükte yazdır
PrintFormat("Fibo level [%d] value: %.3f, price: %.*f", i, value, digits, level_price);
}
/*
sonuç:
Fibo level [0] value: 0.000, price: 0.61989
Fibo level [1] value: 0.236, price: 0.62533
Fibo level [2] value: 0.382, price: 0.62869
Fibo level [3] value: 0.500, price: 0.63140
Fibo level [4] value: 0.618, price: 0.63412
Fibo level [5] value: 1.000, price: 0.64292
Fibo level [6] value: 1.618, price: 0.65715
Fibo level [7] value: 2.618, price: 0.68018
Fibo level [8] value: 4.236, price: 0.71745
*/
}
//+------------------------------------------------------------------+
//| Belirtilen grafikte Fibo seviyeleri grafiksel nesnesi oluştur |
//+------------------------------------------------------------------+
bool CreateFibo(const long chart_id)
{
//--- Fibo seviyelerini grafikte görünen en yüksek fiyat değerinden en düşük fiyat değerine kadar çiz ve bunları al
double price_high=0, price_low=0;
datetime time_high =0, time_low =0;
if(!GetChartExtremums(chart_id, price_high, price_low, time_high, time_low))
return(false);
//--- bulunan fiyat/zaman koordinatları üzerinde Fibo seviyeleri nesnesini oluştur
if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_FIBO, WND, time_high, price_high, time_low, price_low))
{
PrintFormat("%s: ObjectCreate() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- her şey yolunda - grafiği güncelle ve ‘true’ geri döndür
ChartRedraw();
return(true);
}
//+------------------------------------------------------------------+
//| Grafikteki maksimum, minimum fiyatları ve zamanlarını geri döndür|
//+------------------------------------------------------------------+
bool GetChartExtremums(const long chart_id, double &price_high, double &price_low, datetime &time_high, datetime &time_low)
{
//--- değişkenleri sıfırla
price_high=price_low=0;
time_high =time_low =0;
//--- grafik sembolü
string symbol = ChartSymbol(chart_id);
//--- ilk görünür çubuğun numarasına ve grafikteki çubuk sayısına göre kopyalanan zaman serisi aralığının başlangıcını hesapla
int first = (int)ChartGetInteger(chart_id, CHART_FIRST_VISIBLE_BAR);
int count = (int)ChartGetInteger(chart_id, CHART_VISIBLE_BARS);
int start = first+1-count;
//--- zaman serilerinin kopyalanacağı diziler
double array_high[];
double array_low[];
datetime array_time[];
int index;
//--- üç zaman serisini ‘count’ miktarında ve 'start'tan başlayarak dizilere kopyala
ResetLastError();
if(CopySeries(symbol, PERIOD_CURRENT, start, count, COPY_RATES_TIME|COPY_RATES_HIGH|COPY_RATES_LOW, array_time, array_high, array_low)!=count)
{
PrintFormat("%s: CopySeries() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- array_high dizisinde en yüksek fiyat indeksini ara
index=ArrayMaximum(array_high);
if(index<0)
{
PrintFormat("%s: ArrayMaximum() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- görünür grafikteki en yüksek fiyatı ve bu fiyatın bulunduğu çubuğun zaman değerini hatırla
price_high=array_high[index];
time_high=array_time[index];
//--- array_low dizisinde en düşük fiyat indeksini ara
index=ArrayMinimum(array_low);
if(index<0)
{
PrintFormat("%s: ArrayMinimum() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- görünür grafikteki en düşük fiyatı ve bu fiyatın bulunduğu çubuğun zaman değerini hatırla
price_low=array_low[index];
time_low=array_time[index];
//--- her şey yolunda
return(true);
}
|