ObjectCreate

bool  ObjectCreate(
   long         chart_id,      // 图表标识符
   string       name,          // 物件名称
   ENUM_OBJECT  type,          // 物件类型
   int          sub_window,    // 窗口索引
   datetime     time1,         // 第一定位点的时间
   double       price1,        // 第一定位点的价格
   ...
   datetime     timeN=0,       // 第N个定位点的时间
   double       priceN=0,      // 
   ...
   datetime     time30=0,      // 第30个定位点的时间
   double       price30=0      // 第30个定位点的价格
   );

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property script_show_inputs
 
#define   OBJ_NAME   "TestObjectCreate"            // 对象名称
#define   OBJ_X      40                            // 对象 X 坐标
#define   OBJ_Y      40                            // 对象 Y 坐标
#define   OBJ_WIDTH  300                           // 对象宽度
#define   OBJ_HEIGHT 200                           // 对象高度
#define   WND        0                             // 图表子窗口
 
input ENUM_OBJECT InpObjectToCreate =  OBJ_VLINE;  /* Object type to create   */ // 绘制在图表上的对象类型
 
struct SPoint                                      // 锚点结构
  {
   double   price;
   datetime time;
  };
 
SPoint   ExtAnchorPoints[5];                       // 图形对象锚点的数组
long     ExtChartID;                               // ID 
 
//+------------------------------------------------------------------+
//| 脚本程序起始函数                                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 检查可用柱形的数量
   int bars=Bars(_Symbol,_Period);
   if(bars<7)
     {
      PrintFormat("The number of available bars (%d) is not enough to create some graphical objects",bars);
      return;
     }
//--- 当前图表 ID
   ExtChartID=ChartID();
 
//--- 删除之前创建的对象
   ObjectDelete(ExtChartID, OBJ_NAME);
 
//--- 设置五个锚点 (时间/价格)
   SetAnchorPointsData();
 
//--- 锚点的时间/价格
   datetime tm0=ExtAnchorPoints[0].time;
   double   pr0=ExtAnchorPoints[0].price;
   datetime tm1=ExtAnchorPoints[1].time;
   double   pr1=ExtAnchorPoints[1].price;
   datetime tm2=ExtAnchorPoints[2].time;
   double   pr2=ExtAnchorPoints[2].price;
   datetime tm3=ExtAnchorPoints[3].time;
   double   pr3=ExtAnchorPoints[3].price;
   datetime tm4=ExtAnchorPoints[4].time;
   double   pr4=ExtAnchorPoints[4].price;
   
//--- 如果对象已成功创建, 设置它的其余参数:
   if(ObjectCreate(ExtChartID,OBJ_NAME,InpObjectToCreate,WND,tm0,pr0,tm1,pr1,tm2,pr2,tm3,pr3,tm4,pr4))
     {
      //--- 使对象可选择并选择它
      ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTABLE, true);
      ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTED, true);
      
      //---用于按图表坐标定位的对象
      ENUM_OBJECT obj=InpObjectToCreate;
      if(obj==OBJ_LABEL || obj==OBJ_BUTTON || obj==OBJ_CHART || obj==OBJ_BITMAP_LABEL || obj==OBJ_EDIT || obj==OBJ_RECTANGLE_LABEL)
        {
         //--- 设置对象坐标 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XDISTANCE,OBJ_X);
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YDISTANCE,OBJ_Y);
         //--- 设置对象大小 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XSIZE,OBJ_WIDTH); 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YSIZE,OBJ_HEIGHT);
        }
      //--- 更新图表以显示变化
      ChartRedraw(ExtChartID);
     }
  }
//+------------------------------------------------------------------+
//| 填充对象锚点的数组                                                  |
//+------------------------------------------------------------------+
void SetAnchorPointsData(void)
  {
//--- 左侧锚点柱形 (索引为0)
   int bar_first=(int)ChartGetInteger(ExtChartID,CHART_FIRST_VISIBLE_BAR)-1;
   
//--- 设置第一个锚点(索引为0)的价格/时间
   ExtAnchorPoints[0].price=iOpen(_Symbol,_Period,bar_first);
   ExtAnchorPoints[0].time =iTime(_Symbol,_Period,bar_first);
   
//--- 设置索引从1至3的锚点的价格/时间
   int distance=(int)round(bar_first/4);  // 锚点之间的距离柱数
   for(int i=1;i<4;i++)
     {
      ExtAnchorPoints[i].price=iOpen(_Symbol,_Period,bar_first-i*distance);
      ExtAnchorPoints[i].time =iTime(_Symbol,_Period,bar_first-i*distance);
     }
   
//--- 设置最后一个锚点 (索引为4) 的价格/时间
   ExtAnchorPoints[4].price=iOpen(_Symbol,_Period,1);
   ExtAnchorPoints[4].time =iTime(_Symbol,_Period,1);
  }