DokümantasyonBölümler
MQL5 ReferansıNesne FonksiyonlarıObjectsTotal 

ObjectsTotal

Belirtilen çizelgenin belirtilen alt-penceresinde, belirli tipteki nesnelerin sayısına dönüş yapar.

int  ObjectsTotal(
   long  chart_id,           // çizelge tanımlayıcısı
   int   sub_window=-1,      // pencere indisi
   int   type=-1             // nesne tipi
   );

Parametreler

chart_id

[in]  Çizelge tanımlayıcısı. 0, mevcut çizelge anlamına gelir.

sub_window=-1

[in]  Çizelge alt penceresinin indisi. 0 ana çizelge penceresidir, -1 ise ana pencere de dahil olmak üzere tüm alt pencereler anlamına gelir.

type=-1

[in]  Nesne tipi. Bu değer, ENUM_OBJECT değerlerinden biri olabilir. -1 tüm tipler anlamına gelir.

Dönüş değeri

Nesnelerin sayısı.

Not

Fonksiyon, eşzamanlı bir çağrı kullanır; bu, fonksiyonun çağrı öncesinde bu grafik için yerine getirilmiş tüm komutların yürütülmesini beklediği anlamına gelir, bu nedenle bu fonksiyon çok zaman alıcı olabilir. Bu özellik, bir grafikte çok sayıda nesneyle çalışırken dikkate alınmalıdır.

 

Örnek:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- grafik kimliği
   long chart_id=ChartID();
   
//--- ana pencere ile birlikte grafik alt pencerelerinin sayısını al
   long wnd=0;
   ResetLastError();
   if(!ChartGetInteger(chart_id, CHART_WINDOWS_TOTAL, 0, wnd))
     {
      Print("ChartGetInteger() failed. Error ", GetLastError());
      return;
     }
   
//--- her bir grafik alt penceresi için grafiksel nesnelerin sayısını al ve günlükte görüntüle
   for(int i=0; i<(int)wnd; i++)
     {
      int objects=ObjectsTotal(chart_id, i);
      string wnd_head=(i==0 ? "The main chart window" : StringFormat("The window with index %d of the chart", i));
      PrintFormat("%s contains %d graphic objects", wnd_head, objects);
     }
   /*
   iki alt pencereli ana pencere için sonuç
   (ana pencere işlem etiketleri içeriyor
   ve alt pencerelerde iki grafiksel nesne bulunuyor):
   The main chart window contains 656 graphic objects
   The window with index 1 of the chart contains 2 graphic objects 
   The window with index 2 of the chart contains 2 graphic objects
   */
  }