//--- açıklama
#property description "Script, \"Elliott Düzeltme Dalgası\" grafiksel nesnesini çizer."
#property description "Tutturma noktasının koordinatları, çizelge boyutunun"
#property description "yüzdesi olarak ayarlanır."
//--- betiğin çalıştırılması sırasında giriş parametreleri penceresini göster
#property script_show_inputs
//--- betiğin giriş parametreleri
input string InpName="ElliotWave3"; // Nesne ismi
input int InpDate1=10; // 1-inci noktanın tarihi, %
input int InpPrice1=90; // 1-inci noktanın fiyatı, %
input int InpDate2=30; // 2-inci noktanın tarihi, %
input int InpPrice2=10; // 2-inci noktanın fiyatı, %
input int InpDate3=50; // 3-üncü noktanın tarihi, %
input int InpPrice3=40; // 3-üncü noktanın fiyatı, %
input ENUM_ELLIOT_WAVE_DEGREE InpDegree=ELLIOTT_MINOR; // Seviye
input bool InpDrawLines=true; // Çizgilerin görüntülenmesi
input color InpColor=clrRed; // Çizgilerin rengi
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Çizgilerin stili
input int InpWidth=2; // Çizgilerin kalınlığı
input bool InpBack=false; // Arka-plan nesnesi
input bool InpSelection=true; // Taşıma için vurgula
input bool InpHidden=true; // Nesne listesinde gizle
input long InpZOrder=0; // Fare tıklaması için öncelik
//+------------------------------------------------------------------+
//| Elliott Düzeltme Dalgasını verilen koordinatlarda oluştur |
//+------------------------------------------------------------------+
bool ElliotWave3Create(const long chart_ID=0, // çizelge kimliği
const string name="ElliotWave3", // dalga ismi
const int sub_window=0, // alt-pencere indisi
datetime time1=0, // ilk nokta zamanı
double price1=0, // ilk nokta fiyatı
datetime time2=0, // ikinci nokta zamanı
double price2=0, // ikinci nokta fiyatı
datetime time3=0, // üçüncü nokta zamanı
double price3=0, // üçüncü nokta fiyatı
const ENUM_ELLIOT_WAVE_DEGREE degree=ELLIOTT_MINUETTE, // derece
const bool draw_lines=true, // çizgilerin görüntülenmesi
const color clr=clrRed, // nesne rengi
const ENUM_LINE_STYLE style=STYLE_SOLID, // çizgilerin stili
const int width=1, // çizgilerin kalınlığı
const bool back=false, // arka-plan nesnesi
const bool selection=true, // taşıma için vurgula
const bool hidden=true, // nesne listesinde gizle
const long z_order=0) // fare tıklaması için öncelik
{
//--- ayarlanmamışsa, tutturma noktası koordinatlarını ayarla
ChangeElliotWave3EmptyPoints(time1,price1,time2,price2,time3,price3);
//--- hata değerini sıfırla
ResetLastError();
//--- Verilen koordinatlarda "Elliott Düzeltme Dalgasını" oluştur
if(!ObjectCreate(chart_ID,name,OBJ_ELLIOTWAVE3,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": \"Elliott Düzeltme Dalgası\" oluşturulamadı! Hata kodu = ",GetLastError());
return(false);
}
//--- dereceyi (dalga boyunu) ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_DEGREE,degree);
//--- çizgilerin görüntülenmesi modunu etkinleştir (true) veya devre dışı bırak (false)
ObjectSetInteger(chart_ID,name,OBJPROP_DRAWLINES,draw_lines);
//--- nesnenin rengini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- çizgi stilini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- çizgilerin genişliğini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- ön-planda (false) veya arkaplanda (true) göster
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- taşıma için vurgulama modunu etkinleştir (true) veya devre dışı bırak (false)
//--- ObjectCreate fonksiyonu ile bir nesne oluşturulurken,
//--- nesne ön tanımlı olarak vurgulanamaz veya taşınamaz. Bu yöntemin içinde, parametre için ön tanımlı olarak 'true' değerinin
//--- seçilmesi, nesnenin vurgulanmasını ve taşınmasını mümkün kılar
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nesne listesinde grafiksel nesnenin adını sakla (true) veya göster (false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- çizelge üzerinde fare tıklaması olayının alınması için özellik ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Elliott Düzeltme Dalgasının tutturma noktasını taşı |
//+------------------------------------------------------------------+
bool ElliotWave3PointChange(const long chart_ID=0, // çizelge kimliği
const string name="ElliotWave3", // nesne ismi
const int point_index=0, // tutturma (çapa) noktası ismi
datetime time=0, // tutturma noktası zaman koordinatı
double price=0) // tutturma noktası fiyat koordinatı
{
//--- noktanın pozisyonu belirlenmemişse, noktayı Bid (alış) fiyatı olan mevcut çubuğa taşı
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- hata değerini sıfırla
ResetLastError();
//--- tutturma noktasını taşı
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": tutturma noktasının taşınması başarısız! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Elliott Düzeltme Dalgasını sil |
//+------------------------------------------------------------------+
bool ElliotWave3Delete(const long chart_ID=0, // çizelge kimliği
const string name="ElliotWave3") // nesne ismi
{
//--- hata değerini sıfırla
ResetLastError();
//--- nesneyi sil
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": \"Elliott Düzeltme Dalgası\" nesnesi silinemedi! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Elliott Düzeltme Dalgasının tutturma noktalarının değerlerini |
//| kontrol et ve boş olanlar için varsayılan değerleri ayarla |
//+------------------------------------------------------------------+
void ChangeElliotWave3EmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3)
{
//--- son 10 çubuğun açılış zamanlarını almak için bir dizi
datetime temp[];
ArrayResize(temp,10);
//--- veriyi al
CopyTime(Symbol(),Period(),TimeCurrent(),10,temp);
//--- çizelge üzerindeki bir noktanın değerini al
double point=SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- ilk noktanın zamanı ayarlanmamışsa, son çubuktan 9 çubuk solda olacak
if(!time1)
time1=temp[0];
//--- ilk noktanın fiyatı ayarlanmamışsa mevcut Bid değerini alacak
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- ikinci noktanın zamanı ayarlanmamışsa, son çubuktan 5 çubuk solda olacak
if(!time2)
time2=temp[4];
//--- ikinci noktanın fiyatı ayarlanmamışsa, ilkinin 300 puan aşağısına konumla
if(!price2)
price2=price1-300*point;
//--- üçüncü noktanın zamanı ayarlanmamışsa, son çubuktan 1 çubuk solda olacak
if(!time3)
time3=temp[8];
//--- üçüncü noktanın fiyatı ayarlanmamışsa, ilkinin 200 puan aşağısına konumla
if(!price3)
price3=price1-200*point;
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- giriş parametrelerinin doğruluğunu kontrol et
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Hata! Hatalı giriş parametresi değerleri!");
return;
}
//--- çizelge penceresindeki görünür çubukların sayısı
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- fiyat dizisi büyüklüğü
int accuracy=1000;
//--- nesnenin tutturma noktası konumunu değiştirmek için kullanılacak
//--- tarih ve fiyat değerlerinin saklanacağı diziler
datetime date[];
double price[];
//--- bellek tahsisi
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- tarih dizisini doldur
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Zaman değerlerinin kopyalanması başarısız oldu! Hata kodu = ",GetLastError());
return;
}
//--- fiyat dizisini değerlerle doldur
//--- çizelgedeki en yüksek ve en düşük değerleri bul
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- fiyatlar için bir değişim birimini tanımla ve diziyi doldur
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- Elliott Düzeltme Dalgalarını çizmek için noktaları ayarla
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- Elliott Düzeltme Dalgalarını oluştur
if(!ElliotWave3Create(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpDegree,InpDrawLines,InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- çizelgeyi yenile ve 1 saniye bekle
ChartRedraw();
Sleep(1000);
//--- şimdi, tutturma noktalarını taşı
//--- döngü sayacı
int v_steps=accuracy/5;
//--- üçüncü tutturma noktasını taşı
for(int i=0;i<v_steps;i++)
{
//--- bir sonraki değeri kullan
if(p3<accuracy-1)
p3+=1;
//--- tutturma noktasını taşı
if(!ElliotWave3PointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- döngü sayacı
v_steps=accuracy*4/5;
//--- ilk ve ikinci tutturma noktalarını taşı
for(int i=0;i<v_steps;i++)
{
//--- şu değerleri kullan
if(p1>1)
p1-=1;
if(p2<accuracy-1)
p2+=1;
//--- noktaları kaydır
if(!ElliotWave3PointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!ElliotWave3PointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- nesneyi çizelgeden sil
ElliotWave3Delete(0,InpName);
ChartRedraw();
//--- 1 saniyelik gecikme
Sleep(1000);
//---
}
|