ObjectCreate

bool  ObjectCreate(
   long         chart_id,      // Identifikator des Charts
   string       name,          // Objektname
   ENUM_OBJECT  type,          // Objekttyp
   int          sub_window,    // Index des Fensters
   datetime     time1,         // Zeit des ersten Ankerpunktes 
   double       price1,        // Preis des ersten Ankerpunktes 
   ...
   datetime     timeN=0,       // Zeit des N-Ankerpunktes
   double       priceN=0,      // Preis des N-Ankerpunktes
   ...
   datetime     time30=0,      // Zeit des 30. Ankerpunktes
   double       price30=0      // Preis des 30. Ankerpunktes
   );

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property script_show_inputs
 
#define   OBJ_NAME   "TestObjectCreate"            // Objekt-Name
#define   OBJ_X      40                            // Objekt X-Koordinate
#define   OBJ_Y      40                            // Objekt Y-Koordinate
#define   OBJ_WIDTH  300                           // Objekt-Breite
#define   OBJ_HEIGHT 200                           // Objekt-Höhe
#define   WND        0                             // Unterfenster des Charts
 
input ENUM_OBJECT InpObjectToCreate =  OBJ_VLINE;  /* zu erstellender Objekttyp   */ // Objekttyp, der im Chart dargestellt werden soll
 
struct SPoint                                      // Struktur des Ankerpunkts
  {
   double   price;
   datetime time;
  };
 
SPoint   ExtAnchorPoints[5];                       // Array von Ankerpunkten grafischer Objekte
long     ExtChartID;                               // ID 
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Anzahl der verfügbaren Balken überprüfen
   int bars=Bars(_Symbol,_Period);
   if(bars<7)
     {
      PrintFormat("The number of available bars (%d) is not enough to create some graphical objects",bars);
      return;
     }
//--- aktuelle Chart-ID
   ExtChartID=ChartID();
 
//--- zuvor erstelltes Objekt löschen
   ObjectDelete(ExtChartID, OBJ_NAME);
 
//--- fünf Ankerpunkte (Zeit/Preis) festlegen
   SetAnchorPointsData();
 
//--- Preis/Zeit der Ankerpunkte
   datetime tm0=ExtAnchorPoints[0].time;
   double   pr0=ExtAnchorPoints[0].price;
   datetime tm1=ExtAnchorPoints[1].time;
   double   pr1=ExtAnchorPoints[1].price;
   datetime tm2=ExtAnchorPoints[2].time;
   double   pr2=ExtAnchorPoints[2].price;
   datetime tm3=ExtAnchorPoints[3].time;
   double   pr3=ExtAnchorPoints[3].price;
   datetime tm4=ExtAnchorPoints[4].time;
   double   pr4=ExtAnchorPoints[4].price;
   
//--- Wenn das Objekt erfolgreich erstellt wurde, lege die restlichen Parameter fest:
   if(ObjectCreate(ExtChartID,OBJ_NAME,InpObjectToCreate,WND,tm0,pr0,tm1,pr1,tm2,pr2,tm3,pr3,tm4,pr4))
     {
 //--- Objekt auswählbar machen und auswählen
      ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTABLE, true);
      ObjectSetInteger(ExtChartID, OBJ_NAME, OBJPROP_SELECTED, true);
      
 //--- für Objekte, die anhand von Chart-Koordinaten positioniert sind
      ENUM_OBJECT obj=InpObjectToCreate;
      if(obj==OBJ_LABEL || obj==OBJ_BUTTON || obj==OBJ_CHART || obj==OBJ_BITMAP_LABEL || obj==OBJ_EDIT || obj==OBJ_RECTANGLE_LABEL)
        {
 //--- Objektkoordinaten festlegen 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XDISTANCE,OBJ_X);
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YDISTANCE,OBJ_Y);
         //--- Objektgröße festlegen 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_XSIZE,OBJ_WIDTH); 
         ObjectSetInteger(ExtChartID,OBJ_NAME,OBJPROP_YSIZE,OBJ_HEIGHT);
        }
      //--- Aktualisieren des Charts, um die Änderungen anzuzeigen
      ChartRedraw(ExtChartID);
     }
  }
//+------------------------------------------------------------------+
//| Füllen des Arrays der Objektankerpunkte                          |
//+------------------------------------------------------------------+
void SetAnchorPointsData(void)
  {
//--- linker Ankerpunktbalken (mit Index 0)
   int bar_first=(int)ChartGetInteger(ExtChartID,CHART_FIRST_VISIBLE_BAR)-1;
   
//--- Festlegen von Preis/Zeit des ersten Ankerpunkts (mit Index 0)
   ExtAnchorPoints[0].price=iOpen(_Symbol,_Period,bar_first);
   ExtAnchorPoints[0].time =iTime(_Symbol,_Period,bar_first);
   
//--- Festlegen von Preis/Zeit der Ankerpunkte mit den Indizes 1 - 3
   int distance=(int)round(bar_first/4);  // Abstand in Balken zwischen den Ankerpunkten
   for(int i=1;i<4;i++)
     {
      ExtAnchorPoints[i].price=iOpen(_Symbol,_Period,bar_first-i*distance);
      ExtAnchorPoints[i].time =iTime(_Symbol,_Period,bar_first-i*distance);
     }
   
//--- Festlegen von Preis/Zeit des letzten Ankerpunkts (mit Index 4)
   ExtAnchorPoints[4].price=iOpen(_Symbol,_Period,1);
   ExtAnchorPoints[4].time =iTime(_Symbol,_Period,1);
  }