//--- açıklama
#property description "Script \"Gann Izgarası\" grafiksel nesnesini oluşturur."
#property description "Tutturma (çapa) noktası koordinatları, çizelge penceresi""
#property description "boyutunun yüzdesi şeklinde ayarlanır."
//--- betiğin çalıştırılması sırasında giriş parametreleri penceresini göster
#property script_show_inputs
//--- betiğin giriş parametreleri
input string InpName="GannGrid"; // Izgaranın ismi
input int InpDate1=15; // 1-inci noktanın tarihi, %
input int InpPrice1=25; // 1-inci noktanın fiyatı, %
input int InpDate2=35; // 2-inci noktanın tarihi, %
input double InpScale=3.0; // Ölçek
input bool InpDirection=false; // Trend yönü
input color InpColor=clrRed; // Izgara rengi
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Izgara çizgilerinin stili
input int InpWidth=1; // Yelpaze çizgilerinin kalınlığı
input bool InpBack=false; // Arkaplan nesnesi
input bool InpSelection=true; // Taşımak için vurgula
input bool InpHidden=true; // Nesne listesinde gizle
input long InpZOrder=0; // Fare tıklaması için öncelik
//+------------------------------------------------------------------+
//| Gan Izgarası Oluştur |
//+------------------------------------------------------------------+
bool GannGridCreate(const long chart_ID=0, // çizelge kimliği
const string name="GannGrid", // ızgara ismi
const int sub_window=0, // alt pencere indisi
datetime time1=0, // ilk nokta zamanı
double price1=0, // ilk nokta fiyatı
datetime time2=0, // ikinci nokta zamanı
const double scale=1.0, // ölçek
const bool direction=true, // trend yönü
const color clr=clrRed, // ızgara rengi
const ENUM_LINE_STYLE style=STYLE_SOLID, // ızgara çizgilerinin stili
const int width=1, // ızgara çizgilerinin kalınlığı
const bool back=false, // arka planda
const bool selection=true, // taşıma için vurgula
const bool hidden=true, // nesneyi listede gizle
const long z_order=0) // fare tıklaması için öncelik
{
//--- ayarlanmamışsa, tutturma noktası koordinatlarını ayarla
ChangeGannGridEmptyPoints(time1,price1,time2);
//--- hata değerini sıfırla
ResetLastError();
//--- Gann Izgarasını verilen koordinatlara göre oluştur
if(!ObjectCreate(chart_ID,name,OBJ_GANNGRID,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": \"Gann Izgarası\" oluşturulamadı! Hata kodu = ",GetLastError());
return(false);
}
//--- ölçeği değiştir (çubuk başına düşen pip olarak)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- Gann Yelpazesinin trend yönünü değiştir (true - azalan, false - artan)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- ızgara rengini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- ızgara çizgilerinin stilini ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- ızgara çizgilerinin kalınlığını ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- ön-planda (false) veya arkaplanda (true) göster
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- taşıma için vurgulama modunu etkinleştir (true) veya devre dışı bırak (false)
//--- ObjectCreate fonksiyonu ile bir nesne oluşturulurken,
//--- nesne ön tanımlı olarak vurgulanamaz veya taşınamaz. Bu yöntemin içinde, parametre için ön tanımlı olarak 'true' değerinin
//--- seçilmesi, nesnenin vurgulanmasını ve taşınmasını mümkün kılar
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nesne listesinde grafiksel nesnenin adını sakla (true) veya göster (false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- çizelge üzerinde fare tıklaması olayının alınması için özellik ayarla
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Gann Izgarası tutturma noktasını taşı |
//+------------------------------------------------------------------+
bool GannGridPointChange(const long chart_ID=0, // çizelge kimliği
const string name="GannGrid", // ızgara ismi
const int point_index=0, // tutturma noktası indisi
datetime time=0, // çapa noktası zaman koordinatı
double price=0) // çapa noktası fiyat koordinatı
{
//--- noktanın pozisyonu belirlenmemişse, noktayı Bid (alış) fiyatı olan mevcut çubuğa taşı
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- hata değerini sıfırla
ResetLastError();
//--- ızgara tutturma noktasını taşı
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": tutturma noktasının taşınması başarısız! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Gann Izgarasının ölçeğini değiştir |
//+------------------------------------------------------------------+
bool GannGridScaleChange(const long chart_ID=0, // çizelge kimliği
const string name="GannGrid", // ızgara ismi
const double scale=1.0) // ölçek
{
//--- hata değerini sıfırla
ResetLastError();
//--- ölçeği değiştir (çubuk başına düşen pip olarak)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": ölçek değiştirilemedi! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Gann Izgarasının trend yönünü değiştir |
//+------------------------------------------------------------------+
bool GannGridDirectionChange(const long chart_ID=0, // çizelge kimliği
const string name="GannGrid", // çizelge ismi
const bool direction=true) // trend yönü
{
//--- hata değerini sıfırla
ResetLastError();
//--- Gann Izgarasının trend yönünü değiştir
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
": trend yönü değiştirilemedi! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Fonksiyon Gann Izgarasını çizelgeden siler |
//+------------------------------------------------------------------+
bool GannGridDelete(const long chart_ID=0, // çizelge kimliği
const string name="GannGrid") // ızgara ismi
{
//--- hata değerini sıfırla
ResetLastError();
//--- Gann Izgarasını sil
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": \"Gann Izgarasının\" silinmesi başarısız oldu! Hata kodu = ",GetLastError());
return(false);
}
//--- başarılı çalıştırma
return(true);
}
//+------------------------------------------------------------------+
//| Gann Izgarasının tutturma noktası değerlerini kontrol et ve |
//| boş olanlar için varsayılan değerleri kullan |
//+------------------------------------------------------------------+
void ChangeGannGridEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- ikinci noktanın zamanı ayarlanmamışsa, mevcut çubuğun üstünde olacak
if(!time2)
time2=TimeCurrent();
//--- ilk noktanın zamanı ayarlanmamışsa, ikinci noktanın 9 çubuk solunda olacak
if(!time1)
{
//--- son 10 çubuğun açılış zamanını alacak bir dizi
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- ilk noktayı ikinciden 9 çubuk sonraya ayarla
time1=temp[0];
}
//--- ilk noktanın fiyatı ayarlanmamışsa mevcut Bid değerini alacak
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- giriş parametrelerinin doğruluğunu kontrol et
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Hata! Hatalı giriş parametresi değerleri!");
return;
}
//--- çizelge penceresindeki görünür çubukların sayısı
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- fiyat dizisi büyüklüğü
int accuracy=1000;
//--- nesnenin tutturma noktası konumunu değiştirmek için kullanılacak
//--- tarih ve fiyat değerlerinin saklanacağı diziler
datetime date[];
double price[];
//--- bellek tahsisi
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- tarih dizisini doldur
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Zaman değerlerinin kopyalanması başarısız oldu! Hata kodu = ",GetLastError());
return;
}
//--- fiyat dizisini değerlerle doldur
//--- çizelgedeki en yüksek ve en düşük değerleri bul
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- fiyatlar için bir değişim birimini tanımla ve diziyi doldur
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- Gann Izgarasının çizileceği noktaları tanımla
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- Gann Izgarasını oluştur
if(!GannGridCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- çizelgeyi yenile ve 1 saniye bekle
ChartRedraw();
Sleep(1000);
//--- şimdi, ızgaranın tutturma noktasını taşı
//--- döngü sayacı
int v_steps=accuracy/4;
//--- ilk tutturma noktasını dikey olarak taşı
for(int i=0;i<v_steps;i++)
{
//--- bir sonraki değeri kullan
if(p1<accuracy-1)
p1+=1;
if(!GannGridPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- döngü sayacı
int h_steps=bars/4;
//--- ikinci tutturma noktasını yatay olarak taşı
for(int i=0;i<h_steps;i++)
{
//--- bir sonraki değeri kullan
if(d2<bars-1)
d2+=1;
if(!GannGridPointChange(0,InpName,1,date[d2],0))
return;
//--- script işlemi devre dışı bırakıldı mı kontrol et
if(IsStopped())
return;
//--- çizelgeyi yenile
ChartRedraw();
// 0.05 saniyelik gecikme
Sleep(50);
}
//--- 1 saniyelik gecikme
Sleep(1000);
//--- ızgaranın trend yönünü azalan olarak ayarla
GannGridDirectionChange(0,InpName,true);
//--- çizelgeyi yeniden çiz
ChartRedraw();
//--- 1 saniyelik gecikme
Sleep(1000);
//--- ızgarayı çizelgeden siler
GannGridDelete(0,InpName);
ChartRedraw();
//--- 1 saniyelik gecikme
Sleep(1000);
//---
}
|
