#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define COORD_X 200
#define COORD_Y 100
#define OBJ_NAME "TestTextGetSizeBitmapLabel"
#define RES_NAME "TestTextGetSizeResource"
#define COLOR_NULL 0x00FFFFFF
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- mevcut grafik kimliği
long chart_id= ChartID();
string font_names[] ={"Arial", "Tahoma", "Calibri"};
uint flags_array[]={0, FONT_ITALIC, FONT_UNDERLINE, FONT_STRIKEOUT};
uint fw_array[]={FW_DONTCARE, FW_THIN, FW_EXTRALIGHT, FW_ULTRALIGHT, FW_LIGHT,
FW_NORMAL, FW_REGULAR, FW_MEDIUM, FW_SEMIBOLD, FW_DEMIBOLD,
FW_BOLD, FW_EXTRABOLD, FW_ULTRABOLD, FW_HEAVY, FW_BLACK};
//--- fiyat grafiğinin herhangi bir özelliğinin çizilmesini devre dışı bırak
ChartSetInteger(chart_id, CHART_SHOW, false);
//--- grafiksel kaynağın parametrelerini bildir
uint rc_width =(int)ChartGetInteger(chart_id, CHART_WIDTH_IN_PIXELS);
uint rc_height=(int)ChartGetInteger(chart_id, CHART_HEIGHT_IN_PIXELS);
uint rc_data[];
uint rc_size=rc_width*rc_height;
//--- metin çıktısı için bir grafiksel kaynak oluştur
if(!CreateResource(chart_id, rc_data, rc_width, rc_height))
return;
//--- yazı tipi adları arasında döngü
for(int i=0; i<(int)font_names.Size(); i++)
{
//--- yazı tipi bayrakları arasında döngü
for(int j=0; j<(int)flags_array.Size(); j++)
{
//--- diziden elde edilen yazı tipi ve stil bayrağı ile metin çiz
DrawText(font_names[i], flags_array[j], rc_data, rc_width, rc_height);
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- tüm metinlerin çıktısını farklı yazı tipi boyutları ve stilleriyle yaptıktan sonra,
//--- farklı yazı tipi genişliği bayraklarıyla metin göster
for(int i=0; i<(int)fw_array.Size(); i++)
{
//--- genişlik bayrakları ile metin görüntülemek için yazı tipi boyutunu ve adını ayarla
string font_name="Tahoma";
int size=-140;
TextSetFont(font_name, size, fw_array[i]);
//--- çizilecek bir metin dizgesi oluştur, bunu kaynak piksel dizisine çıktı olarak ver ve kaynağı güncelle
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagWidthDescription(fw_array[i]), size, size/-10);
TextOut(text, COORD_X, COORD_Y, ANCHOR_LEFT_UPPER, rc_data, rc_width, rc_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, rc_data, rc_width, rc_height, true);
//--- bir saniye bekle
Sleep(1000);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- beş saniye bekle, ardından kaynağı serbest bırak ve grafiksel nesneyi sil
Sleep(5000);
ResourceFree(RES_NAME);
ObjectDelete(chart_id, OBJ_NAME);
//--- fiyat grafiğinin herhangi bir özelliğinin çizilmesine izin verir
ChartSetInteger(chart_id, CHART_SHOW, true);
ChartRedraw(chart_id);
/*
Metin mesajları, komut dosyasının yürütülmesinin sonucu olarak grafikte görüntülenir.
Metinler farklı yazı tiplerinin yanı sıra stil ve genişlik bayraklarına sahiptir.
*/
}
//+------------------------------------------------------------------+
//| Belirtilen yazı tipi ve bayraklarla |
//| farklı boyutlarda beş metin dizgesi görüntüle |
//+------------------------------------------------------------------+
void DrawText(const string font_name, uint flags, uint &pixels_array[], uint res_width, uint res_height)
{
//--- farklı yazı tipi boyutlarına sahip beş metin dizgesi çıktıla
for(int i=0; i<5; i++)
{
//--- yazı tipi boyutunu hesapla ve çizim yöntemlerini kullanarak metin çıktısı için yazı tipini ayarla
int size=-140+10*i;
TextSetFont(font_name, size, flags);
//--- çizilecek bir metin dizgesi oluştur, bunu kaynak piksel dizisine çıktı olarak ver ve kaynağı güncelle
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagDescription(flags), size, size/-10);
TextOut(text, COORD_X, COORD_Y+22*i, ANCHOR_LEFT_UPPER, pixels_array, res_width, res_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, pixels_array, res_width, res_height, true);
//--- biraz bekle
Sleep(800);
}
}
//+------------------------------------------------------------------+
//| Yazı tipi stili bayraklarının açıklamasını geri döndür |
//+------------------------------------------------------------------+
string FlagDescription(const uint flag)
{
switch(flag)
{
case FONT_ITALIC : return(" Italic");
case FONT_UNDERLINE : return(" Underline");
case FONT_STRIKEOUT : return(" Strikeout");
}
return("");
}
//+------------------------------------------------------------------+
//| Yazı tipi genişliği bayraklarının açıklamasını geri döndür |
//+------------------------------------------------------------------+
string FlagWidthDescription(const uint flag)
{
switch(flag)
{
case FW_DONTCARE : return(" Dontcare");
case FW_THIN : return(" Thin");
case FW_EXTRALIGHT: return(" Extralight");
case FW_ULTRALIGHT: return(" Ultralight");
case FW_LIGHT : return(" Light");
case FW_NORMAL : return(" Normal");
case FW_REGULAR : return(" Regular");
case FW_MEDIUM : return(" Medium");
case FW_SEMIBOLD : return(" Semibold");
case FW_DEMIBOLD : return(" Demibold");
case FW_BOLD : return(" Bold");
case FW_EXTRABOLD : return(" Extrabold");
case FW_ULTRABOLD : return(" Ultrabold");
case FW_HEAVY : return(" Heavy");
case FW_BLACK : return(" Black");
}
return("");
}
//+------------------------------------------------------------------+
//| Grafiğin tamamı için bir grafiksel kaynak oluştur |
//+------------------------------------------------------------------+
bool CreateResource(const long chart_id, uint &pixel_data[], const uint width, const uint height)
{
//--- piksel dizisinin büyüklüğünü ayarla
ResetLastError();
uint size=width*height;
if(ArrayResize(pixel_data, size)!=size)
{
PrintFormat("%s: ArrayResize() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- piksel dizisini saydam renkle doldur ve buna dayalı bir grafiksel kaynak oluştur
ArrayInitialize(pixel_data, COLOR_NULL);
if(!ResourceCreate(RES_NAME, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE))
{
PrintFormat("%s: ResourceCreate() failed. Error code ",__FUNCTION__, GetLastError());
return(false);
}
//--- grafiğin sol üst köşesinin koordinatlarında bir "bitmap etiket" nesnesi oluştur
if(!ObjectCreate(0, OBJ_NAME, OBJ_BITMAP_LABEL, 0, 0, 0))
{
PrintFormat("%s: ObjectCreate() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- oluşturulan bitmap nesnesinin genişlik ve yüksekliğini grafiksel kaynağın genişlik ve yüksekliğine eşit olarak ayarla.
//--- nesne çapa noktasını merkezine ayarla.
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_XSIZE, width))
{
PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_YSIZE, height))
{
PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- bitmap nesnesi için önceden oluşturulmuş grafiksel kaynağı bir görüntü dosyası olarak belirt
//--- bu durumda, kullanılan grafiksel kaynağın adını belirtmek için adının önüne “::” eklememiz gerekir
if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_BMPFILE, "::"+RES_NAME))
{
PrintFormat("%s: ObjectSetString() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- her şey yolunda
return(true);
}
//+------------------------------------------------------------------+
//| Grafiksel kaynak verilerini güncelle |
//+------------------------------------------------------------------+
void Update(const string res_name, const uint &pixel_data[], const uint width, const uint height, const bool redraw)
{
//--- sıfır boyut iletilirse ayrıl
if(width==0 || height==0)
return;
//--- kaynak verilerini güncelle ve grafiği yeniden çiz
if(ResourceCreate(res_name, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
|