#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define OBJ_NAME "TestObjectGetDouble" // Objekt-Name
#define WND 0 // Unterfenster des Charts
#define EXT " (%$)" // Formatierungszeichenfolge für die Anzeige von Preiswerten auf Ebenen
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion |
//+------------------------------------------------------------------+
void OnStart()
{
//--- aktuelle Chart-ID, Chart-Symbol und Symbol-Dezimalstelle
long chart_id= ChartID();
string symbol = ChartSymbol(chart_id);
int digits = (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
//--- Erstellen des grafischen Objekts "Fibonacci-Levels" zu den Höchst- und Tiefstpreisen des sichtbaren Charts
if(!CreateFibo(chart_id))
return;
//--- Anzahl der Objektebenen
int total=(int)ObjectGetInteger(chart_id, OBJ_NAME, OBJPROP_LEVELS);
double value =0;
double price0=0;
double price1=0;
//--- Ankerpunktpreise
price0=ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_PRICE, 0);
price1=ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_PRICE, 1);
//--- in einer Schleife über die Anzahl der Objektebenen
for(int i=0; i<total; i++)
{
//--- den für die aktuelle Ebene festgelegten Wert abrufen
ResetLastError();
if(!ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_LEVELVALUE, i, value))
{
Print("ObjectGetDouble() failed. Error ", GetLastError());
return;
}
//--- Ermitteln von Höchst- und Tiefstpreis der Objektbindung und den Abstand zwischen ihnen im Preiswert
double max=fmax(price0, price1);
double min=fmin(price0, price1);
double range=max-min;
//--- Farbe für die Ebene festlegen, damit sie sowohl auf dunklen als auch auf hellen Hintergründen des Charts sichtbar ist
double level_price=min+range*value;
//--- Festlegen einer Formatzeichenfolge für das Niveau, sodass dessen Preiswert zusammen mit dem Niveauwert angezeigt wird
ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_LEVELCOLOR, i, clrRed);
//--- einen Formatstring für das Niveau festlegen, damit dessen Preiswert zusammen mit dem Level-Wert angezeigt wird
string level_text=ObjectGetString(chart_id, OBJ_NAME, OBJPROP_LEVELTEXT, i);
if(StringFind(level_text, EXT)<0)
{
level_text+=EXT;
ObjectSetString(chart_id, OBJ_NAME, OBJPROP_LEVELTEXT, i, level_text);
}
//--- Ausgabe der Levelnummer und die dazugehörigen Daten – den Levelwert und den Preis – im Journal
PrintFormat("Fibo level [%d] value: %.3f, price: %.*f", i, value, digits, level_price);
}
/*
Ergebnis:
Fibo level [0] value: 0.000, price: 0.61989
Fibo level [1] value: 0.236, price: 0.62533
Fibo level [2] value: 0.382, price: 0.62869
Fibo level [3] value: 0.500, price: 0.63140
Fibo level [4] value: 0.618, price: 0.63412
Fibo level [5] value: 1.000, price: 0.64292
Fibo level [6] value: 1.618, price: 0.65715
Fibo level [7] value: 2.618, price: 0.68018
Fibo level [8] value: 4.236, price: 0.71745
*/
}
//+------------------------------------------------------------------+
//| Erstellen des grafischen Objekts "Fibo-Levels" auf dem Chart |
//+------------------------------------------------------------------+
bool CreateFibo(const long chart_id)
{
//--- Zeichnen und abrufen der Fibonacci-Niveaus vom höchsten bis zum niedrigsten sichtbaren Preiswert im Chart
double price_high=0, price_low=0;
datetime time_high =0, time_low =0;
if(!GetChartExtremums(chart_id, price_high, price_low, time_high, time_low))
return(false);
//--- Erstellen des Fibo-Levels-Objekts anhand der gefundenen Preis-/Zeitkoordinaten.
if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_FIBO, WND, time_high, price_high, time_low, price_low))
{
PrintFormat("%s: ObjectCreate() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- alles in Ordnung – Chart aktualisieren und "true" zurückgeben
ChartRedraw();
return(true);
}
//+------------------------------------------------------------------+
//| Gibt Höchst- und Tiefstpreise des Charts & deren Zeitpunkt zurück|
//+------------------------------------------------------------------+
bool GetChartExtremums(const long chart_id, double &price_high, double &price_low, datetime &time_high, datetime &time_low)
{
//--- Variablen zurücksetzen
price_high=price_low=0;
time_high =time_low =0;
//--- Chart-Symbol
string symbol = ChartSymbol(chart_id);
//--- Berechnen des Beginns des Bereichs der kopierten Zeitreihe basierend auf der Nummer des ersten sichtbaren Balkens und der Anzahl der Balken im Chart
int first = (int)ChartGetInteger(chart_id, CHART_FIRST_VISIBLE_BAR);
int count = (int)ChartGetInteger(chart_id, CHART_VISIBLE_BARS);
int start = first+1-count;
//--- Arrays, in die Zeitreihen kopiert werden sollen
double array_high[];
double array_low[];
datetime array_time[];
int index;
//--- Kopiere drei Zeitreihen in Arrays in der Menge "count" und beginnend bei "start"
ResetLastError();
if(CopySeries(symbol, PERIOD_CURRENT, start, count, COPY_RATES_TIME|COPY_RATES_HIGH|COPY_RATES_LOW, array_time, array_high, array_low)!=count)
{
PrintFormat("%s: CopySeries() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Suche nach dem maximalen Preisindex im Array array_high
index=ArrayMaximum(array_high);
if(index<0)
{
PrintFormat("%s: ArrayMaximum() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Merke dir den höchsten Preis auf dem sichtbaren Chart und den Zeitwert des Balkens, auf dem sich dieser Preis befindet
price_high=array_high[index];
time_high=array_time[index];
//--- Suche nach dem Mindestpreisindex im Array array_low
index=ArrayMinimum(array_low);
if(index<0)
{
PrintFormat("%s: ArrayMinimum() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Merke dir den niedrigsten Preis auf dem sichtbaren Chart und den Zeitwert des Balkens, auf dem sich dieser Preis befindet
price_low=array_low[index];
time_low=array_time[index];
//--- alles in Ordnung
return(true);
}
|