//--- Beschreibung
#property description "Das Skript erstellt ein graphisches Objekt \"Horizontale Linie\"."
#property description "Preis des Ankerpunkts wird als Prozentsatz"
#property description "Chartfenster."
//--- Zeigen den Fenster von Eingabeparametern in der Skript-Startup
#property script_show_inputs
//--- Eingangsparameter von Skript
input string InpName="HLine"; // Linienname
input int InpPrice=25; // Linienpreis in %
input color InpColor=clrRed; // Linienfarbe
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Linienstil
input int InpWidth=3; // Linienbreite
input bool InpBack=false; // Die Linie im Hintergrund
input bool InpSelection=true; // Wählen zu bewegen
input bool InpHidden=true; // Ausgeblendet in der Objektliste
input long InpZOrder=0; // Priorität auf Mausklick
//+------------------------------------------------------------------+
//| Erstellt eine horizontale Linie |
//+------------------------------------------------------------------+
bool HLineCreate(const long chart_ID=0, // ID des Charts
const string name="HLine", // Linienname
const int sub_window=0, // Nummer des Unterfensters
double price=0, // Linienpreis
const color clr=clrRed, // Linienfarbe
const ENUM_LINE_STYLE style=STYLE_SOLID, // Linienstil
const int width=1, // Linienbreite
const bool back=false, // Im Hintergrund
const bool selection=true, // Wählen um zu bewegen
const bool hidden=true, // Ausgeblendet in der Objektliste
const long z_order=0) // Priorität auf Mausklick
{
//--- wenn der Preis nicht angegeben ist, setzen wir ihn gleich dem aktuellen Bid-Preis
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- eine horizontale Linie erstellen
if(!ObjectCreate(chart_ID,name,OBJ_HLINE,sub_window,0,price))
{
Print(__FUNCTION__,
": Horizontale Linie konnte nicht erstellt werden! Fehlercode = ",GetLastError());
return(false);
}
//--- Farbe der Linie setzen
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- Linienstil setzen
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- Linienbreite setzen
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- Im Vordergrund (false) oder Hintergrund (true) anzeigen
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- Aktivieren (true) oder deaktivieren (false) Mausbewegung Modus
//--- Wenn Sie ein grafisches Objekt durch Funktion ObjectCreate erstellen, das Objekt
//--- kann nicht ausgewählt und verschoben werden. Innerhalb dieser Methode ist der Standardwert des Parameters selection
//--- true, was Sie das Objekt auswählen und verschieben erlaubt
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- Verbergen (true) oder Anzeigen (false) den Namen des graphischen Objektes in der Objektliste
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- setzen die Priorität für eine Mausklick-Ereignisse auf dem Chart
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Horizontale Linie bewegen |
//+------------------------------------------------------------------+
bool HLineMove(const long chart_ID=0, // ID des Charts
const string name="HLine", // Linienname
double price=0) // Linienfarbe
{
//--- wenn der Preis der Linie nicht angegeben ist, bewegen wir die Linie auf das Niveau des aktuellen Bid-Preises
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- eine horizontale Linie bewegen
if(!ObjectMove(chart_ID,name,0,0,price))
{
Print(__FUNCTION__,
": Horizontale Linie konnte nicht bewegt werden! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Löscht eine horizontale Linie |
//+------------------------------------------------------------------+
bool HLineDelete(const long chart_ID=0, // ID des Charts
const string name="HLine") // Linienname
{
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- eine horizontale Linie löschen
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": Horizontale Linie konnte nicht gelöscht werden! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- Überprüfen die Richtigkeit der Eingabeparameter
if(InpPrice<0 || InpPrice>100)
{
Print("Fehler! Ungültige Eingabeparameter! ");
return;
}
//--- Größe des Arrays price
int accuracy=1000;
//--- Array speichert Preiswerte, die verwendet werden,
//--- um die Koordinaten der Ankerpunkten der Linie zu setzen und zu ändern
double price[];
//--- Speicher reservieren
ArrayResize(price,accuracy);
//--- Füllen den Array der Preise
//--- den Minimal- und Maximalwert der Charts finden
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- Schritte der Preisänderung finden und das Array füllen
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- Wir definieren Punkte, um die Linie zu zeichnen
int p=InpPrice*(accuracy-1)/100;
//--- eine horizontale Linie erstellen
if(!HLineCreate(0,InpName,0,price[p],InpColor,InpStyle,InpWidth,InpBack,
InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- den Chart neu zeichnen und 1 Sekunde warten
ChartRedraw();
Sleep(1000);
//--- jetzt bewegen wir die Linie
//--- Schleifenzähler
int v_steps=accuracy/2;
//--- Linie bewegen
for(int i=0;i<v_steps;i++)
{
//--- den nächsten Wert nehmen
if(p<accuracy-1)
p+=1;
//--- den Punkt bewegen
if(!HLineMove(0,InpName,price[p]))
return;
//--- Überprüfen die Fakten von Zwangsabschaltung der Skript
if(IsStopped())
return;
//--- den Chart neu zeichnen
ChartRedraw();
}
//--- 1 Sekunde Verzögerung
Sleep(1000);
//--- die Linie aus dem Chart löschen
HLineDelete(0,InpName);
ChartRedraw();
//--- 1 Sekunde Verzögerung
Sleep(1000);
//---
}
|