//--- Beschreibung
#property description "Das Skript erstellt ein graphisches Objekt \"Gann Gitter\"."
#property description "Koordinaten der Gitterankerpunkten werden in Prozente"
#property description "der Größe des Chartfensters eingegeben."
//--- Zeigen den Fenster von Eingabeparametern in der Skript-Startup
#property script_show_inputs
//--- Eingangsparameter von Skript
input string InpName="GannGrid"; // Gittername
input int InpDate1=15; // Datum des ersten Punktes in %
input int InpPrice1=25; // Preis des ersten Punktes in %
input int InpDate2=35; // Datum des zweiten Punktes in %
input double InpScale=3.0; // Maßstab
input bool InpDirection=false; // Trendrichtung
input color InpColor=clrRed; // Gitterfarbe
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Gitterlinienstil
input int InpWidth=1; // Breite der Fanlinien
input bool InpBack=false; // Das Gitter im Hintergrund
input bool InpSelection=true; // Wählen um zu bewegen
input bool InpHidden=true; // Ausgeblendet in der Objektliste
input long InpZOrder=0; // Priorität auf Mausklick
//+------------------------------------------------------------------+
//| Erstellt "Gann Gitter" |
//+------------------------------------------------------------------+
bool GannGridCreate(const long chart_ID=0, // ID des Charts
const string name="GannGrid", // Gittername
const int sub_window=0, // Nummer des Fensters
datetime time1=0, // Zeit des ersten Punktes
double price1=0, // Preis des ersten Punktes
datetime time2=0, // Zeit des zweiten Punktes
const double scale=1.0, // Maßstab
const bool direction=true, // Trendrichtung
const color clr=clrRed, // Gitterfarbe
const ENUM_LINE_STYLE style=STYLE_SOLID, // Gitterlinienstil
const int width=1, // Gitterlinienbreite
const bool back=false, // In der Hintergrund
const bool selection=true, // Wählen um zu bewegen
const bool hidden=true, // Verborgen in der Liste der Objekten
const long z_order=0) // Priorität für Mausklick
{
//--- Die Koordinaten der Bezugspunkte angeben, wenn sie nicht gesetzt sind
ChangeGannGridEmptyPoints(time1,price1,time2);
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- "Gann Gitter" auf angegebenen Koordinaten erstellen
if(!ObjectCreate(chart_ID,name,OBJ_GANNGRID,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": Objekt \" Gann Gitter\" konnte nicht erstellt werden! Fehlercode = ",GetLastError());
return(false);
}
//--- Ändern wir den Maßstab (Anzahl der Pips pro Bar)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- Ändern wir die Richtung des Trends von "Gann Gitter" (true - absteigend, falsch - aufsteigend)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- Gitterfarbe setzen
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- Gitterlinienstil angeben
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- Breite der Gitterlinien einstellen
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- Im Vordergrund (false) oder Hintergrund (true) anzeigen
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- aktivieren (true) oder deaktivieren (false) Wählen des Gitters für Bewegung
//--- Wenn Sie ein grafisches Objekt durch Funktion ObjectCreate erstellen, das Objekt
//--- kann nicht ausgewählt und verschoben werden. Innerhalb dieser Methode ist der Standardwert des Parameters selection
//--- true, was Sie das Objekt auswählen und verschieben erlaubt
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- Verbergen (true) oder Anzeigen (false) den Namen des graphischen Objektes in der Objektliste
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- setzen die Priorität für eine Mausklick-Ereignisse auf dem Chart
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Verschiebt den Ankerpunkt von Gann Gitter |
//+------------------------------------------------------------------+
bool GannGridPointChange(const long chart_ID=0, // ID des Charts
const string name="GannGrid", // Gittername
const int point_index=0, // Nummer des Ankerpunktes
datetime time=0, // Zeitkoordinate des Punktes
double price=0) // Preiskoordinate des Punktes
{
//--- Wenn die Koordinaten des Punktes nicht angegeben sind, dann verschieben wir es an den aktuellen Bar mit dem Preis Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- Gitterankerpunkt bewegen
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": der Bezugspunkt konnte nicht bewegt werden! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Ändert den Maßstab von "Gann Gitter" |
//+------------------------------------------------------------------+
bool GannGridScaleChange(const long chart_ID=0, // ID des Charts
const string name="GannGrid", // Gitter
const double scale=1.0) // Maßstab
{
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- Ändern wir den Maßstab (Anzahl der Pips pro Bar)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": Konnte nicht den Maßstab ändern! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Ändert die Trendrichtung von "Gann Gitter" |
//+------------------------------------------------------------------+
bool GannGridDirectionChange(const long chart_ID=0, // ID des Charts
const string name="GannGrid", // Gittername
const bool direction=true) // Trendrichtung
{
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- Ändern wir die Trendrichtung von "Gann Gitter"
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
": Konnte nicht die Trendrichtung ändern! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Die Funktion löscht das Objekt "Gann Gitter" |
//+------------------------------------------------------------------+
bool GannGridDelete(const long chart_ID=0, // ID des Charts
const string name="GannGrid") // Gittername
{
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- Gann Gitter löschen
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": Objekt \" Gann Gitter\" konnte nicht gelöscht werden! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Überprüft die Werte der Ankerpunkten von Gann Gitter |
//| und setzt Standardwerte für leere Werte |
//+------------------------------------------------------------------+
void ChangeGannGridEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- wenn die Zeit des zweiten Punktes nicht angegeben ist, wird sie auf dem aktuellen Bar sein
if(!time2)
time2=TimeCurrent();
//--- wenn die Zeit des ersten Punktes nicht angegeben ist, wird sie auf 9 Baren nach links vom ersten sein
if(!time1)
{
//--- Array um Eröffnungszeit der letzten 10 Bars aufzunehmen
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- stellen wir den ersten Punkt 9 Baren links dem zweiten Punkt
time1=temp[0];
}
//--- Wenn der Preis des ersten Punktes nicht angegeben wird, dann wird es einen Wert von Bid haben
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- Überprüfen die Richtigkeit der Eingabeparameter
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Fehler! Ungültige Eingabeparameter! ");
return;
;}
//--- Die Anzahl der sichtbaren Bars im Chart-Fenster
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- Größe des Arrays price
int accuracy=1000;
//--- Arrays für Werte von Daten und Preise, die für Setzung und Änderung
//--- der Koordinaten der Ankerpunkten des Gitters verwendet werden
datetime date[];
double price[];
//--- Speicher reservieren
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- Füllen die Anordnung von Daten
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Kann nicht den Wert der Zeit kopieren! Fehlercode = ",GetLastError());
return;
}
//--- Füllen den Array der Preise
//--- den Minimal- und Maximalwert der Charts finden
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- Schritte der Preisänderung finden und das Array füllen
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- Definieren die Punkte um Gann Gitter zu zeichnen
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- Gann Gitter erstellen
if(!GannGridCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- den Chart neu zeichnen und 1 Sekunde warten
ChartRedraw();
Sleep(1000);
//--- jetzt bewegen wir die Gitterankerpunkte
//--- Schleifenzähler
int v_steps=accuracy/4;
//--- Wir bewegen den ersten Bezugspunkt vertikal
for(int i=0;i<v_steps;i++)
{
//--- den nächsten Wert nehmen
if(p1<accuracy-1)
p1+=1;
if(!GannGridPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- Überprüfen die Fakten von Zwangsabschaltung der Skript
if(IsStopped())
return;
//--- den Chart neu zeichnen
ChartRedraw();
}
//--- 1 Sekunde Verzögerung
Sleep(1000);
//--- Schleifenzähler
int h_steps=bars/4;
//--- den zweiten Punkt horizontal bewegen
for(int i=0;i<h_steps;i++)
{
//--- den nächsten Wert nehmen
if(d2<bars-1)
d2+=1;
if(!GannGridPointChange(0,InpName,1,date[d2],0))
return;
//--- Überprüfen die Fakten von Zwangsabschaltung der Skript
if(IsStopped())
return;
//--- den Chart neu zeichnen
ChartRedraw();
// Verzögerung 0.05 Sekunden
Sleep(50);
}
//--- 1 Sekunde Verzögerung
Sleep(1000);
//--- Ändern wir die Trendrichtung des Gitters zu absteigend
GannGridDirectionChange(0,InpName,true);
//--- den Chart neu zeichnen
ChartRedraw();
//--- 1 Sekunde Verzögerung
Sleep(1000);
//--- das Gitter aus dem Chart löschen
GannGridDelete(0,InpName);
ChartRedraw();
//--- 1 Sekunde Verzögerung
Sleep(1000);
//---
}
|