#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define COORD_X 200
#define COORD_Y 100
#define OBJ_NAME "TestTextGetSizeBitmapLabel"
#define RES_NAME "TestTextGetSizeResource"
#define COLOR_NULL 0x00FFFFFF
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion |
//+------------------------------------------------------------------+
void OnStart()
{
//--- aktuelle Chart-ID
long chart_id= ChartID();
string font_names[] ={"Arial", "Tahoma", "Calibri"};
uint flags_array[]={0, FONT_ITALIC, FONT_UNDERLINE, FONT_STRIKEOUT};
uint fw_array[]={FW_DONTCARE, FW_THIN, FW_EXTRALIGHT, FW_ULTRALIGHT, FW_LIGHT,
FW_NORMAL, FW_REGULAR, FW_MEDIUM, FW_SEMIBOLD, FW_DEMIBOLD,
FW_BOLD, FW_EXTRABOLD, FW_ULTRABOLD, FW_HEAVY, FW_BLACK};
//--- Zeichnen aller Attribute des Preis-Chart deaktivieren
ChartSetInteger(chart_id, CHART_SHOW, false);
//--- Deklaration der Parameter der grafischen Ressource
uint rc_width =(int)ChartGetInteger(chart_id, CHART_WIDTH_IN_PIXELS);
uint rc_height=(int)ChartGetInteger(chart_id, CHART_HEIGHT_IN_PIXELS);
uint rc_data[];
uint rc_size=rc_width*rc_height;
//--- Erstellen einer grafischen Ressource für die Textausgabe
if(!CreateResource(chart_id, rc_data, rc_width, rc_height))
return;
//--- Schleife durch die Namen der Schrifttypen
for(int i=0; i<(int)font_names.Size(); i++)
{
//--- Schleife durch die Flags der Schrifttypen
for(int j=0; j<(int)flags_array.Size(); j++)
{
//--- Zeichnen des Texts mit dem Schrifttyp und dem Stil, die Sie aus dem Array erhalten haben.
DrawText(font_names[i], flags_array[j], rc_data, rc_width, rc_height);
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- nachdem alle Texte mit unterschiedlichen Schriftgrößen und -stilen ausgegeben wurden,
//--- zeige den Text mit unterschiedlichen Flags der Schriftbreiten anzeigen
for(int i=0; i<(int)fw_array.Size(); i++)
{
//--- Festlegen der Schriftgröße und des Namens für die Anzeige von Text mit den Breiten-Flags
string font_name="Tahoma";
int size=-140;
TextSetFont(font_name, size, fw_array[i]);
//--- Erstellen eines zu zeichnenden Textes, Ausgabe in das Ressourcen-Pixel-Array aus und Aktualisieren der Ressource
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagWidthDescription(fw_array[i]), size, size/-10);
TextOut(text, COORD_X, COORD_Y, ANCHOR_LEFT_UPPER, rc_data, rc_width, rc_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, rc_data, rc_width, rc_height, true);
//--- eine Sekunde warten
Sleep(1000);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- fünf Sekunden warten, dann die Ressource freigeben und das grafische Objekt löschen
Sleep(5000);
ResourceFree(RES_NAME);
ObjectDelete(chart_id, OBJ_NAME);
//--- Erlaube das Zeichnen beliebiger Attribute des Preis-Charts
ChartSetInteger(chart_id, CHART_SHOW, true);
ChartRedraw(chart_id);
/*
Als Ergebnis der Skriptausführung werden Textnachrichten auf dem Chart angezeigt.
Die Texte haben unterschiedliche Schriftarten sowie Stil- und Breiten-Flags
*/
}
//+------------------------------------------------------------------+
//| Zeige fünf Textzeichenfolgen unterschiedlicher |
//| Größe mit der angegebenen Schriftart und den angegebenen Flags |
//+------------------------------------------------------------------+
void DrawText(const string font_name, uint flags, uint &pixels_array[], uint res_width, uint res_height)
{
//--- Ausgabe von fünf Textzeichenfolgen mit unterschiedlichen Schriftgrößen
for(int i=0; i<5; i++)
{
//--- Berechnung der Schriftgröße und Festlegung der Schriftart für die Textausgabe mithilfe von Zeichenmethoden
int size=-140+10*i;
TextSetFont(font_name, size, flags);
//--- Erstellen eines zu zeichnenden Textes, Ausgabe in das Ressourcen-Pixel-Array aus und Aktualisieren der Ressource
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagDescription(flags), size, size/-10);
TextOut(text, COORD_X, COORD_Y+22*i, ANCHOR_LEFT_UPPER, pixels_array, res_width, res_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, pixels_array, res_width, res_height, true);
//--- wart ein Weilchen
Sleep(800);
}
}
//+------------------------------------------------------------------+
//| Eine Beschreibung der Schriftart-Flags zurückgeben |
//+------------------------------------------------------------------+
string FlagDescription(const uint flag)
{
switch(flag)
{
case FONT_ITALIC : return(" Italic");
case FONT_UNDERLINE : return(" Underline");
case FONT_STRIKEOUT : return(" Strikeout");
}
return("");
}
//+------------------------------------------------------------------+
//| Gibt die Beschreibung der Flags für die Schriftbreite zurück |
//+------------------------------------------------------------------+
string FlagWidthDescription(const uint flag)
{
switch(flag)
{
case FW_DONTCARE : return(" Egal");
case FW_THIN : return(" Dünn");
case FW_EXTRALIGHT: return(" Extraleicht");
case FW_ULTRALIGHT: return(" Ultraleicht");
case FW_LIGHT : return(" Leicht");
case FW_NORMAL : return(" Normal");
case FW_REGULAR : return(" Regulär");
case FW_MEDIUM : return(" Medium");
case FW_SEMIBOLD : return(" Halb fett");
case FW_DEMIBOLD : return(" Demi fett");
case FW_BOLD : return(" Fett");
case FW_EXTRABOLD : return(" Extra fett");
case FW_ULTRABOLD : return(" Ultra fett");
case FW_HEAVY : return(" Schwer");
case FW_BLACK : return(" Schwarz");
}
return("");
}
//+------------------------------------------------------------------+
//| Grafische Ressource für das gesamte Chart erstellen |
//+------------------------------------------------------------------+
bool CreateResource(const long chart_id, uint &pixel_data[], const uint width, const uint height)
{
//--- Festlegen der Größe des Pixelarrays
ResetLastError();
uint size=width*height;
if(ArrayResize(pixel_data, size)!=size)
{
PrintFormat("%s: ArrayResize() fehlgeschlagen. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Füllen des Pixelarrays mit einer transparenten Farbe und Erstellen einer grafischen Ressource auf der Grundlage dieser Farbe
ArrayInitialize(pixel_data, COLOR_NULL);
if(!ResourceCreate(RES_NAME, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE))
{
PrintFormat("%s: ResourceCreate() fehlgeschlagen. Error code ",__FUNCTION__, GetLastError());
return(false);
}
//--- Erstellen des Grafiklabel-Objekt an den Koordinaten der oberen linken Ecke des Charts.
if(!ObjectCreate(0, OBJ_NAME, OBJ_BITMAP_LABEL, 0, 0, 0))
{
PrintFormat("%s: ObjectCreate() fehlgeschlagen. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- die Breite und Höhe des erstellten Bitmap-Objekts auf die Breite und Höhe der grafischen Ressource einstellen.
//--- Setzen des Ankerpunkts des Objekts auf seine Mitte.
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_XSIZE, width))
{
PrintFormat("%s: ObjectSetInteger() fehlgeschlagen. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_YSIZE, height))
{
PrintFormat("%s: ObjectSetInteger() fehlgeschlagen. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Angabe der zuvor erstellten grafischen Ressource für das Bitmap-Objekt als Bilddatei
//--- in diesem Fall müssen wir, um den Namen der verwendeten grafischen Ressource anzugeben, "::" vor ihrem Namen hinzufügen
if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_BMPFILE, "::"+RES_NAME))
{
PrintFormat("%s: ObjectSetString() fehlgeschlagen. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- alles in Ordnung
return(true);
}
//+------------------------------------------------------------------+
//| Grafische Ressourcendaten aktualisieren |
//+------------------------------------------------------------------+
void Update(const string res_name, const uint &pixel_data[], const uint width, const uint height, const bool redraw)
{
//--- Verlassen, wenn Dimensionen von 0 übergeben wurden
if(width==0 || height==0)
return;
//--- Ressourcendaten aktualisieren und den Chart neu zeichnen
if(ResourceCreate(res_name, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
|