//--- Beschreibung
#property description "Das Skript erstellt ein graphisches Objekt \"Fibonacci Zeitzonen\"."
#property description "Koordinaten der Ankerpunkten werden in Pixeln angegeben"
#property description "Chartfenster."
//--- Zeigen den Fenster von Eingabeparametern in der Skript-Startup
#property script_show_inputs
//--- Eingangsparameter von Skript
input string InpName="FiboTimes"; // Objektname
input int InpDate1=10; // Datum des ersten Punktes in %
input int InpPrice1=45; // Preis des ersten Punktes in %
input int InpDate2=20; // Datum des zweiten Punktes in %
input int InpPrice2=55; // Preis des zweiten Punktes in %
input color InpColor=clrRed; // Objektfarbe
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Linienstil
input int InpWidth=2; // Linienbreite
input bool InpBack=false; // Objekt im Hintergrund
input bool InpSelection=true; // Wählen um zu bewegen
input bool InpHidden=true; // Ausgeblendet in der Objektliste
input long InpZOrder=0; // Priorität auf Mausklick
//+------------------------------------------------------------------+
//| Erstellt Objekt Fibonacci Zeitzonen auf angegebenen Koordinaten |
//+------------------------------------------------------------------+
bool FiboTimesCreate(const long chart_ID=0, // ID des Charts
const string name="FiboTimes", // Objektname
const int sub_window=0, // Nummer des Unterfensters
datetime time1=0, // Zeit des ersten Punktes
double price1=0, // Preis des ersten Punktes
datetime time2=0, // Zeit des zweiten Punktes
double price2=0, // Preis des zweiten Punktes
const color clr=clrRed, // Objektfarbe
const ENUM_LINE_STYLE style=STYLE_SOLID, // Linienstil des Objekts
const int width=1, // Breite der Objektlinie
const bool back=false, // In der Hintergrund
const bool selection=true, // Wählen um zu bewegen
const bool hidden=true, // Verborgen in der Liste der Objekten
const long z_order=0) // Priorität für Mausklick
{
//--- Die Koordinaten der Bezugspunkte angeben, wenn sie nicht gesetzt sind
ChangeFiboTimesEmptyPoints(time1,price1,time2,price2);
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- "Fibonacci Zeitzonen" auf angegebenen Koordinaten erstellen
if(!ObjectCreate(chart_ID,name,OBJ_FIBOTIMES,sub_window,time1,price1,time2,price2))
{
Print(__FUNCTION__,
": Objekt \" Fibonacci Zeitzonen\" konnte nicht erstellt werden! Fehlercode = ",GetLastError());
return(false);
}
//--- Farbe setzen
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- Linienstil setzen
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- Linienbreite setzen
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- Im Vordergrund (false) oder Hintergrund (true) anzeigen
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- aktivieren (true) oder deaktivieren (false) Bewegung des Objekts für Bewegung
//--- Wenn Sie ein grafisches Objekt durch Funktion ObjectCreate erstellen, das Objekt
//--- kann nicht ausgewählt und verschoben werden. Innerhalb dieser Methode ist der Standardwert des Parameters selection
//--- true, was Sie das Objekt auswählen und verschieben erlaubt
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- Verbergen (true) oder Anzeigen (false) den Namen des graphischen Objektes in der Objektliste
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- setzen die Priorität für eine Mausklick-Ereignisse auf dem Chart
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Gibt die Anzahl der Ebenen und ihren Parameter an |
//+------------------------------------------------------------------+
bool FiboTimesLevelsSet(int levels, // Anzahl der Ebenelinien
double &values[], // Werte der Linien
color &colors[], // Farbe der Linien
ENUM_LINE_STYLE &styles[], // Linienstil
int &widths[], // Linienbreite
const long chart_ID=0, // ID des Charts
const string name="FiboTimes") // Objektname
{
//--- Überprüfen wir die Größe des Arrays
if(levels!=ArraySize(colors) || levels!=ArraySize(styles) ||
levels!=ArraySize(widths) || levels!=ArraySize(widths))
{
Print(__FUNCTION__,": Länge des Arrays entspricht nicht der Anzahl der Ebenen, Fehler!");
return(false);
}
//--- Die Anzahl der Ebenen angeben
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELS,levels);
//--- die Eigenschaften der Ebenen im Zyklus angeben
for(int i=0;i<levels;i++)
{
//--- Wert der Ebene
ObjectSetDouble(chart_ID,name,OBJPROP_LEVELVALUE,i,values[i]);
//--- Farbe der Ebene
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELCOLOR,i,colors[i]);
//--- Stil der Ebene
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELSTYLE,i,styles[i]);
//--- Stärke der Ebene
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELWIDTH,i,widths[i]);
//--- Beschreibung der Ebene
ObjectSetString(chart_ID,name,OBJPROP_LEVELTEXT,i,DoubleToString(values[i],1));
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Verschiebt den Ankerpunkt von Fibonacci Zeitzonen |
//+------------------------------------------------------------------+
bool FiboTimesPointChange(const long chart_ID=0, // ID des Charts
const string name="FiboTimes", // Objektname
const int point_index=0, // Nummer des Ankerpunktes
datetime time=0, // Zeitkoordinate des Punktes
double price=0) // Preiskoordinate des Punktes
{
//--- Wenn die Koordinaten des Punktes nicht angegeben sind, dann verschieben wir es an den aktuellen Bar mit dem Preis Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- bewegen den Bezugspunkt
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": der Bezugspunkt konnte nicht bewegt werden! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Löscht das Objekt "Fibonacci Zeitzonen" |
//+------------------------------------------------------------------+
bool FiboTimesDelete(const long chart_ID=0, // ID des Charts
const string name="FiboTimes") // Objektname
{
//--- Setzen den Wert des Fehlers zurück
ResetLastError();
//--- das Objekt löschen
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": Objekt \" Fibonacci Zeitzonen\" konnte nicht gelöscht werden! Fehlercode = ",GetLastError());
return(false);
}
//--- die erfolgreiche Umsetzung
return(true);
}
//+------------------------------------------------------------------+
//| Prüft die Werte der Ankerpunkten von "Fibonacci Zeitzonen" |
//| und setzt Standardwerte für leere Werte |
//+------------------------------------------------------------------+
void ChangeFiboTimesEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- Wenn Zeit des ersten Punktes nicht angegeben ist, wird es auf dem aktuellen Bar sein
if(!time1)
time1=TimeCurrent();
//--- Wenn der Preis des ersten Punktes nicht angegeben wird, dann wird es einen Wert von Bid haben
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- wenn die Zeit des zweiten Punktes nicht angegeben ist, wird sie auf 2 Balken nach links sein
if(!time2)
{
//--- Array um die Zeit der Öffnung der letzten 3 Bars zu empfangen
datetime temp[3];
CopyTime(Symbol(),Period(),time1,3,temp);
//--- stellen wir den ersten Punkt 2 Baren links auf dem zweiten Punkt
time2=temp[0];
}
//--- Wenn der Preis des zweiten Punktes nicht angegeben wird, dann wird es der Preis des ersten Punktes gleich
if(!price2)
price2=price1;
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- Überprüfen die Richtigkeit der Eingabeparameter
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
{
Print("Fehler! Ungültige Eingabeparameter! ");
return;
}
//--- Die Anzahl der sichtbaren Bars im Chart-Fenster
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- Größe des Arrays price
int accuracy=1000;
//--- Arrays für Werte von Daten und Preise, die für Setzung und Änderung
//--- der Koordinaten der Ankerpunkten von Fibonacci Zeitzonen verwendet werden
datetime date[];
double price[];
//--- Speicher reservieren
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- Füllen die Anordnung von Daten
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Kann nicht den Wert der Zeit kopieren! Fehlercode = ",GetLastError());
return;
}
//--- Füllen den Array der Preise
//--- den Minimal- und Maximalwert der Charts finden
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- Schritte der Preisänderung finden und das Array füllen
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- Definieren die Punkte um Fibonacci Zeitzonen zu zeichnen
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
//--- Objekt erstellen
if(!FiboTimesCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- den Chart neu zeichnen und 1 Sekunde warten
ChartRedraw();
Sleep(1000);
//--- jetzt bewegen wir die Ankerpunkte
//--- Schleifenzähler
int h_steps=bars*2/5;
//--- den zweiten Punkt bewegen
for(int i=0;i<h_steps;i++)
{
//--- den nächsten Wert nehmen
if(d2<bars-1)
d2+=1;
//--- den Punkt bewegen
if(!FiboTimesPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- Überprüfen die Fakten von Zwangsabschaltung der Skript
if(IsStopped())
return;
//--- den Chart neu zeichnen
ChartRedraw();
// Verzögerung 0.05 Sekunden
Sleep(50);
}
//--- 1 Sekunde Verzögerung
Sleep(1000);
//--- Schleifenzähler
h_steps=bars*3/5;
//--- den ersten Punkt bewegen
for(int i=0;i<h_steps;i++)
{
//--- den nächsten Wert nehmen
if(d1<bars-1)
d1+=1;
//--- den Punkt bewegen
if(!FiboTimesPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- Überprüfen die Fakten von Zwangsabschaltung der Skript
if(IsStopped())
return;
//--- den Chart neu zeichnen
ChartRedraw();
// Verzögerung 0.05 Sekunden
Sleep(50);
}
//--- 1 Sekunde Verzögerung
Sleep(1000);
//--- das Objekt aus dem Chart löschen
FiboTimesDelete(0,InpName);
ChartRedraw();
//--- 1 Sekunde Verzögerung
Sleep(1000);
//---
}
|
