#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define OBJ_NAME "TestObjectGetTimeByValue" // Name des grafischen Objekts
#define STEP 100 // Preisschritt
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion |
//+------------------------------------------------------------------+
void OnStart()
{
//--- ID, Symbol
long chart_id=ChartID();
string chart_symbol=ChartSymbol(chart_id);
//--- den Punktwert des Chart-Symbols abrufen
double point=SymbolInfoDouble(chart_symbol, SYMBOL_POINT);
if(point==0)
{
PrintFormat("Der Punktwert des Symbols \"%s\" konnte nicht abgerufen werden. Error %d", chart_symbol, GetLastError());
return;
}
//--- Erstellen eines gleichmäßigen Kanals vom Höchstwert des linken sichtbaren Balkens zum Tiefstwert des rechten Balkens
if(!CreateChannel(chart_id))
return;
//--- Chart-Maximum und -Minimum, Dezimalstellen des Chart-Symbols
double chart_max=ChartGetDouble(chart_id, CHART_PRICE_MAX);
double chart_min=ChartGetDouble(chart_id, CHART_PRICE_MIN);
int digits=(int)SymbolInfoInteger(chart_symbol, SYMBOL_DIGITS);
//--- solange der berechnete Preis größer ist als der Mindestpreiswert des Charts,
//--- durchlaufe die Chartpreise mit STEP in einer Schleife und erhalte den Zeitwert
//--- für den berechneten Preiswert jeder Linie des äquidistanten Kanals.
//--- gib die empfangene Zeit für jede Linie in das Journal aus
int index=0;
double price=chart_max;
do
{
price=chart_max-STEP*index*point;
datetime time0=ObjectGetTimeByValue(chart_id, OBJ_NAME, price, 0);
datetime time1=ObjectGetTimeByValue(chart_id, OBJ_NAME, price, 1);
string time0_str=(time0>0 ? TimeToString(time0) : "No value at this price");
string time1_str=(time1>0 ? TimeToString(time1) : "No value at this price");
string idx=StringFormat("%02d", index);
PrintFormat("[%s] For price %.*f the time value at line 0: %s, at line 1: %s", idx, digits, price, time0_str, time1_str);
index++;
}
while(!IsStopped() && price>=chart_min);
//--- 5 Sekunden warten und aufräumen
Sleep(5000);
ObjectDelete(chart_id, OBJ_NAME);
ChartRedraw(chart_id);
/*
Ergebnis:
[00] For price 1.26110 the time value at line 0: No value at this price, at line 1: No value at this price
[01] For price 1.26010 the time value at line 0: 2024.12.30 17:00, at line 1: No value at this price
[02] For price 1.25910 the time value at line 0: 2024.12.30 22:30, at line 1: No value at this price
[03] For price 1.25810 the time value at line 0: 2024.12.31 04:00, at line 1: 2024.12.30 16:30
[04] For price 1.25710 the time value at line 0: 2024.12.31 10:00, at line 1: 2024.12.30 22:00
[05] For price 1.25610 the time value at line 0: 2024.12.31 15:30, at line 1: 2024.12.31 03:30
[06] For price 1.25510 the time value at line 0: 2024.12.31 21:00, at line 1: 2024.12.31 09:00
[07] For price 1.25410 the time value at line 0: 2025.01.02 03:30, at line 1: 2024.12.31 14:30
[08] For price 1.25310 the time value at line 0: No value at this price, at line 1: 2024.12.31 20:30
[09] For price 1.25210 the time value at line 0: No value at this price, at line 1: 2025.01.02 03:00
[10] For price 1.25110 the time value at line 0: No value at this price, at line 1: No value at this price
[11] For price 1.25010 the time value at line 0: No value at this price, at line 1: No value at this price
[12] For price 1.24910 the time value at line 0: No value at this price, at line 1: No value at this price
[13] For price 1.24810 the time value at line 0: No value at this price, at line 1: No value at this price
*/
}
//+--------------------------------------------------------------------------------------------+
//| Erstelle einen gleichmäßigen Kanal vom Hoch des linken Balkens zum Tief des rechten Balkens|
//+--------------------------------------------------------------------------------------------+
bool CreateChannel(const long chart_id=0)
{
long bar1 =0, bar2 =0, visible=0;
datetime time1 =0, time2 =0;
double price1=0, price2=0;
//--- den ersten Balken des Charts links anzeigen
ResetLastError();
if(!ChartGetInteger(chart_id, CHART_FIRST_VISIBLE_BAR, 0, bar1))
{
PrintFormat("%s: ChartGetInteger() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Anzahl der sichtbaren Balken im Chart
if(!ChartGetInteger(chart_id, CHART_VISIBLE_BARS, 0, visible))
{
PrintFormat("%s: ChartGetInteger() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Anpassen der erhaltenen Werte und Berechnen des Index des ersten rechts sichtbaren Balkens
bar1-=1;
visible-=2;
bar2=bar1-visible;
//--- Chart-Symbol
string symbol=ChartSymbol(chart_id);
//--- Zeit des ersten, sichtbaren Balken links im Chart abrufen
ResetLastError();
datetime time_array[1];
if(CopyTime(symbol, PERIOD_CURRENT, (int)bar1, 1, time_array)!=1)
{
PrintFormat("%s: CopyTime() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
time1=time_array[0];
//--- Ermitteln der Zeit des ersten sichtbaren Balkens rechts auf dem Chart
if(CopyTime(symbol, PERIOD_CURRENT, (int)bar2, 1, time_array)!=1)
{
PrintFormat("%s: CopyTime() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
time2=time_array[0];
//--- den Höchstpreis des ersten Balkens links im Chart abrufen
double price_array[];
if(CopyHigh(symbol, PERIOD_CURRENT, (int)bar1, 1, price_array)!=1)
{
PrintFormat("%s: CopyHigh() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
price1=price_array[0];
//--- den Tiefstpreis des ersten sichtbaren Balkens rechts im Chart abrufen
if(CopyLow(symbol, PERIOD_CURRENT, (int)bar2, 1, price_array)!=1)
{
PrintFormat("%s: CopyLow() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
price2=price_array[0];
//--- Berechnen der Preisspanne des Charts in Punkten
//--- Bei einem gleichmäßigen Kanal beträgt der Abstand der zweiten Linie 1/3 der Preisspanne
double range=price1-price2;
double distance=range*0.3;
//--- An den berechneten Koordinaten ein grafisches Objekt erstellen – einen äquidistanten Kanal
if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_CHANNEL, 0, time1, price1, time2, price2, time1, price1-distance))
{
PrintFormat("%s: ObjectCreate() fehlgeschlagen. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- Aktualisieren des Charts und Zurückgeben von 'true'
ChartRedraw(chart_id);
return(true);
}
|