DokumentationKategorien
Nachschlagewerk MQL5Graphische ObjekteObjectsTotal 

ObjectsTotal

Gibt die Anzahl der Objekte im angegebenen Chart, angegebenen Subfenster des angegebenen Charts des angegebenen Typs zurück.

int  ObjectsTotal(
   long  chart_id,           // Identifikator des Charts
   int   sub_window=-1,      // Index des Fensters
   int   type=-1             // Objekttyp     
   );

Parameter

chart_id

[in]  Identifikator des Charts. 0 bedeutet den laufenden Chart.

sub_window=-1

[in]  Nummer des Subfensters des Charts. 0 bedeutet Hauptfenster des Charts,  -1 bedeutet alle Subfenster des Charts, einschliesslich Hauptfenster.

type=-1

[in]  Objekttyp. Wert kann einer der Enumerationswerte ENUM_OBJECT sein. -1 bedeutet alle Typen.

Rückgabewert

Anzahl der Objekte.

Hinweis

Die Funktion verwendet einen synchronen Aufruf, d.h. dass die Funktion auf die Ausführung aller Befehle wartet, die vor deren Aufruf zur Warteschlange des Charts hinzugefügt wurden, deswegen kann die Funktion viel Zeit in Anspruch nehmen. Dies muss man beachten, wenn man mit vielen Objekten im Chart arbeitet.

 

Beispiel:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Chart-ID
   long chart_id=ChartID();
   
//--- Anzahl der Chart-Unterfenster zusammen mit dem Hauptfenster abrufen
   long wnd=0;
   ResetLastError();
   if(!ChartGetInteger(chart_id, CHART_WINDOWS_TOTAL, 0, wnd))
     {
      Print("ChartGetInteger() failed. Error ", GetLastError());
      return;
     }
   
//--- Anzahl der grafischen Objekte für jedes Chart-Unterfenster abrufen und im Journal anzeigen
   for(int i=0; i<(int)wnd; i++)
     {
      int objects=ObjectsTotal(chart_id, i);
      string wnd_head=(i==0 ? "Das Hauptfenster des Chart" : StringFormat("The window with index %d of the chart", i));
      PrintFormat("%s contains %d graphic objects", wnd_head, objects);
     }
   /*
   Ergebnis für das Hauptfenster mit zwei Unterfenstern,
   wobei das Hauptfenster die Deal-Kennzeichnungen enthält
   und in den Unterfenstern zwei grafische Objekte vorhanden sind:
   The main chart window contains 656 graphic objects
   The window with index 1 of the chart contains 2 graphic objects 
   The window with index 2 of the chart contains 2 graphic objects
   */
  }