下载MetaTrader 5

OBJ_TEXT

文本对象。

ObjText

注意

相对于文本的定位点位置可以从 ENUM_ANCHOR_POINT 枚举选择。您也可以使用 OBJPROP_ANGLE 属性来改变文本定位角。

示例

下面的脚本创建图表上的多个文本对象。已开发的特别函数用于创建和改变图形对象的属性。您可以在您的个人应用中使用这些函数"as is" 。

 

//--- 描述
#property description "Script creates \"Text\" graphical object."
//--- 启动脚本期间显示输入参数的窗口
#property script_show_inputs
//--- 脚本的输入参数
input string            InpFont="Arial";         // 字体
input int               InpFontSize=10;          // 字体大小
input color             InpColor=clrRed;         // 颜色
input double            InpAngle=90.0;           // 倾斜角度
input ENUM_ANCHOR_POINT InpAnchor=ANCHOR_BOTTOM// 定位类型
input bool              InpBack=false;           // 背景对象
input bool              InpSelection=false;      // 突出移动
input bool              InpHidden=true;          // 隐藏对象列表中
input long              InpZOrder=0;             // 鼠标单击优先
//+------------------------------------------------------------------+
//| 创建文本对象                                                       |
//+------------------------------------------------------------------+
bool TextCreate(const long              chart_ID=0,               // 图表 ID
                const string            name="Text",              // 对象名称
                const int               sub_window=0,             // 子窗口指数
                datetime                time=0,                   // 定位点时间
                double                  price=0,                  // 定位点价格
                const string            text="Text",              // 文本本身
                const string            font="Arial",             // 字体
                const int               font_size=10,             // 字体大小
                const color             clr=clrRed,               // 颜色
                const double            angle=0.0,                // 文本倾斜
                const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER// 定位类型
                const bool              back=false,               // 在背景中
                const bool              selection=false,          // 突出移动
                const bool              hidden=true,              // 隐藏在对象列表
                const long              z_order=0)                // 鼠标单击优先
  {
//--- 若未设置则设置定位点的坐标
   ChangeTextEmptyPoint(time,price);
//--- 重置错误的值
   ResetLastError();
//--- 创建文本对象
   if(!ObjectCreate(chart_ID,name,OBJ_TEXT,sub_window,time,price))
     {
      Print(__FUNCTION__,
            ": failed to create \"Text\" object! Error code = ",GetLastError());
      return(false);
     }
//--- 设置文本
   ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- 设置文本字体
   ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- 设置字体大小
   ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- 设置文本的倾斜角
   ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- 设置定位类型
   ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- 设置颜色
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 显示前景 (false) 或背景 (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 启用 (true) 或禁用 (false) 通过鼠标移动对象的模式
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 在对象列表隐藏(true) 或显示 (false) 图形对象名称
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 设置在图表中优先接收鼠标点击事件
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 成功执行
   return(true);
  }
//+------------------------------------------------------------------+
//| 移动定位点                                                        |
//+------------------------------------------------------------------+
bool TextMove(const long   chart_ID=0,  // 图表 ID
              const string name="Text"// 对象名称
              datetime     time=0,      // 定位点时间坐标
              double       price=0)     // 定位点价格坐标
  {
//--- 如果没有设置点的位置,则将其移动到当前的卖价柱
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 重置错误的值
   ResetLastError();
//--- 移动定位点
   if(!ObjectMove(chart_ID,name,0,time,price))
     {
      Print(__FUNCTION__,
            ": failed to move the anchor point! Error code = ",GetLastError());
      return(false);
     }
//--- 成功执行
   return(true);
  }
//+------------------------------------------------------------------+
//| 改变对象文本                                                       |
//+------------------------------------------------------------------+
bool TextChange(const long   chart_ID=0,  // 图表 ID
                const string name="Text"// 对象名称
                const string text="Text"// 文本
  {
//--- 重置错误的值
   ResetLastError();
//--- 改变对象文本
   if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
     {
      Print(__FUNCTION__,
            ": failed to change the text! Error code = ",GetLastError());
      return(false);
     }
//--- 成功执行
   return(true);
  }
//+------------------------------------------------------------------+
//| 删除文本对象                                                       |
//+------------------------------------------------------------------+
bool TextDelete(const long   chart_ID=0,  // 图表 ID
                const string name="Text"// 对象名称
  {
//--- 重置错误的值
   ResetLastError();
//--- 删除对象
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": failed to delete \"Text\" object! Error code = ",GetLastError());
      return(false);
     }
//--- 成功执行
   return(true);
  }
//+------------------------------------------------------------------+
//| 检查定位点的值和为空点设置                                           |
//| 默认的值                                                          |
//+------------------------------------------------------------------+
void ChangeTextEmptyPoint(datetime &time,double &price)
  {
//--- 如果点的时间没有设置,它将位于当前柱
   if(!time)
      time=TimeCurrent();
//--- 如果点的价格没有设置,则它将用卖价值
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
  }
//+------------------------------------------------------------------+
//| 脚本程序起始函数                                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date[]; // 存储可见柱日期的数组
   double   low[];  // 存储可见柱最低价格的数组
   double   high[]; // 存储可见柱最高价格的数组
//--- 图表窗口的可见柱的数量
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 内存分配
   ArrayResize(date,bars);
   ArrayResize(low,bars);
   ArrayResize(high,bars);
//--- 填写日期数组
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("Failed to copy time values! Error code = ",GetLastError());
      return;
     }
//--- 填写最低价格的数组
   if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
     {
      Print("Failed to copy the values of Low prices! Error code = ",GetLastError());
      return;
     }
//--- 填写最高价格的数组
   if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
     {
      Print("Failed to copy the values of High prices! Error code = ",GetLastError());
      return;
     }
//--- 定义文本显示的频率
   int scale=(int)ChartGetInteger(0,CHART_SCALE);
//--- 定义步骤
   int step=1;
   switch(scale)
     {
      case 0:
         step=12;
         break;
      case 1:
         step=6;
         break;
      case 2:
         step=4;
         break;
      case 3:
         step=2;
         break;
     }
//--- 创建最高和最低柱的值的文本(间隔)。
   for(int i=0;i<bars;i+=step)
     {
      //--- 创建文本
      if(!TextCreate(0,"TextHigh_"+(string)i,0,date[i],high[i],DoubleToString(high[i],5),InpFont,InpFontSize,
         InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
        {
         return;
        }
      if(!TextCreate(0,"TextLow_"+(string)i,0,date[i],low[i],DoubleToString(low[i],5),InpFont,InpFontSize,
         InpColor,-InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
        {
         return;
        }
      //--- 检查脚本操作是否已经强制禁用
      if(IsStopped())
         return;
      //--- 重画图表
      ChartRedraw();
      // 0.05 秒延迟
      Sleep(50);
     }
//--- 半秒延迟
   Sleep(500);
//--- 删除文本
   for(int i=0;i<bars;i+=step)
     {
      if(!TextDelete(0,"TextHigh_"+(string)i))
         return;
      if(!TextDelete(0,"TextLow_"+(string)i))
         return;
      //--- 重画图表
      ChartRedraw();
      // 0.05 秒延迟
      Sleep(50);
     }
//---
  }


更新: 2015.12.03