//--- 描述
#property description "Script creates the right price label on the chart."
#property description "Anchor point coordinate is set in"
#property description "percentage of the chart window size."
//--- 启动脚本期间显示输入参数的窗口
#property script_show_inputs
//--- 脚本的输入参数
input string InpName="RightPrice"; // 价格标签名称
input int InpDate=0; // 定位点日期在%
input int InpPrice=90; // 定位点价格在 %
input color InpColor=clrRed; // 价格标签颜色
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // 边界线条风格
input int InpWidth=2; // 价格标签大小
input bool InpBack=false; // 背景标签
input bool InpSelection=true; // 突出移动
input bool InpHidden=true; // 隐藏对象列表中
input long InpZOrder=0; // 鼠标单击优先
//+------------------------------------------------------------------+
//| 创建向右价格标签 |
//+------------------------------------------------------------------+
bool ArrowRightPriceCreate(const long chart_ID=0, // 图表 ID
const string name="RightPrice", // 价格标签名称
const int sub_window=0, // 子窗口指数
datetime time=0, // 定位点时间
double price=0, // 定位点价格
const color clr=clrRed, // 价格标签颜色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 边界线条风格
const int width=1, // 价格标签大小
const bool back=false, // 在背景中
const bool selection=true, // 突出移动
const bool hidden=true, // 隐藏在对象列表
const long z_order=0) // 鼠标单击优先
{
//--- 若未设置则设置定位点的坐标
ChangeArrowEmptyPoint(time,price);
//--- 重置错误的值
ResetLastError();
//--- 创建价格标签
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_RIGHT_PRICE,sub_window,time,price))
{
Print(__FUNCTION__,
": failed to create the right price label! Error code = ",GetLastError());
return(false);
}
//--- 设置标签颜色
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 设置边界线条风格
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 设置标签大小
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 显示前景 (false) 或背景 (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 启用 (true) 或禁用 (false) 通过鼠标移动标签的模式
//--- 当使用ObjectCreate函数创建图形对象时，对象不能
//--- 默认下突出并移动。在这个方法中，默认选择参数
//--- true 可以突出移动对象
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 在对象列表隐藏(true) 或显示 (false) 图形对象名称
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 设置在图表中优先接收鼠标点击事件
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 成功执行
return(true);
}
//+------------------------------------------------------------------+
//| 移动定位点 |
//+------------------------------------------------------------------+
bool ArrowRightPriceMove(const long chart_ID=0, // 图表 ID
const string name="RightPrice", // 标签名称
datetime time=0, // 定位点时间坐标
double price=0) // 定位点价格坐标
{
//--- 如果没有设置点的位置，则将其移动到当前的卖价柱
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 重置错误的值
ResetLastError();
//--- 移动定位点
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 成功执行
return(true);
}
//+------------------------------------------------------------------+
//| 从图表删除向右价格标签 |
//+------------------------------------------------------------------+
bool ArrowRightPriceDelete(const long chart_ID=0, // 图表 ID
const string name="RightPrice") // 标签名称
{
//--- 重置错误的值
ResetLastError();
//--- 删除标签
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete the right price label! Error code = ",GetLastError());
return(false);
}
//--- 成功执行
return(true);
}
//+------------------------------------------------------------------+
//| 检查定位点的值和为空点设置 |
//| 默认的值 |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- 如果点的时间没有设置，它将位于当前柱
if(!time)
time=TimeCurrent();
//--- 如果点的价格没有设置，则它将用卖价值
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| 脚本程序起始函数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 检查输入参数的正确性
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- 图表窗口的可见柱的数量
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 价格数组大小
int accuracy=1000;
//--- 存储要使用的日期和价格值的数组
//--- 用于设置和改变标签定位点坐标
datetime date[];
double price[];
//--- 内存分配
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 填写日期数组
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 填写价格数组
//--- 找出图表的最高值和最低值
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 定义变化的价格并填写该数组
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 定义绘制标签的点
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- 在图表上创建向右价格标签
if(!ArrowRightPriceCreate(0,InpName,0,date[d],price[p],InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 重画图表并等待1秒
ChartRedraw();
Sleep(1000);
//--- 现在，移动定位点
//--- 循环计数器
int v_steps=accuracy*4/5;
//--- 移动定位点
for(int i=0;i<v_steps;i++)
{
//--- 使用下面的值
if(p>1)
p-=1;
//--- 移动点
if(!ArrowRightPriceMove(0,InpName,date[d],price[p]))
return;
//--- 检查脚本操作是否已经强制禁用
if(IsStopped())
return;
//--- 重画图表
ChartRedraw();
}
//--- 1 秒延迟
Sleep(1000);
//--- 从图表删除标签
ArrowRightPriceDelete(0,InpName);
ChartRedraw();
//--- 1 秒延迟
Sleep(1000);
//---
}
|
