FileWrite

uint  FileWrite(
   int  file_handle,     // handle файла
   ...                   // список записываемых параметров
   );

//+------------------------------------------------------------------+
//|                                               Demo_FileWrite.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- параметры для получения данных из терминала
input string             InpSymbolName="EURUSD";           // валютная пара
input ENUM_TIMEFRAMES    InpSymbolPeriod=PERIOD_H1;        // таймфрейм
input int                InpFastEMAPeriod=12;              // период быстрой средней
input int                InpSlowEMAPeriod=26;              // период медленной средней
input int                InpSignalPeriod=9;                // период усреднения разности
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE;      // тип цены
input datetime           InpDateStart=D'2012.01.01 00:00'; // дата начала копирования данных
//--- параметры для записи данных в файл
input string             InpFileName="MACD.csv";  // имя файла
input string             InpDirectoryName="Data"; // имя директории
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish; // дата конца копирования данных
   bool     sign_buff[]; // массив сигналов (true - покупка, false - продажа)
   datetime time_buff[]; // массив времени наступления сигналов
   int      sign_size=0; // размер массивов сигналов
   double   macd_buff[]; // массив значений индикатора
   datetime date_buff[]; // массив дат индикатора
   int      macd_size=0; // размер массивов индикатора
//--- время окончания - текущее
   date_finish=TimeCurrent();
//--- получим хэндл индикатора MACD
   ResetLastError();
   int macd_handle=iMACD(InpSymbolName,InpSymbolPeriod,InpFastEMAPeriod,InpSlowEMAPeriod,InpSignalPeriod,InpAppliedPrice);
   if(macd_handle==INVALID_HANDLE)
     {
      //--- не удалось получить хэндл индикатора
      PrintFormat("Ошибка получения хэндла индикатора. Код ошибки = %d",GetLastError());
      return;
     }
//--- находимся в цикле, пока индикатор не рассчитает все свои значения
   while(BarsCalculated(macd_handle)==-1)
      Sleep(10); // задержка, чтобы индикатор успел вычислить свои значения
//--- скопируем значения индикатора за определенный период
   ResetLastError();
   if(CopyBuffer(macd_handle,0,InpDateStart,date_finish,macd_buff)==-1)
     {
      PrintFormat("Не удалось скопировать значения индикатора. Код ошибки = %d",GetLastError());
      return;
     }
//--- скопируем соответствующее время для значений индикатора
   ResetLastError();
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
     {
      PrintFormat("Не удалось скопировать значения времени. Код ошибки = %d",GetLastError());
      return;
     }
//--- освободим память, занимаемую индикатором
   IndicatorRelease(macd_handle);
//--- получим размер буфера
   macd_size=ArraySize(macd_buff);
//--- проанализируем данные и сохраним сигналы индикатора в массивы
   ArrayResize(sign_buff,macd_size-1);
   ArrayResize(time_buff,macd_size-1);
   for(int i=1;i<macd_size;i++)
     {
      //--- сигнал на покупку
      if(macd_buff[i-1]<0 && macd_buff[i]>=0)
        {
         sign_buff[sign_size]=true;
         time_buff[sign_size]=date_buff[i];
         sign_size++;
        }
      //--- сигнал на продажу
      if(macd_buff[i-1]>0 && macd_buff[i]<=0)
        {
         sign_buff[sign_size]=false;
         time_buff[sign_size]=date_buff[i];
         sign_size++;
        }
     }
//--- откроем файл для записи значений индикатора (если его нет, то создастся автоматически)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для записи",InpFileName);
      PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- сначала запишем количество сигналов
      FileWrite(file_handle,sign_size);
      //--- запишем время сигналов и их значения в файл
      for(int i=0;i<sign_size;i++)
         FileWrite(file_handle,time_buff[i],sign_buff[i]);
      //--- закрываем файл
      FileClose(file_handle);
      PrintFormat("Данные записаны, файл %s закрыт",InpFileName);
     }
   else
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
  }