//+------------------------------------------------------------------+
//| Demo_FileIsLineEnding.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots 1
//---- plot Label1
#property indicator_label1 "Overbought & Oversold"
#property indicator_type1 DRAW_COLOR_BARS
#property indicator_color1 clrRed, clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 2
//--- параметры для чтения данных
input string InpFileName="RSI.csv"; // имя файла
input string InpDirectoryName="Data"; // имя директории
//--- индикаторные буферы
double open_buff[];
double high_buff[];
double low_buff[];
double close_buff[];
double color_buff[];
//--- переменные перекупленности
int ovb_ind=0;
int ovb_size=0;
datetime ovb_time[];
//--- переменные перепроданности
int ovs_ind=0;
int ovs_size=0;
datetime ovs_time[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- переменные размеров массивов по умолчанию
int ovb_def_size=100;
int ovs_def_size=100;
//--- выделим память для массивов
ArrayResize(ovb_time,ovb_def_size);
ArrayResize(ovs_time,ovs_def_size);
//--- откроем файл
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_CSV|FILE_ANSI);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("Файл %s открыт для чтения",InpFileName);
PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
double value;
//--- читаем данные из файла
while(!FileIsEnding(file_handle))
{
//--- читаем первое значение в строке
value=FileReadNumber(file_handle);
//--- читаем в разные массивы в зависимости от результата функции
if(value>=70)
ReadData(file_handle,ovb_time,ovb_size,ovb_def_size);
else
ReadData(file_handle,ovs_time,ovs_size,ovs_def_size);
}
//--- закроем файл
FileClose(file_handle);
PrintFormat("Данные прочитаны, файл %s закрыт",InpFileName);
}
else
{
PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
return(INIT_FAILED);
}
//--- привязка массивов
SetIndexBuffer(0,open_buff,INDICATOR_DATA);
SetIndexBuffer(1,high_buff,INDICATOR_DATA);
SetIndexBuffer(2,low_buff,INDICATOR_DATA);
SetIndexBuffer(3,close_buff,INDICATOR_DATA);
SetIndexBuffer(4,color_buff,INDICATOR_COLOR_INDEX);
//---- установка значений индикатора, которые не будут видимы на графике
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Чтение данных строки файла |
//+------------------------------------------------------------------+
void ReadData(const int file_handle,datetime &arr[],int &size,int &def_size)
{
bool flag=false;
//--- читаем пока не дойдем до конца строки или файла
while(!FileIsLineEnding(file_handle) && !FileIsEnding(file_handle))
{
//--- сдвинем каретку, прочитав число
if(flag)
FileReadNumber(file_handle);
//--- запоминаем текущую дату
arr[size]=FileReadDatetime(file_handle);
size++;
//--- при необходимости увеличим размер массива
if(size==def_size)
{
def_size+=100;
ArrayResize(arr,def_size);
}
//--- проскочили первую итерацию
flag=true;
}
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
ArraySetAsSeries(time,false);
ArraySetAsSeries(open,false);
ArraySetAsSeries(high,false);
ArraySetAsSeries(low,false);
ArraySetAsSeries(close,false);
//--- цикл для еще необработанных баров
for(int i=prev_calculated;i<rates_total;i++)
{
//--- по умолчанию 0
open_buff[i]=0;
high_buff[i]=0;
low_buff[i]=0;
close_buff[i]=0;
color_buff[i]=0;
//--- проверка, есть ли еще данные
if(ovb_ind<ovb_size)
for(int j=ovb_ind;j<ovb_size;j++)
{
//--- если даты совпадают, то бар лежит в зоне перекупленности
if(time[i]==ovb_time[j])
{
open_buff[i]=open[i];
high_buff[i]=high[i];
low_buff[i]=low[i];
close_buff[i]=close[i];
//--- 0 - красный цвет
color_buff[i]=0;
//--- увеличим счетчик
ovb_ind=j+1;
break;
}
}
//--- проверка, есть ли еще данные
if(ovs_ind<ovs_size)
for(int j=ovs_ind;j<ovs_size;j++)
{
//--- если даты совпадают, то бар лежит в зоне перепроданности
if(time[i]==ovs_time[j])
{
open_buff[i]=open[i];
high_buff[i]=high[i];
low_buff[i]=low[i];
close_buff[i]=close[i];
//--- 1 - синий цвет
color_buff[i]=1;
//--- увеличим счетчик
ovs_ind=j+1;
break;
}
}
}
//--- return value of prev_calculated for next call
return(rates_total);
}
//+------------------------------------------------------------------+
//| Обработчик события ChartEvent |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
const long &lparam,
const double &dparam,
const string &sparam
)
{
//--- изменяем толщину индикатора в зависимости от масштаба
if(ChartGetInteger(0,CHART_SCALE)>3)
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,2);
else
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,1);
}
|