FileReadDatetime

Читает из файла типа CSV строку одного из форматов: "YYYY.MM.DD HH:MI:SS", "YYYY.MM.DD" или "HH:MI:SS" - и преобразует её в значение типа datetime.

datetime  FileReadDatetime(
   int  file_handle      // handle файла
   );

Параметры

file_handle

[in]  Файловый описатель, возвращаемый функцией FileOpen().

Возвращаемое значение

Значение типа datetime.

Пример (используется файл, полученный в результате работы примера для функции FileWrite)

//+------------------------------------------------------------------+
//|                                        Demo_FileReadDateTime.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//---- plot Label1
#property indicator_label1  "UpSignal"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  4
//---- plot Label2
#property indicator_label2  "DownSignal"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrRed
#property indicator_style2  STYLE_SOLID
#property indicator_width2  4
//--- параметры для чтения данных
input string InpFileName="MACD.csv";  // имя файла
input string InpDirectoryName="Data"// имя директории
//--- глобальные переменные
int      ind=0;       // индекс
double   upbuff[];    // индикаторный буфер стрелок вверх
double   downbuff[];  // индикаторный буфер стрелок вниз
bool     sign_buff[]; // массив сигналов (true - покупка, false - продажа)
datetime time_buff[]; // массив времени наступления сигналов
int      size=0;      // размер массивов сигналов
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- откроем файл
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_CSV);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для чтения",InpFileName);
      //--- сначала прочитаем количество сигналов
      size=(int)FileReadNumber(file_handle);
      //--- выделим память для массивов
      ArrayResize(sign_buff,size);
      ArrayResize(time_buff,size);
      //--- прочитаем данные из файла
      for(int i=0;i<size;i++)
        {
         //--- время сигнала
         time_buff[i]=FileReadDatetime(file_handle);
         //--- значение сигнала
         sign_buff[i]=FileReadBool(file_handle);
        }
      //--- закрываем файл
      FileClose(file_handle);
     }
   else
     {
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
      return(INIT_FAILED);
     }
//--- привязка массивов
   SetIndexBuffer(0,upbuff,INDICATOR_DATA);
   SetIndexBuffer(1,downbuff,INDICATOR_DATA);
//--- зададим код символа для отрисовки в PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,241);
   PlotIndexSetInteger(1,PLOT_ARROW,242);
//---- установка значений индикатора, которые не будут видимы на графике
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   ArraySetAsSeries(time,false);
   ArraySetAsSeries(high,false);
   ArraySetAsSeries(low,false);
//--- цикл для еще необработанных баров
   for(int i=prev_calculated;i<rates_total;i++)
     {
      //--- по умолчанию 0
      upbuff[i]=0;
      downbuff[i]=0;
      //--- проверка, есть ли еще данные
      if(ind<size)
        {
         for(int j=ind;j<size;j++)
           {
            //--- если даты совпадают, то используем значение из файла
            if(time[i]==time_buff[j])
              {
               //--- рисуем стрелку в зависимости от сигнала
               if(sign_buff[j])
                  upbuff[i]=high[i];
               else
                  downbuff[i]=low[i];
               //--- увеличим счетчик
               ind=j+1;
               break;
              }
           }
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }

Смотри также

Тип datetime, StringToTime, TimeToString, FileWrite