//+------------------------------------------------------------------+
//| Demo_FileWrite.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- 端末からデータを受け取るパラメータ
input string InpSymbolName="EURUSD"; // 通貨ペア
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_H1; // 時間軸
input int InpFastEMAPeriod=12; // 高速 EMA 期間
input int InpSlowEMAPeriod=26; // 低速 EMA 期間
input int InpSignalPeriod=9; // 差分平均期間
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE; // 価格の種類
input datetime InpDateStart=D'2012.01.01 00:00'; // データコピー開始日
//--- ファイルにデータを書き込むためのパラメータ
input string InpFileName="MACD.csv"; // ファイル名
input string InpDirectoryName="Data"; // ディレクトリ名
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date_finish; // データコピー終了日
bool sign_buff[]; // シグナル配列（true - 買、false - 売）
datetime time_buff[]; // シグナル到着時の配列
int sign_size=0; // シグナル配列サイズ
double macd_buff[]; // 指標値の配列
datetime date_buff[]; // 指標日付の配列
int macd_size=0; // 指標配列のサイズ
//--- 終了時刻が現在時刻
date_finish=TimeCurrent();
//--- MACD 指標ハンドルを受け取る
ResetLastError();
int macd_handle=iMACD(InpSymbolName,InpSymbolPeriod,InpFastEMAPeriod,InpSlowEMAPeriod,InpSignalPeriod,InpAppliedPrice);
if(macd_handle==INVALID_HANDLE)
{
//--- 指標ハンドルの受け取りに失敗
PrintFormat("Error when receiving indicator handle. Error code = %d",GetLastError());
return;
}
//--- 全ての指標値が計算されるまでループに留まる
while(BarsCalculated(macd_handle)==-1)
Sleep(10); // 指標が全ての値を計算出来るように一時停止
//--- 一定期間の指標値を複製する
ResetLastError();
if(CopyBuffer(macd_handle,0,InpDateStart,date_finish,macd_buff)==-1)
{
PrintFormat("Failed to copy indicator values. Error code = %d",GetLastError());
return;
}
//--- 指標値に適切な時間を複製する
ResetLastError();
if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
{
PrintFormat("Failed to copy time values. Error code = %d",GetLastError());
return;
}
//--- 指標で使用されたメモリを解放する
IndicatorRelease(macd_handle);
//--- バッファサイズを受け取る
macd_size=ArraySize(macd_buff);
//--- データを分析し指標シグナルを配列に保存する
ArrayResize(sign_buff,macd_size-1);
ArrayResize(time_buff,macd_size-1);
for(int i=1;i<macd_size;i++)
{
//--- 買いシグナル
if(macd_buff[i-1]<0 && macd_buff[i]>=0)
{
sign_buff[sign_size]=true;
time_buff[sign_size]=date_buff[i];
sign_size++;
}
//--- 売りシグナル
if(macd_buff[i-1]>0 && macd_buff[i]<=0)
{
sign_buff[sign_size]=false;
time_buff[sign_size]=date_buff[i];
sign_size++;
}
}
//--- 指標値を書き込むためにファイルを開く（ファイルが存在しない場合は自動的に作成される）
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("%s file is available for writing",InpFileName);
PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- 初めにシグナル数を書く
FileWrite(file_handle,sign_size);
//--- シグナルの時間と値をファイルに書く
for(int i=0;i<sign_size;i++)
FileWrite(file_handle,time_buff[i],sign_buff[i]);
//--- ファイルを閉じる
FileClose(file_handle);
PrintFormat("Data is written, %s file is closed",InpFileName);
}
else
PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
}
|