Скачать MetaTrader 5

FileWriteInteger

Записывает в bin-файл значение параметра типа int с текущего положения файлового указателя.

uint  FileWriteInteger(
   int  file_handle,        // handle файла
   int  value,              // записываемое значение
   int  size=INT_VALUE      // размер в байтах
   );

Параметры

file_handle

[in]  Файловый описатель, возвращаемый функцией FileOpen().

value

[in]  Целое значение.

size=INT_VALUE

[in]  Количество байт (до 4 включительно), которые нужно записать. Предусмотрены соответствующие константы: CHAR_VALUE=1, SHORT_VALUE=2 и INT_VALUE=4, таким образом функция может записать целое значение типа char, uchar, short, ushort, int или uint

Возвращаемое значение

В случае удачи функция возвращает количество записанных байт. Файловый указатель перемещается на это же количество байт.

Пример:

//+------------------------------------------------------------------+
//|                                        Demo_FileWriteInteger.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- параметры для получения данных из терминала
input string             InpSymbolName="EURUSD";           // валютная пара
input ENUM_TIMEFRAMES    InpSymbolPeriod=PERIOD_H1;        // таймфрейм
input datetime           InpDateStart=D'2013.01.01 00:00'; // дата начала копирования данных
//--- параметры для записи данных в файл
input string             InpFileName="Trend.bin"// имя файла
input string             InpDirectoryName="Data"// имя директории
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish=TimeCurrent();
   double   close_buff[];
   datetime time_buff[];
   int      size;
//--- сбросим значение ошибки
   ResetLastError();
//--- скопируем цену закрытия для каждого бара
   if(CopyClose(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,close_buff)==-1)
     {
      PrintFormat("Не удалось скопировать значения цен закрытия. Код ошибки = %d",GetLastError());
      return;
     }
//--- скопируем время для каждого бара
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
     {
      PrintFormat("Не удалось скопировать значения времени. Код ошибки = %d",GetLastError());
      return;
     }
//--- получим размер буфера
   size=ArraySize(close_buff);
//--- откроем файл для записи значений (если его нет, то создастся автоматически)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для записи",InpFileName);
      PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- 
      int   up_down=0; // флаг тенденции
      int   arr_size;  // размера массива arr
      uchar arr[];     // массив типа uchar
      //--- запишем значения времени в файл
      for(int i=0;i<size-1;i++)
        {
         //--- сравним цены закрытия на текущем и следующем барах
         if(close_buff[i]<=close_buff[i+1])
           {
            if(up_down!=1)
              {
               //--- запишем значение даты в файл, используя FileWriteInteger
               StringToCharArray(TimeToString(time_buff[i]),arr);
               arr_size=ArraySize(arr);
               //--- сначала запишем количество символов в массиве
               FileWriteInteger(file_handle,arr_size,INT_VALUE);
               //--- запишем сами символы
               for(int j=0;j<arr_size;j++)
                  FileWriteInteger(file_handle,arr[j],CHAR_VALUE);
               //--- изменим флаг тенденции
               up_down=1;
              }
           }
         else
           {
            if(up_down!=-1)
              {
               //--- запишем значение даты в файл, используя FileWriteInteger
               StringToCharArray(TimeToString(time_buff[i]),arr);
               arr_size=ArraySize(arr);
               //--- сначала запишем количество символов в массиве
               FileWriteInteger(file_handle,arr_size,INT_VALUE);
               //--- запишем сами символы
               for(int j=0;j<arr_size;j++)
                  FileWriteInteger(file_handle,arr[j],CHAR_VALUE);
               //--- изменим флаг тенденции
               up_down=-1;
              }
           }
        }
      //--- закрываем файл
      FileClose(file_handle);
      PrintFormat("Данные записаны, файл %s закрыт",InpFileName);
     }
   else
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
  }

Смотри также

IntegerToString, StringToInteger, Целые типы


Обновлено: 2015.12.03