//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- объявляем параметры графического ресурса
string rc_name="Resource";
uint rc_width=100;
uint rc_height=100;
uint rc_data[];
uint rc_size=rc_width*rc_height;
ResetLastError();
//--- устанавливаем размер массива пикселей
if(ArrayResize(rc_data,rc_size)!=rc_size)
{
Print("ArrayResize() failed. Error code: ",GetLastError());
return;
}
//--- заполняем массив пикселей прозрачным цветом и на его основе создаём графический ресурс
ArrayInitialize(rc_data,0x00FFFFFF);
if(!ResourceCreate(rc_name,rc_data,rc_width,rc_height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
{
Print("ResourceCreate() failed. Error code: ",GetLastError());
return;
}
Print("Size of created recource array: ",rc_data.Size());
//--- проверим созданный графический ресурс.
//--- получаем данные времени и цены текущего бара
MqlTick tick={};
if(!SymbolInfoTick(Symbol(),tick))
{
Print("SymbolInfoTick() failed. Error code: ",GetLastError());
return;
}
//--- создаём объект "Рисунок" на координатах цены и времени последнего тика
string obj_name="Bitmap";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP,0,tick.time,tick.bid))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- устанавливаем созданному объекту-рисунку ширину и высоту, равные ширине и высоте графического ресурса.
//--- устанавливаем точку привязки объекта по его центру.
ObjectSetInteger(0,obj_name,OBJPROP_XSIZE,rc_width);
ObjectSetInteger(0,obj_name,OBJPROP_YSIZE,rc_height);
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- указываем для объекта-рисунка в качестве файла изображения ранее созданный графический ресурс
//--- в этом случае для указания имени используемого графического ресурса нужно перед его именем дописать "::"
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"::"+rc_name);
//--- Установим цвет DodgerBlue с прозрачностью 200
uint clr=ColorToARGB(clrDodgerBlue,200);
//--- заполним установленным цветом весь массив пикселей графического ресурса
ArrayInitialize(rc_data,clr);
//--- обновим данные графического ресурса
Update(rc_name,rc_data,rc_width,rc_height,true);
//--- подождём три секунды и сменим цвет изображения
Print("Wait 3 seconds before changing color");
Sleep(3000);
//--- установим цвет OrangeRed с прозрачностью 200
Print("Change color");
clr=ColorToARGB(clrOrangeRed,200);
//--- заполним установленным цветом весь массив пикселей графического ресурса
ArrayInitialize(rc_data,clr);
//--- обновим данные графического ресурса
Update(rc_name,rc_data,rc_width,rc_height,true);
//--- ждём три секунды и освобождаем графический ресурс
Print("Wait 3 seconds before ResourceFree()");
Sleep(3000);
bool res=ResourceFree("::"+rc_name);
Print("ResourceFree: ",res);
//--- пробуем поменять цвет после освобождения ресурса
Print("Trying to change color to GreenYellow after ResourceFree()");
//--- установим цвет GreenYellow с прозрачностью 200
clr=ColorToARGB(clrGreenYellow,200);
//--- заполним установленным цветом весь массив пикселей графического ресурса
ArrayInitialize(rc_data,clr);
//--- обновим данные графического ресурса (рисунок остаётся, но цвет изменить уже невозможно)
Update(rc_name,rc_data,rc_width,rc_height,true);
Print("The color has not changed because the resource has been released");
//--- ждём три секунды и удаляем объект-рисунок
Print("Wait 3 seconds before deleting the Bitmap object");
Sleep(3000);
Print("Delete Bitmap object");
ObjectDelete(0,obj_name);
}
//+------------------------------------------------------------------+
//| Обновляем данные графического ресурса |
//+------------------------------------------------------------------+
void Update(const string res_name,const uint &pixel_data[],const uint width,const uint height,const bool redraw)
{
//--- если переданы нулевые размеры - уходим
if(width==0 || height==0)
return;
//--- обновляем ресурсные данные и перерисовываем график
if(ResourceCreate(res_name,pixel_data,width,height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
|