//--- параметры графического ресурса
string ExtResName="Resource";
int ExtResWidth=100;
int ExtResHeight=100;
uint ExtResData[];
int ExtResSize=ExtResWidth*ExtResHeight;
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
ResetLastError();
//--- устанавливаем размер массива пикселей
if(ArrayResize(ExtResData,ExtResSize)!=ExtResSize)
{
Print("ArrayResize() failed. Error code: ",GetLastError());
return;
}
//--- заполняем массив пикселей прозрачным цветом и на его основе создаём графический ресурс
ArrayInitialize(ExtResData,0x00FFFFFF);
if(!ResourceCreate(ExtResName,ExtResData,ExtResWidth,ExtResHeight,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
{
Print("ResourceCreate() failed. Error code: ",GetLastError());
return;
}
Print("Size of created recource array: ",ExtResData.Size());
//--- проверим созданный графический ресурс.
//--- получаем данные времени и цены текущего бара
MqlTick tick={};
if(!SymbolInfoTick(Symbol(),tick))
{
Print("SymbolInfoTick() failed. Error code: ",GetLastError());
return;
}
//--- cоздаём объект "Рисунок" на координатах цены и времени последнего тика
string obj_name="Bitmap";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP,0,tick.time,tick.bid))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- устанавливаем созданному объекту-рисунку ширину и высоту, равные ширине и высоте графического ресурса.
//--- устанавливаем точку привязки объекта по его центру.
ObjectSetInteger(0,obj_name,OBJPROP_XSIZE,ExtResWidth);
ObjectSetInteger(0,obj_name,OBJPROP_YSIZE,ExtResHeight);
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- указываем для объекта-рисунка в качестве файла изображения ранее созданный графический ресурс
//--- в этом случае для указания имени используемого графического ресурса нужно перед его именем дописать "::"
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"::"+ExtResName);
//--- установим цвет GreenYellow с прозрачностью 200
uint clr=ColorToARGB(clrGreenYellow,200);
//--- заполним установленным цветом весь массив пикселей графического ресурса
ArrayInitialize(ExtResData,clr);
//--- нарисуем сетку цветом DodgerBlue
for(int x=0;x<ExtResWidth;x+=9)
LineVertical(x,0,ExtResHeight,ColorToARGB(clrDodgerBlue,200));
for(int y=0;y<ExtResHeight;y+=9)
LineHorizontal(0,ExtResWidth,y,ColorToARGB(clrDodgerBlue,200));
//--- обновим данные графического ресурса
Update(ExtResName,ExtResData,ExtResWidth,ExtResHeight,true);
//--- подождём 3 секунды перед удалением ресурса и графического объекта
Print("Wait 3 seconds before deleting the resource and graphic object");
Sleep(3000);
//--- сохраним ресурс в файле
ResetLastError();
if(!ResourceSave("::"+ExtResName,"ResourceSave\\"+ExtResName+".bmp"))
{
Print("ResourceSave() failed. Error code: ",GetLastError());
return;
}
//--- удалим ресурс и графический объект-рисунок
if(!ResourceFree("::"+ExtResName))
{
Print("ResourceFree() failed. Error code: ",GetLastError());
return;
}
if(!ObjectDelete(0,obj_name))
{
Print("ObjectDelete() failed. Error code: ",GetLastError());
return;
}
//--- теперь создадим новый объект "Графическая метка" на координатах цены и времени последнего тика, смещённый влево на ширину изображения
//--- получим экранные координаты по ранее полученным цене и времени последнего тика
int x=0,y=0;
if(!ChartTimePriceToXY(0,0,tick.time,tick.bid,x,y))
{
Print("ChartTimePriceToXY() failed. Error code: ",GetLastError());
return;
}
obj_name="BitmapLabel";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP_LABEL,0,0,0))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- устанавливаем точку привязки объекта по его центру.
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- устанавливаем объекту-графической метке координаты цены и времени последнего тика, смещённые влево на ширину изображения
ObjectSetInteger(0,obj_name,OBJPROP_XDISTANCE,x-ExtResWidth);
ObjectSetInteger(0,obj_name,OBJPROP_YDISTANCE,y);
//--- указываем для объекта-графической метки в качестве файла изображения ранее сохранённый ресурс как bmp-изображение
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"\\Files\\ResourceSave\\"+ExtResName+".bmp");
//--- обновляем график
ChartRedraw();
//--- подождём 3 секунды перед удалением объекта-графической метки
Print("Wait 3 seconds before deleting the new graphic object");
Sleep(3000);
if(!ObjectDelete(0,obj_name))
Print("ObjectDelete() failed. Error code: ",GetLastError());
}
//+------------------------------------------------------------------+
//| Обновляет данные графического ресурса |
//+------------------------------------------------------------------+
void Update(const string res_name,const uint &pixel_data[],const uint width,const uint height,const bool redraw)
{
//--- если переданы нулевые размеры - уходим
if(width==0 || height==0)
return;
//--- обновляем ресурсные данные и перерисовываем график
if(ResourceCreate(res_name,pixel_data,width,height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
//+------------------------------------------------------------------+
//| Рисует вертикальную линию |
//+------------------------------------------------------------------+
void LineVertical(int x,int y1,int y2,const uint clr)
{
int tmp;
//--- сортировка по Y
if(y1>y2)
{
tmp=y1;
y1 =y2;
y2 =tmp;
}
//--- линия за границами картинки
if(y2<0 || y1>=ExtResHeight || x<0 || x>=ExtResWidth)
return;
//--- остаемся внутри границ картинки
if(y1<0)
y1=0;
if(y2>=ExtResHeight)
y2=ExtResHeight-1;
//--- рисуем линию
int index=y1*ExtResWidth+x;
for(int i=y1; i<=y2; i++,index+=ExtResWidth)
ExtResData[index]=clr;
}
//+------------------------------------------------------------------+
//| Рисует горизонтальную линию |
//+------------------------------------------------------------------+
void LineHorizontal(int x1,int x2,int y,const uint clr)
{
int tmp;
//--- сортировка по X
if(x1>x2)
{
tmp=x1;
x1 =x2;
x2 =tmp;
}
//--- линия за границами картинки
if(x2<0 || x1>=ExtResWidth || y<0 || y>=ExtResHeight)
return;
//--- остаемся внутри границ картинки
if(x1<0)
x1=0;
if(x2>=ExtResWidth)
x2=ExtResWidth-1;
//--- рисуем линию
ArrayFill(ExtResData,y*ExtResWidth+x1,(x2-x1)+1,clr);
}
|