Скачать MetaTrader 5

GetTickCount

Функция GetTickCount() возвращает количество миллисекунд, прошедших с момента старта системы.

uint  GetTickCount();

Возвращаемое значение

Значение типа uint.

Примечание

Счетчик ограничен разрешающей способностью системного таймера. Так как время хранится как беззнаковое целое, то он переполняется каждые 49.7 дней при непрерывной работе компьютера.

Пример:

#define MAX_SIZE 40
//+------------------------------------------------------------------+
//| скрипт для замера времени вычисления 40 чисел Фибоначчи          |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- запомним начальное значение
   uint start=GetTickCount();
//--- переменная для получения очередного числа из ряда Фибоначчи
   long fib=0;
//--- цикл, в котором вычисляем заданное количество чисел из ряда Фибоначчи
   for(int i=0;i<MAX_SIZE;i++) fib=TestFibo(i);
//--- получим затраченное время в миллисекундах
   uint time=GetTickCount()-start;
//--- выведем в журнал "Эксперты" сообщение
   PrintFormat("Вычисление %d первых чисел Фибоначчи заняло %d ms",MAX_SIZE,time);
//--- работа скрипта завершена
   return;
  }
//+------------------------------------------------------------------+
//| Функция получения числа Фибоначчи по его порядковому номеру      |
//+------------------------------------------------------------------+
long TestFibo(long n)
  {
//--- первый член ряда Фибоначчи
   if(n<2) return(1);
//--- все последующие члены вычисляются по этой формуле
   return(TestFibo(n-2)+TestFibo(n-1));
  }

Смотри также

Дата и время


Обновлено: 2015.12.03