FileLoad

Ele lê todo o conteúdo do arquivo binário especificado numa variedade transferida de tipos numéricos ou estruturas simples. A função permite ler rapidamente os dados de um tipo conhecido na matriz apropriada.

long  FileLoad(
   const string  file_name,         // nome do arquivo
   void&         buffer[],          // matriz de tipos numéricos ou estruturas simples
   int           common_flag=0      // sinalizador de arquivo, por padrão o arquivo é localizado na pasta <diretório_de_dados>\MQL5\Files\
   );

Parâmetros

file_name

[in]  Nome do arquivo a partir do qual serão lidos os dados.

buffer

[out]  Matriz de tipos numéricos ou estruturas simples.

common_flag=0

[in] Sinalizador de arquivo que indica o modo de trabalho. Se este parâmetro não for especificado, o arquivo é procurado na subpasta MQL5\Files (ou <diretório_do_agente_de_teste>\MQL5\Files em caso de teste).

Valor de retorno

Número de elementos lidos ou -1 em caso de falha.

Observação

A função FileLoad() lê, a partir do arquivo, o número de bytes múltiplo do tamanho da matriz. Por exemplo, suponha que o tamanho do arquivo é 10 bytes e a leitura de dados é realizada numa matriz do tipo double (sizeof(double)=8). Neste caso, você vai ler apenas 8 bytes, os restantes 2 bytes no final do arquivo serão simplesmente descartados e a função FileLoad() retornará 1 (lido 1 elemento).

Exemplo:

//+------------------------------------------------------------------+
//|                                                Demo_FileLoad.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property script_show_inputs
//--- input parameters
input int      bars_to_save=10; // número de barras
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string  filename=_Symbol+"_rates.bin";
   MqlRates rates[];
//---
   int copied=CopyRates(_Symbol,_Period,0,bars_to_save,rates);
   if(copied!=-1)
     {
      PrintFormat(" CopyRates(%s) copied %d bars",_Symbol,copied);
      //---  escrevemos as cotações no arquivo
      if(!FileSave(filename,rates,FILE_COMMON))
         PrintFormat("FileSave() failed, error=%d",GetLastError());
     }
   else
      PrintFormat("Failed CopyRates(%s), error=",_Symbol,GetLastError());
//--- agora lemos estas cotações de volta para o arquivo
   ArrayFree(rates);
   long count=FileLoad(filename,rates,FILE_COMMON);
   if(count!=-1)
     {
      Print("Time\tOpen\tHigh\tLow\tClose\tTick Voulme\tSpread\tReal Volume");
      for(int i=0;i<count;i++)
        {
         PrintFormat("%s\t%G\t%G\t%G\t%G\t%I64u\t%d\t%I64u",
                     TimeToString(rates[i].time,TIME_DATE|TIME_SECONDS),
                     rates[i].open,rates[i].high,rates[i].low,rates[i].close,
                     rates[i].tick_volume,rates[i].spread,rates[i].real_volume);
        }
     }
  }

Veja também

Estruturas e classes, FileReadArray, FileReadStruct, FileSave