DocumentaçãoSeções
Referência MQL5Funções de ArquivoFileIsEnding 

FileIsEnding

Define o final do arquivo em processo de leitura.

bool  FileIsEnding(
   int  file_handle      // Manipulador de arquivo
   );

Parâmetros

file_handle

[in]  Descritor de arquivo retornado pelo FileOpen().

Valor do Retorno

A função retorna verdadeiro se o fim do arquivo foi alcançado no processo de leitura ou em movimento do ponteiro de arquivo.

Observação

Para definir o final do arquivo, a função tenta ler a próxima string a partir dele. Se a string não existe, a função retorna true, caso contrário, retorna false.

Exemplo:

//--- mostrar a janela de parâmetros de entrada quando do lançamento do script
#property script_show_inputs
//--- parâmetros de entrada
input string InpFileName="file.txt";    // nome do arquivo
input string InpDirectoryName="Data";   // nome do diretório
input int    InpEncodingType=FILE_ANSI; // ANSI=32 ou UNICODE=64
//+------------------------------------------------------------------+
//| Programa Script da função start (iniciar)                        |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Imprimir o caminho para o arquivo que vamos usar
   PrintFormat("Trabalhando %s\\Arquivos\\ pasta",TerminalInfoString(TERMINAL_DATA_PATH));
//--- redefine o valor de erro
   ResetLastError();
//--- abrir um arquivo para leitura(se não existe arquivo, ocorrerá um erro)
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_TXT|InpEncodingType);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- imprimir o conteúdo do arquivo
      while(!FileIsEnding(file_handle))
         Print(FileReadString(file_handle));
      //--- fechar o arquivo
      FileClose(file_handle);
     }
   else
      PrintFormat("Erro, código = %d",GetLastError());
  }