DocumentaçãoSeções
Referência MQL5Funções de ArquivoFileReadInteger 

FileReadInteger

Lê de um arquivo binário um valor do tipo int, short ou char, dependendo do tamanho especificado em bytes. A leitura é feita a partir da posição atual do ponteiro do arquivo.

Lê de um arquivo CSV uma string da posição atual até o separador (ou até o fim da linha de texto) e converte a string lida para um valor do tipo int, short ou char, dependendo do tamanho especificado em bytes.

int  FileReadInteger(
   int  file_handle,        // Manipular Arquivo
   int  size=INT_VALUE      // Tamanho de um inteiro em bytes
   );

Parâmetros

file_handle

[in]  Descritor de arquivo retornado pelo FileOpen().

size=INT_VALUE

[in]  Número de bytes (até 4 inclusive), que devem ser lidos. As constantes correspondentes são fornecidos: CHAR_VALUE = 1, SHORT_VALUE = 2 e INT_VALUE = 4, então a função pode ler todo o valor do tipo char, short ou int.

Valor do Retorno

Um valor do tipo int. O resultado desta função deve ser explicitamente convertido para um tipo de destino, ou seja, para o tipo de dados que você precisa ler. Uma vez que um valor do tipo int é retornado, ele pode ser facilmente convertido para qualquer valor inteiro. O ponteiro do arquivo é deslocado pelo número de bytes lidos.

Equivalente à chamada da função FileRead com um parâmetro do tipo char, short ou int. Para ler dados do tipo uint de forma garantida, recomenda-se usar FileRead com o parâmetro correspondente.

char char_value;
FileRead(file_handle,char_value);
short short_value;
FileRead(file_handle,short_value);
uint uint_value;
FileRead(file_handle,uint_value);

Observação

Para obter informações sobre o erro, chame a função GetLastError().

Quando ler menos do que 4 bytes, o resultado recebido é sempre positivo. Se um ou dois bytes são lidos, o sinal do número pode ser determinado por colagem explícita do tipo char (1 byte) ou short (2 bytes). Recebendo o sinal para um número de três bytes não é simples, uma vez que não há nenhuma correspondente tipo subjacente.

Exemplo (o arquivo obtido após a execução do exemplo pela função FileWriteInteger é usado aqui)

//+------------------------------------------------------------------+
//|                                         Demo_FileReadInteger.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//---- Plotar Etiqueta1
#property indicator_label1  "Trends"
#property indicator_type1   DRAW_SECTION
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- paramêtros para leitura de dados
input string InpFileName="Trend.bin"; // file name
input string InpDirectoryName="Data"; // nome do diretório
//--- variáveis globais
int      ind=0;
int      size=0;
datetime time_buff[];
//--- buffers do indicador
double   buff[];
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
   int def_size=100;
//--- alocar memória para o array
   ArrayResize(time_buff,def_size);
//--- abre o arquivo
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s arquivo está disponível para leitura",InpFileName);
      PrintFormat("Caminho do arquivo: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- variáveis ​​adicionais
      int    arr_size;
      uchar  arr[];
      //--- ler dados de um arquivo
      while(!FileIsEnding(file_handle))
        {
         //--- descobrir quantos símbolos são usados ​​para escrever o tempo
         arr_size=FileReadInteger(file_handle,INT_VALUE);
         ArrayResize(arr,arr_size);
         for(int i=0;i<arr_size;i++)
            arr[i]=(char)FileReadInteger(file_handle,CHAR_VALUE);
         //--- armazenar o valor de tempo
         time_buff[size]=StringToTime(CharArrayToString(arr));
         size++;
         //--- aumentar as dimensões arrays, se são transbordados
         if(size==def_size)
           {
            def_size+=100;
            ArrayResize(time_buff,def_size);
           }
        }
      //--- fechar o arquivo
      FileClose(file_handle);
      PrintFormat("Dados são lidos, %s arquivo está fechado",InpFileName);
     }
   else
     {
      PrintFormat("Falha para abrir %s arquivo, Código de erro = %d",InpFileName,GetLastError());
      return(INIT_FAILED);
     }
//--- ligar array para buffer de indicador
   SetIndexBuffer(0,buff,INDICATOR_DATA);
//---- definir os valores dos indicadores que não serão visíveis no gráfico
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   ArraySetAsSeries(time,false);
   ArraySetAsSeries(close,false);
//---o loop para as barras que ainda não foram manipuladas
   for(int i=prev_calculated;i<rates_total;i++)
     {
      //--- 0 por padrão
      buff[i]=0;
      //---verificar se todos os dados ainda estão presente
      if(ind<size)
        {
         for(int j=ind;j<size;j++)
           {
            //--- se as datas coincidem, usar o valor do arquivo
            if(time[i]==time_buff[j])
              {
               //--- receber o preço
               buff[i]=close[i];
               //--- aumentar o contador
               ind=j+1;
               break;
              }
           }
        }
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }

Também Veja

IntegerToString, StringToInteger, Tipos inteiros, FileWriteInteger

FileReadFloat
FileReadLong