FileReadLong

long  FileReadLong(
   int  file_handle    // Manipular arquivo
   );

//+------------------------------------------------------------------+
//|                                            Demo_FileReadLong.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_buffers 1
#property indicator_plots   1
//---- Plotar Etiqueta1
#property indicator_label1  "Volume"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrYellow
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
#property indicator_separate_window
//--- paramêtros para leitura de dados
input string InpFileName="Volume.bin"; // file name
input string InpDirectoryName="Data";  // directory name
//--- variáveis globais
int      ind=0;
int      size=0;
long     volume_buff[];
datetime time_buff[];
//--- buffers do indicador
double   buff[];
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- abre o arquivo
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s arquivo está aberto para escrita",InpFileName);
      PrintFormat("Caminho do arquivo: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- em primeiro lugar, ler a quantidade de dados no arquivo
      size=(int)FileReadLong(file_handle);
      //--- alocar memória para os arrays
      ArrayResize(volume_buff,size);
      ArrayResize(time_buff,size);
      //--- ler dados de um arquivo
      for(int i=0;i<size;i++)
        {
         time_buff[i]=(datetime)FileReadLong(file_handle);
         volume_buff[i]=FileReadLong(file_handle);
        }
      //--- fechar o arquivo
      FileClose(file_handle);
      PrintFormat("Dados são lidos, %s arquivo está fechado",InpFileName);
     }
   else
     {
      PrintFormat("Falha para abrir %s arquivo, Código de erro = %d",InpFileName,GetLastError());
      return(INIT_FAILED);
     }
//--- associa o array ao buffer do indicador com índice 0
   SetIndexBuffer(0,buff,INDICATOR_DATA);
//---- definir os valores dos indicadores que serão visíveis no gráfico
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   ArraySetAsSeries(time,false);
//---o loop para as barras que ainda não foram manipuladas
   for(int i=prev_calculated;i<rates_total;i++)
     {
      //--- 0 por padrão
      buff[i]=0;
      //---verificar se todos os dados ainda estão presente
      if(ind<size)
        {
         for(int j=ind;j<size;j++)
           {
            //--- se as datas coincidem, usar o valor do arquivo
            if(time[i]==time_buff[j])
              {
               buff[i]=(double)volume_buff[j];
               ind=j+1;
               break;
              }
           }
        }
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }