//+------------------------------------------------------------------+
//| Demo_FileReadBool.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 2
//---- Plotar Etiqueta1
#property indicator_label1 "UpSignal"
#property indicator_type1 DRAW_ARROW
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 4
//---- plotar Label2
#property indicator_label2 "DownSignal"
#property indicator_type2 DRAW_ARROW
#property indicator_color2 clrRed
#property indicator_style2 STYLE_SOLID
#property indicator_width2 4
//--- paramêtros para leitura de dados
input string InpFileName="MACD.csv"; // file name
input string InpDirectoryName="Data"; // nome do diretório
//--- variáveis globais
int ind=0; // índice
double upbuff[]; // buffers indicador de setas para cima
double downbuff[]; // buffers indicador de setas para baix
bool sign_buff[]; // sinal array (verdadeiro - comprar, falso - vender)
datetime time_buff[]; // conjunto de chegada dos sinais time
int size=0; // tamanho de arrays de sinal
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado |
//+------------------------------------------------------------------+
int OnInit()
{
//--- abre o arquivo
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_CSV);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("%s arquivo esta aberto para leitura",InpFileName);
//--- em primeiro lugar, ler o número de sinais
size=(int)FileReadNumber(file_handle);
//--- alocar memória para os arrays
ArrayResize(sign_buff,size);
ArrayResize(time_buff,size);
//--- ler dados de um arquivo
for(int i=0;i<size;i++)
{
//--- tempo de sinal
time_buff[i]=FileReadDatetime(file_handle);
//--- valor do sinal
sign_buff[i]=FileReadBool(file_handle);
}
//--- fechar o arquivo
FileClose(file_handle);
}
else
{
PrintFormat("Falha para abrir %s arquivo, Código de erro = %d",InpFileName,GetLastError());
return(INIT_FAILED);
}
//--- ligando as arrays
SetIndexBuffer(0,upbuff,INDICATOR_DATA);
SetIndexBuffer(1,downbuff,INDICATOR_DATA);
//--- definir o código símbolo para desenho em PLOT_ARROW
PlotIndexSetInteger(0,PLOT_ARROW,241);
PlotIndexSetInteger(1,PLOT_ARROW,242);
//---- definir os valores dos indicadores que não serão vistos no gráfico
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0);
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
ArraySetAsSeries(time,false);
ArraySetAsSeries(low,false);
ArraySetAsSeries(high,false);
//---o loop para as barras que ainda não foram manipuladas
for(int i=prev_calculated;i<rates_total;i++)
{
//--- 0 por padrão
upbuff[i]=0;
downbuff[i]=0;
//---verificar se todos os dados ainda estão presente
if(ind<size)
{
for(int j=ind;j<size;j++)
{
//--- se as datas coincidem, usar o valor do arquivo
if(time[i]==time_buff[j])
{
//--- desenhar a seta de acordo com o sinal
if(sign_buff[j])
upbuff[i]=high[i];
else
downbuff[i]=low[i];
//--- aumentar o contador
ind=j+1;
break;
}
}
}
}
//--- valor retorno de prev_calculated para a próxima chamada
return(rates_total);
}
|