//--- parâmetros do recurso gráfico
string ExtResName="Resource";
int ExtResWidth=100;
int ExtResHeight=100;
uint ExtResData[];
int ExtResSize=ExtResWidth*ExtResHeight;
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
ResetLastError();
//--- definimos o tamanho do array de pixels
if(ArrayResize(ExtResData,ExtResSize)!=ExtResSize)
{
Print("ArrayResize() failed. Error code: ",GetLastError());
return;
}
//--- preenchemos o array de pixels com cor transparente e com base nele criamos um recurso gráfico
ArrayInitialize(ExtResData,0x00FFFFFF);
if(!ResourceCreate(ExtResName,ExtResData,ExtResWidth,ExtResHeight,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
{
Print("ResourceCreate() failed. Error code: ",GetLastError());
return;
}
Print("Size of created recource array: ",ExtResData.Size());
//--- verificamos o recurso gráfico criado
//--- obtemos os dados de tempo e preço da barra atual
MqlTick tick={};
if(!SymbolInfoTick(Symbol(),tick))
{
Print("SymbolInfoTick() failed. Error code: ",GetLastError());
return;
}
//--- criamos um objeto "Desenho" nas coordenadas de preço e tempo do último tick
string obj_name="Bitmap";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP,0,tick.time,tick.bid))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- definimos para o objeto-desenho a largura e a altura iguais às do recurso gráfico.
//--- definimos o ponto de ancoragem do objeto pelo seu centro.
ObjectSetInteger(0,obj_name,OBJPROP_XSIZE,ExtResWidth);
ObjectSetInteger(0,obj_name,OBJPROP_YSIZE,ExtResHeight);
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- especificamos para o objeto-desenho o arquivo de imagem do recurso gráfico criado anteriormente
//--- neste caso, para indicar o nome do recurso gráfico usado, deve-se escrever "::" antes de seu nome
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"::"+ExtResName);
//--- definimos a cor GreenYellow com transparência de 200
uint clr=ColorToARGB(clrGreenYellow,200);
//--- preenchemos com a cor definida todo o array de pixels do recurso gráfico
ArrayInitialize(ExtResData,clr);
//--- traçamos a grade com a cor DodgerBlue
for(int x=0;x<ExtResWidth;x+=9)
LineVertical(x,0,ExtResHeight,ColorToARGB(clrDodgerBlue,200));
for(int y=0;y<ExtResHeight;y+=9)
LineHorizontal(0,ExtResWidth,y,ColorToARGB(clrDodgerBlue,200));
//--- atualizamos os dados do recurso gráfico
Update(ExtResName,ExtResData,ExtResWidth,ExtResHeight,true);
//--- aguardamos 3 segundos antes de excluir o recurso e o objeto gráfico
Print("Wait 3 seconds before deleting the resource and graphic object");
Sleep(3000);
//--- salvamos o recurso em um arquivo
ResetLastError();
if(!ResourceSave("::"+ExtResName,"ResourceSave\\"+ExtResName+".bmp"))
{
Print("ResourceSave() failed. Error code: ",GetLastError());
return;
}
//--- excluimos o recurso e o objeto desenho
if(!ResourceFree("::"+ExtResName))
{
Print("ResourceFree() failed. Error code: ",GetLastError());
return;
}
if(!ObjectDelete(0,obj_name))
{
Print("ObjectDelete() failed. Error code: ",GetLastError());
return;
}
//--- criamos um objeto "Marca Gráfica" nas coordenadas de preço e tempo do último tick, deslocado para a esquerda conforme a largura da imagem
//--- obtemos as coordenadas de tela com base no preço e tempo obtidos anteriormente
int x=0,y=0;
if(!ChartTimePriceToXY(0,0,tick.time,tick.bid,x,y))
{
Print("ChartTimePriceToXY() failed. Error code: ",GetLastError());
return;
}
obj_name="BitmapLabel";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP_LABEL,0,0,0))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- definimos o ponto de ancoragem do objeto pelo seu centro.
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- definimos as coordenadas do preço e da hora do último tick, deslocadas para a esquerda conforme a largura da imagem, para o objeto marca gráfica
ObjectSetInteger(0,obj_name,OBJPROP_XDISTANCE,x-ExtResWidth);
ObjectSetInteger(0,obj_name,OBJPROP_YDISTANCE,y);
//--- para o objeto marca gráfica como um arquivo de imagem, especificamos o recurso salvo anteriormente como imagem bmp
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"\\Files\\ResourceSave\\"+ExtResName+".bmp");
//--- atualizamos o gráfico
ChartRedraw();
//--- aguardamos 3 segundos antes de excluir o objeto marca gráfica
Print("Wait 3 seconds before deleting the new graphic object");
Sleep(3000);
if(!ObjectDelete(0,obj_name))
Print("ObjectDelete() failed. Error code: ",GetLastError());
}
//+------------------------------------------------------------------+
//| Atualiza os dados do recurso gráfico |
//+------------------------------------------------------------------+
void Update(const string res_name,const uint &pixel_data[],const uint width,const uint height,const bool redraw)
{
//--- se forem passados tamanhos nulos, saímos
if(width==0 || height==0)
return;
//--- atualizamos os dados do recurso e redesenhamos o gráfico
if(ResourceCreate(res_name,pixel_data,width,height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
//+------------------------------------------------------------------+
//| Desenha uma linha vertical |
//+------------------------------------------------------------------+
void LineVertical(int x,int y1,int y2,const uint clr)
{
int tmp;
//--- classificação por Y
if(y1>y2)
{
tmp=y1;
y1 =y2;
y2 =tmp;
}
//--- linha fora dos limites da imagem
if(y2<0 || y1>=ExtResHeight || x<0 || x>=ExtResWidth)
return;
//--- ficamos dentro dos limites da imagem
if(y1<0)
y1=0;
if(y2>=ExtResHeight)
y2=ExtResHeight-1;
//--- traçamos uma linha´
int index=y1*ExtResWidth+x;
for(int i=y1; i<=y2; i++,index+=ExtResWidth)
ExtResData[index]=clr;
}
//+------------------------------------------------------------------+
//| Desenha uma linha horizontal |
//+------------------------------------------------------------------+
void LineHorizontal(int x1,int x2,int y,const uint clr)
{
int tmp;
//--- classificação por X
if(x1>x2)
{
tmp=x1;
x1 =x2;
x2 =tmp;
}
//--- linha fora dos limites da imagem
if(x2<0 || x1>=ExtResWidth || y<0 || y>=ExtResHeight)
return;
//--- ficamos dentro dos limites da imagem
if(x1<0)
x1=0;
if(x2>=ExtResWidth)
x2=ExtResWidth-1;
//--- traçamos uma linha´
ArrayFill(ExtResData,y*ExtResWidth+x1,(x2-x1)+1,clr);
}
|