CryptDecode

int  CryptEncode(
   ENUM_CRYPT_METHOD   method,        // método
   const uchar&        data[],        // array fonte
   const uchar&        key[],         // key
   uchar&              result[]       // array de destino
   );

input string InpKey = "ABCDEFG";  // Encryption key
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string text="The quick brown fox jumps over the lazy dog";
   uchar src[],dst[],key[];
 
//--- preparação da chave de criptografia
   StringToCharArray(InpKey,key);
//--- preparação do array de origem src[]
   StringToCharArray(text,src);
//--- exibição dos dados de entrada
   PrintFormat("Initial data: size=%d, string='%s'",ArraySize(src),CharArrayToString(src));
 
//--- criptografia do array src[] pelo método DES com a chave de 56 bits key[]
   int res=CryptEncode(CRYPT_DES,src,key,dst);
 
//--- verificação do resultado da criptografia
   if(res>0)
     {
      //--- exibição dos dados criptografados
      PrintFormat("Encoded data: size=%d %s",res,ArrayToHex(dst));
      //--- descriptografia dos dados do array dst[] pelo método DES com a chave de 56 bits key[]
      res=CryptDecode(CRYPT_DES,dst,key,src);
      //--- verificação do resultado
      if(res>0)
        {
         //--- exibição dos dados descriptografados
         PrintFormat("Decoded data: size=%d, string='%s'",ArraySize(src),CharArrayToString(src));
        }
      else
         Print("CryptDecode failed. Error: ",GetLastError());
     }
   else
      Print("CryptEncode failed. Error: ",GetLastError());
  }
//+------------------------------------------------------------------+
//| ArrayToHex                                                       |
//+------------------------------------------------------------------+
string ArrayToHex(uchar &arr[],int count=-1)
  {
   string res="";
 
//--- verificação do tamanho
   if(count<0 || count>ArraySize(arr))
      count=ArraySize(arr);
 
//--- conversão para string hexadecimal
   for(int i=0; i<count; i++)
      res+=StringFormat("%.2X",arr[i]);
 
   return(res);
  }