GetTickCount

A função GetTickCount() retorna o número de milissegundos decorridos desde o inicialização do sistema.

uint  GetTickCount();

Valor do Retorno

Valor de tipo uint.

Observação

O contador é limitado pelas restrições do timer do sistema. O tempo é armazenado como um inteiro sem sinal, assim ele é sobre-preenchido a cada 49.7 dias se um computador trabalhar ininterruptamente.

Exemplo:

#define MAX_SIZE 40
//+------------------------------------------------------------------+
//| Script para medir o tempo de computação de 40 membros Fibonacci  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Lembra o valor inicial
   uint start=GetTickCount();
//--- Uma variável para obtenção do próximo número na série Fibonacci
   long fib=0;
//--- No loop calcular a quantidade específica de números de série de Fibonacci
   for(int i=0;i<MAX_SIZE;i++) fib=TestFibo(i);
//--- Obtém o tempo gasto em milissegundos
   uint time=GetTickCount()-start;
//--- Imprime uma mensagem para o diário Experts
   PrintFormat("Calculando %d primeiros números Fibonacci tiveram %d ms",MAX_SIZE,time);
//--- Script concluído
   return;
  }
//+------------------------------------------------------------------+
//| Função para obter número de Fibonacci pelo seu número serial     |
//+------------------------------------------------------------------+
long TestFibo(long n)
  {
//--- O primeiro membro da série Fibonacci
   if(n<2) return(1);
//--- Todos os outros membros são calculados pela seguinte fórmula
   return(TestFibo(n-2)+TestFibo(n-1));
  }

Também Veja

Data e Hora, EventSetMillisecondTimer, GetTickCount64, GetMicrosecondCount