Referência MQL5Funções ComunsPlaySound

PlaySound

Toca um arquivo de som.

bool  PlaySound(
   string  filename      // nome do arquivo
   );

Parâmetros

filename

[in] Caminho para um arquivo de som. Se filename=NULL, a reprodução é interrompida.

Valor do Retorno

true — se o arquivo for encontrado, caso contrário - false.

Observação

O arquivo deve estar localizado em terminal_directory\Sounds ou em sub-diretórios. Somente arquivos WAV são executados.

Chamar o PlaySound() com o parâmetro NULL interrompe a reprodução.

A função PlaySound() não funciona no Testador de Estratégias.

Exemplo:

#include <Trade\Trade.mqh>
#define MAGIC (123)

//--- input parameters
input string          InpFileNameOK  = "ok.wav";               // arquivo de locução de sucesso
input string          InpFileNameErr = "timeout.wav";          // arquivo de mensagem de erro
input ENUM_ORDER_TYPE InpOrderType   = ORDER_TYPE_BUY_LIMIT;   // tipo de ordem
input double          InpLots        = 0.1;                    // lotes

//--- global variables
CTrade ExtTrade;

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- definimos o magic e o tipo de ordem de execução de acordo com as configurações do símbolo
   ExtTrade.SetExpertMagicNumber(MAGIC);
   ExtTrade.SetTypeFillingBySymbol(Symbol());
//--- chamamos a função de configuração da ordem ou abertura de posição com reprodução de som
   OrderSendWithAudio();
  }
//+------------------------------------------------------------------+
//| A função configura a ordem ou abre a posição                     |
//| e reproduz o som de sucesso ou erro                              |
//+------------------------------------------------------------------+
void OrderSendWithAudio(void)
  {
   bool    res=true;
   MqlTick tick= {};

   ResetLastError();
   if(!SymbolInfoTick(Symbol(),tick))
     {
      Print("SymbolInfoTick() failed. Error code: ",GetLastError());
      PlaySound(InpFileNameErr);
      return;
     }
//--- enviamos uma solicitação ao servidor
   switch(InpOrderType)
     {
      case ORDER_TYPE_BUY :
         res=ExtTrade.Buy(InpLots);
         break;
      case ORDER_TYPE_BUY_LIMIT :
         res=ExtTrade.BuyLimit(InpLots,NormalizeDouble(tick.ask-100*Point(),Digits()));
         break;
      case ORDER_TYPE_BUY_STOP :
         res=ExtTrade.BuyStop(InpLots,NormalizeDouble(tick.ask+100*Point(),Digits()));
         break;
      case ORDER_TYPE_SELL :
         res=ExtTrade.Sell(InpLots);
         break;
      case ORDER_TYPE_SELL_LIMIT :
         res=ExtTrade.SellLimit(InpLots,NormalizeDouble(tick.bid+100*Point(),Digits()));
         break;
      case ORDER_TYPE_SELL_STOP :
         res=ExtTrade.SellStop(InpLots,NormalizeDouble(tick.bid-100*Point(),Digits()));
         break;
      default :
         res=false;
     }
   if(!res)
      Print("Error ",GetLastError());
   Print(ExtTrade.ResultRetcodeDescription());

//--- se a solicitação for aceita, reproduzimos o som ok.wav
   if(ExtTrade.ResultRetcode()==TRADE_RETCODE_DONE)
      PlaySound(InpFileNameOK);
   else
      PlaySound(InpFileNameErr);
  }

Também Veja

Recursos

PeriodSeconds