ResourceCreate

bool  ResourceCreate(
   const string      resource_name,       // Nome do recurso
   const string      path                 // Uma caminho relativo para o arquivo
   );

bool  ResourceCreate(
   const string      resource_name,       // Nome do recurso
   const uint&       data[],              // Conjunto de dados em um array
   uint              img_width,           // A largura do recurso de imagem
   uint              img_height,          // A altura do recurso de imagem
   uint              data_xoffset,        // O deslocamento horizontal para direita do canto superior esquerdo da imagem
   uint              data_yoffset,        // O deslocamento vertical para baixo do canto superior esquerdo da imagem
   uint              data_width,          // A largura total da imagem baseada no conjunto de dados
   ENUM_COLOR_FORMAT color_format         // Método de processamento de cor
   );

//+------------------------------------------------------------------+
//| Atualiza os dados do recurso gráfico                             |
//+------------------------------------------------------------------+
void Update(const string res_name,const uint &pixel_data[],const uint width,const uint height,const bool redraw)
  {
//--- Se forem passados tamanhos nulos, saímos
   if(width==0 || height==0)
      return;
//--- Atualizamos os dados do recurso e redesenhamos o gráfico
   if(ResourceCreate(res_name,pixel_data,width,height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
      ChartRedraw();
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- declaramos os parâmetros do recurso gráfico
   string rc_name="Resource";
   uint   rc_width=100;
   uint   rc_height=100;
   uint   rc_data[];
   uint   rc_size=rc_width*rc_height;
 
   ResetLastError();
//--- definimos o tamanho do array de pixels
   if(ArrayResize(rc_data,rc_size)!=rc_size)
     {
      Print("ArrayResize() failed. Error code: ",GetLastError());
      return;
     }
//--- preenchemos o array de pixels com cor transparente e com base nele criamos um recurso gráfico
   ArrayInitialize(rc_data,0x00FFFFFF);
   if(!ResourceCreate(rc_name,rc_data,rc_width,rc_height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
     {
      Print("ResourceCreate() failed. Error code: ",GetLastError());
      return;
     }
   Print("Size of created recource array: ",rc_data.Size());
 
//--- verificamos o recurso gráfico criado
//--- obtemos os dados de tempo e preço da barra atual
   MqlTick tick={};
   if(!SymbolInfoTick(Symbol(),tick))
     {
      Print("SymbolInfoTick() failed. Error code: ",GetLastError());
      return;
     }
//--- criamos um objeto "Desenho" nas coordenadas de preço e tempo do último tick
   string obj_name="Bitmap";
   if(!ObjectCreate(0,obj_name,OBJ_BITMAP,0,tick.time,tick.bid))
     {
      Print("ObjectCreate() failed. Error code: ",GetLastError());
      return;
     }
//--- definimos para o objeto-desenho a largura e a altura iguais às do recurso gráfico.
//--- definimos o ponto de ancoragem do objeto pelo seu centro.
   ObjectSetInteger(0,obj_name,OBJPROP_XSIZE,rc_width);
   ObjectSetInteger(0,obj_name,OBJPROP_YSIZE,rc_height);
   ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- especificamos para o objeto-desenho o arquivo de imagem do recurso gráfico criado anteriormente
//--- Neste caso, para indicar o nome do recurso gráfico usado, deve-se escrever "::" antes de seu nome
   ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"::"+rc_name);
   
//--- definimos a cor DodgerBlue com transparência de 200
   uint clr=ColorToARGB(clrDodgerBlue,200);
//--- preenchemos com a cor definida todo o array de pixels do recurso gráfico
   ArrayInitialize(rc_data,clr);
//--- atualizamos os dados do recurso gráfico
   Update(rc_name,rc_data,rc_width,rc_height,true);
  }