//--- 説明
#property description "Script draws \"Gann Grid\" graphical object."
#property description "Anchor point coordinates of the grid are set in percentage of"
#property description "the chart window size."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string InpName="GannGrid"; // グリッド名
input int InpDate1=15; // 1 番目のポイントの日付( % )
input int InpPrice1=25; // 1 番目のポイントの価格( % )
input int InpDate2=35; // 2 番目のポイントの日付( % )
input double InpScale=3.0; // 規模
input bool InpDirection=false; // トレンドの方向
input color InpColor=clrRed; // グリッドの色
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // グリッド線のスタイル
input int InpWidth=1; // ファンの線の幅
input bool InpBack=false; // 背景のグリッド
input bool InpSelection=true; // 強調表示して移動
input bool InpHidden=true; // オブジェクトリストに隠す
input long InpZOrder=0; // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| ギャングリッドを作成する |
//+------------------------------------------------------------------+
bool GannGridCreate(const long chart_ID=0, // チャート識別子
const string name="GannGrid", // グリッド名
const int sub_window=0, // サブウィンドウ番号
datetime time1=0, // 1 番目のポイントの時間
double price1=0, // 1 番目のポイントの価格
datetime time2=0, // 2 番目のポイントの時間
const double scale=1.0, // 規模
const bool direction=true, // トレンドの方向
const color clr=clrRed, // グリッドの色
const ENUM_LINE_STYLE style=STYLE_SOLID, // グリッド線のスタイル
const int width=1, // グリッド線の幅
const bool back=false, // 背景で表示する
const bool selection=true, // 強調表示して移動
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- 設定されてない場合アンカーポイントの座標を設定する
ChangeGannGridEmptyPoints(time1,price1,time2);
//--- エラー値をリセットする
ResetLastError();
//--- 与えられた座標でギャングリッドを作成する
if(!ObjectCreate(chart_ID,name,OBJ_GANNGRID,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": failed to create \"Gann Grid\"! Error code = ",GetLastError());
return(false);
}
//--- スケール(バーあたりのピップ数)を変更する
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- ギャンファンのトレンド方向を変更する(true - 下降, false - 上行)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- グリッドの色を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- グリッド線の表示スタイルを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- グリッド線の幅を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 前景(false)または背景(true)に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 強調表示してグリッドを移動するモードを有効(true)か無効(false)にする
//--- ObjectCreate 関数を使用してグラフィックオブジェクトを作成する際、オブジェクトは
//--- デフォルトではハイライトされたり動かされたり出来ない。このメソッド内では、選択パラメータは
//--- デフォルトでは true でハイライトと移動を可能にする。
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示(true)か表示(false)にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ギャングリッドのアンカーポイントを移動する |
//+------------------------------------------------------------------+
bool GannGridPointChange(const long chart_ID=0, // チャート識別子
const string name="GannGrid", // グリッド名
const int point_index=0, // アンカーポイントのインデックス
datetime time=0, // アンカーポイントの時間座標
double price=0) // アンカーポイントの価格座標
{
//--- ポイントの位置が設定されていない場合、売値を有する現在足に移動する
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
ResetLastError();
//--- グリッドのアンカーポイントを移動する
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ギャングリッドの規模を変更する |
//+------------------------------------------------------------------+
bool GannGridScaleChange(const long chart_ID=0, // チャート識別子
const string name="GannGrid", // グリッド
const double scale=1.0) // 規模
{
//--- エラー値をリセットする
ResetLastError();
//--- スケール(バーあたりのピップ数)を変更する
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": failed to change the scale! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ギャングリッドのトレンド方向を変更する |
//+------------------------------------------------------------------+
bool GannGridDirectionChange(const long chart_ID=0, // チャート識別子
const string name="GannGrid", // グリッド名
const bool direction=true) // トレンドの方向
{
//--- エラー値をリセットする
ResetLastError();
//--- ギャングリッドのトレンド方向を変更する
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
": failed to change trend direction! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| この関数はチャートからギャンファンを削除する |
//+------------------------------------------------------------------+
bool GannGridDelete(const long chart_ID=0, // チャート識別子
const string name="GannGrid") // グリッド名
{
//--- エラー値をリセットする
ResetLastError();
//--- ギャングリッドを削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete \"Gann Grid\"! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ギャングリッドのアンカーポイントの値をチェックして |
//| 空の物には初期値を設定する |
//+------------------------------------------------------------------+
void ChangeGannGridEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- 2 番目のポイントの時間が設定されていない場合、現在足になる
if(!time2)
time2=TimeCurrent();
//--- 1 番目のポイントの時間が設定されていない場合、2 番目から 9 バー左に置かれる
if(!time1)
{
//--- 最後の 10 バーのオープン時間を受信するための配列
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- 1 番目のポイントを 2 番目から 9 バー左に設定する
time1=temp[0];
}
//--- 1 番目のポイントの価格が設定されていない場合、売値になる
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 入力パラメータの正しさをチェックする
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- チャートウィンドウで表示されているバーの数
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 価格配列サイズ
int accuracy=1000;
//--- アンカーポイントの座標の設定と変更に使用される日付と
//--- 価格の値を格納するための配列
datetime date[];
double price[];
//--- メモリ割り当て
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 日付配列に書き込む
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 価格配列に書き込む
//--- チャートの最高値と最安値を見つける
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 価格の変更ステップを定義し、配列に書き込む
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- ギャングリッド描画のポイントを定義する
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- ギャングリッドを作成する
if(!GannGridCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- チャートを再描画して 1 秒待つ
ChartRedraw();
Sleep(1000);
//--- グリッドのアンカーポイントを移動する
//--- ループカウンタ
int v_steps=accuracy/4;
//--- 1 番目のアンカーポイントを垂直方向に移動する
for(int i=0;i<v_steps;i++)
{
//--- 次の値を使用する
if(p1<accuracy-1)
p1+=1;
if(!GannGridPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
}
//--- 1 秒の遅れ
Sleep(1000);
//--- ループカウンタ
int h_steps=bars/4;
//--- 2 番目のアンカーポイントを水平方向に移動する
for(int i=0;i<h_steps;i++)
{
//--- 次の値を使用する
if(d2<bars-1)
d2+=1;
if(!GannGridPointChange(0,InpName,1,date[d2],0))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//--- 1 秒の遅れ
Sleep(1000);
//--- グリッドのトレンド方向を下降に変更する
GannGridDirectionChange(0,InpName,true);
//--- チャートを再描画する
ChartRedraw();
//--- 1 秒の遅れ
Sleep(1000);
//--- チャートからグリッドを削除する
GannGridDelete(0,InpName);
ChartRedraw();
//--- 1 秒の遅れ
Sleep(1000);
//---
}
|