DocumentaçãoSeções
Referência MQL5Funções de ArquivoFileReadComplexFloat 

FileReadComplexFloat

Lê um número do tipo complexf de um arquivo binário ou CSV a partir da posição atual do ponteiro do arquivo.

complexf FileReadComplexFloat(
   int     file_handle     // Handle do arquivo
   );

Parâmetros

file_handle

[in]  Descritor de arquivo retornado por FileOpen().

Valor do Retorno

Valor do tipo complexf.

Nota

Para obter informações sobre o erro, chame GetLastError().

Lê 8 bytes de um arquivo binário.

Lê de um arquivo CSV uma string da posição atual até o separador (ou até o fim da linha de texto) e converte a string lida em um valor do tipo complexf.

Equivale a chamar a função FileRead com parâmetro do tipo complexf:

complexf complexf_value;
FileRead(file_handle,complexf_value);

 

Exemplo:

//+------------------------------------------------------------------+
//|                                         TestWriteReadComplex.mq5 |
//|                                  Copyright 2026, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Função de início do programa Script                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   complex  complex_value=1.012345+0.0001i;
   complexf complexf_value=complexf(0.00678+0.005i);
//--- escrever em um arquivo CSV
   int  file_handle=FileOpen("complex.csv",FILE_CSV|FILE_WRITE|FILE_ANSI);
   uint written=FileWriteComplexDouble(file_handle,complex_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\t");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\n");
   FileClose(file_handle);
   complex  complex_value2;
   complexf complexf_value2;
//--- ler de um arquivo CSV
   file_handle=FileOpen("complex.csv",FILE_CSV|FILE_READ|FILE_ANSI);
   complex_value2=FileReadComplexDouble(file_handle);
   complexf_value2=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value2=",complex_value2);
   Print("complexf_value2=",complexf_value2);
//--- escrever em um arquivo binário
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_WRITE);
   written=FileWriteComplexDouble(file_handle,complex_value);
   Print("\nwritten ",written," bytes");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileClose(file_handle);
   complex  complex_value3;
   complexf complexf_value3;
//--- ler de um arquivo binário
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_READ);
   complex_value3=FileReadComplexDouble(file_handle);
   complexf_value3=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value3=",complex_value3);
   Print("complexf_value3=",complexf_value3);
  }

Saída no diário Experts

   written 17 bytes
   written 27 bytes
   complex_value2=(1.012345,0.0001)
   complexf_value2=(0.0067799999,0.0049999999)
   
   written 16 bytes
   written 8 bytes
   complex_value3=(1.012345,0.0001)
   complexf_value3=(0.0067799999,0.0049999999)

Também Veja

Número complexo (complex, complexf), FileRead, FileReadFloat, FileWriteComplexFloat