DocumentaçãoSeções
Referência MQL5Funções de ArquivoFileWriteComplexFloat 

FileWriteComplexFloat

Escreve o valor de um parâmetro complexf em um arquivo binário ou CSV a partir da posição atual do ponteiro do arquivo.

uint  FileWriteComplexFloat(
   int       file_handle,     // Handle do arquivo
   complexf  value            // Valores a escrever
   );

Parâmetros

file_handle

[in]  Descritor de arquivo retornado por FileOpen().

value

[in]  Valor do tipo complexf.

Valor do Retorno

Em caso de sucesso, a função retorna o número de bytes escritos. O ponteiro do arquivo é deslocado pelo mesmo número de bytes.

Nota

Para obter informações sobre o erro, chame GetLastError().

Em um arquivo binário são gravados 8 bytes.

Em um arquivo de texto ou CSV é gravada a representação textual do número complexo.

Exemplo:

//+------------------------------------------------------------------+
//|                                         TestWriteReadComplex.mq5 |
//|                                  Copyright 2026, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Função de início do programa script                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   complex  complex_value=1.012345+0.0001i;
   complexf complexf_value=complexf(0.00678+0.005i);
//--- escrever em um arquivo CSV
   int  file_handle=FileOpen("complex.csv",FILE_CSV|FILE_WRITE|FILE_ANSI);
   uint written=FileWriteComplexDouble(file_handle,complex_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\t");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\n");
   FileClose(file_handle);
   complex  complex_value2;
   complexf complexf_value2;
//--- ler de um arquivo CSV
   file_handle=FileOpen("complex.csv",FILE_CSV|FILE_READ|FILE_ANSI);
   complex_value2=FileReadComplexDouble(file_handle);
   complexf_value2=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value2=",complex_value2);
   Print("complexf_value2=",complexf_value2);
//--- escrever em um arquivo binário
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_WRITE);
   written=FileWriteComplexDouble(file_handle,complex_value);
   Print("\nwritten ",written," bytes");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileClose(file_handle);
   complex  complex_value3;
   complexf complexf_value3;
//--- ler de um arquivo binário
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_READ);
   complex_value3=FileReadComplexDouble(file_handle);
   complexf_value3=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value3=",complex_value3);
   Print("complexf_value3=",complexf_value3);
  }

Saída no diário Experts

   written 17 bytes
   written 27 bytes
   complex_value2=(1.012345,0.0001)
   complexf_value2=(0.0067799999,0.0049999999)
   
   written 16 bytes
   written 8 bytes
   complex_value3=(1.012345,0.0001)
   complexf_value3=(0.0067799999,0.0049999999)

 

Também Veja

Número complexo (complex, complexf), Tipos reais (double, float), FileWriteFloat, FileWriteComplexDouble