CryptDecode

int  CryptDecode(
   ENUM_CRYPT_METHOD   method,        // Umwandlungsmethode
   const uchar&        data[],        // Quell-Array
   const uchar&        key[],         // Schlüssel
   uchar&              result[]       // Empfänger-Array
   );

input string InpKey = "ABCDEFG";  // Encryptions-Schlüssel
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
   string text="The quick brown fox jumps over the lazy dog";
   uchar src[],dst[],key[];
 
//--- Vorbereitung des Verschlüsselungsschlüssels
   StringToCharArray(InpKey,key);
//--- Vorbereitung des Quellarrays src[]
   StringToCharArray(text,src);
//--- Darstellung der Quelldaten
   PrintFormat("Initial data: size=%d, string='%s'",ArraySize(src),CharArrayToString(src));
 
//--- Verschlüsselung des Arrays src[] mit der DES-Methode und dem 56-Bit-Schlüssel key[]
   int res=CryptEncode(CRYPT_DES,src,key,dst);
 
//--- Prüfung des Verschlüsselungsergebnisses
   if(res>0)
     {
      //--- Darstellung der verschlüsselten Daten
      PrintFormat("Encoded data: size=%d %s",res,ArrayToHex(dst));
      //--- Entschlüsselung des Datenarrays dst[] mit der DES-Methode und dem 56-Bit-Schlüssel key[]
      res=CryptDecode(CRYPT_DES,dst,key,src);
      //--- Ergebnisprüfung
      if(res>0)
        {
         //--- Darstellung der entschlüsselten Daten
         PrintFormat("Decoded data: size=%d, string='%s'",ArraySize(src),CharArrayToString(src));
        }
      else
         Print("CryptDecode failed. Error: ",GetLastError());
     }
   else
      Print("CryptEncode failed. Error: ",GetLastError());
  }
//+------------------------------------------------------------------+
//| ArrayToHex                                                       |
//+------------------------------------------------------------------+
string ArrayToHex(uchar &arr[],int count=-1)
  {
   string res="";
 
//--- Feststellen der Größe
   if(count<0 || count>ArraySize(arr))
      count=ArraySize(arr);
 
//--- in hexadezimale Zeichenfolge umwandeln
   for(int i=0; i<count; i++)
      res+=StringFormat("%.2X",arr[i]);
 
   return(res);
  }