ドキュメントセクション
MQL5 リファレンスファイル関数FileFlush 

FileFlush

入力/出力ファイルのバッファに残っている全てのデータをディスクに書き込みます。

void  FileFlush(
  int  file_handle      // ファイルハンドル
  );

パラメータ

file_handle

[in] FileOpen() から戻されたファイル記述子

戻り値

なし

注意事項

ファイルに書き込んだデータは実際にはすぐには見つからないかもしれません。即座にファイルにデータを保存するには FileFlush() 関数を使用します。この関数を使用しない場合、まだディスクに格納されていないデータは FileClose() 関数でファイルが閉じられた時のみに強制的に書き込まれます。

書き込まれたデータが特定の値である時にこの関数を使用する必要があります。この関数の頻繁な呼び出しは、プログラムの動作速度に影響を与える可能性があることに留意すべきです。

FileFlush () 関数はファイルからの読み込みと書き込み操作の間に呼び出される必要があります。

例:

//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- 書き込みするファイル名
input string InpFileName="example.csv"; // ファイル名
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
//--- エラー値をリセットする
  ResetLastError();
//--- ファイルを開く
  int file_handle=FileOpen(InpFileName,FILE_READ|FILE_WRITE|FILE_CSV);
  if(file_handle!=INVALID_HANDLE)
    {
    //--- データをファイルに書く
    for(int i=0;i<1000;i++)
       {
        //--- write 関数を呼び出す
        FileWrite(file_handle,TimeCurrent(),SymbolInfoDouble(Symbol(),SYMBOL_BID),SymbolInfoDouble(Symbol(),SYMBOL_ASK));
        //--- 各128番目の繰り返しでディスク上のデータを保存する
        if((i & 127)==127)
          {
          //--- データはファイルに配置され、重大なエラーの場合に失われることはない
          FileFlush(file_handle);
          PrintFormat("i = %d, OK",i);
          }
        //--- 0.01 秒の休止
        Sleep(10);
       }
    //--- ファイルを閉じる
    FileClose(file_handle);
    }
  else
    PrintFormat("Error, code = %d",GetLastError());
 }

参照

FileClose