FileWriteInteger

この関数は、ファイルポインタの現在位置から開始して、バイナリファイルに int パラメータの値を書き込みます。

uint  FileWriteInteger(
  int  file_handle,        // ファイルハンドル
  int  value,              // 書かれる値
  int  size=INT_VALUE      // バイト単位でのサイズ
  );

パラメータ

file_handle

[in] FileOpen() から戻されたファイル記述子

value

[in] 整数値

size=INT_VALUE

[in] 書かれるバイト数(4以下)。関数が char、short または int 型の値を書けるように、CHAR_VALUE=1、SHORT_VALUE=2 t及び INT_VALUE=4 と対応する定数が用意されています。

戻り値

成功の場合、書かれたバイト数。ファイルポインタは、書かれたバイト数によって動きます。

例:

//+------------------------------------------------------------------+
//|                                        Demo_FileWriteInteger.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- 端末からデータを受け取るパラメータ
input string             InpSymbolName="EURUSD";           // 通貨ペア
input ENUM_TIMEFRAMES   InpSymbolPeriod=PERIOD_H1;       // 時間軸
input datetime           InpDateStart=D'2013.01.01 00:00'; // データコピー開始日
//--- データをファイルに書くパラメータ
input string             InpFileName="Trend.bin"; // ファイル名
input string             InpDirectoryName="Data"; // ディレクトリ名
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  datetime date_finish=TimeCurrent();
  double   close_buff[];
  datetime time_buff[];
  int      size;
//--- エラー値をリセットする
  ResetLastError();
//--- バーに終値を複製する
  if(CopyClose(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,close_buff)==-1)
    {
    PrintFormat("Failed to copy the values of close prices. Error code = %d",GetLastError());
    return;
    }
//--- バーに時間を複製する
  if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
    {
    PrintFormat("Failed to copy time values. Error code = %d",GetLastError());
    return;
    }
//--- バッファサイズを受け取る
  size=ArraySize(close_buff);
//--- 値を書き込むためにファイルを開く(ファイルが存在しない場合は自動的に作成される)
  ResetLastError();
  int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
  if(file_handle!=INVALID_HANDLE)
    {
    PrintFormat("%s file is available for writing",InpFileName);
    PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
    //---
    int   up_down=0; // トレンドフラグ
    int   arr_size; // arr 配列サイズ
    uchar arr[];     // uchar 型の配列
    //--- 時間値をファイルに書く
    for(int i=0;i<size-1;i++)
       {
        //--- 現在と次のバーの終値を比べる
        if(close_buff[i]<=close_buff[i+1])
          {
          if(up_down!=1)
             {
              //--- FileWriteInteger を使用してデータ値をファイルに書く
              StringToCharArray(TimeToString(time_buff[i]),arr);
              arr_size=ArraySize(arr);
              //--- 初めにシンボル数を配列に書く
              FileWriteInteger(file_handle,arr_size,INT_VALUE);
              //--- シンボルを書く
              for(int j=0;j<arr_size;j++)
                FileWriteInteger(file_handle,arr[j],CHAR_VALUE);
              //--- トレンドフラグを変更する
              up_down=1;
             }
          }
        else
          {
          if(up_down!=-1)
             {
              //--- FileWriteInteger を使用してデータ値をファイルに書く
              StringToCharArray(TimeToString(time_buff[i]),arr);
              arr_size=ArraySize(arr);
              //--- 初めにシンボル数を配列に書く
              FileWriteInteger(file_handle,arr_size,INT_VALUE);
              //--- シンボルを書く
              for(int j=0;j<arr_size;j++)
                FileWriteInteger(file_handle,arr[j],CHAR_VALUE);
              //--- トレンドフラグを変更する
              up_down=-1;
             }
          }
       }
    //--- ファイルを閉じる
    FileClose(file_handle);
    PrintFormat("Data is written, %s file is closed",InpFileName);
    }
  else
    PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
 }

参照

IntegerToStringStringToInteger整数型