FileFindClose

この関数は検索ハンドルを閉じます。

void  FileFindClose(
  long  search_handle      //  検索ハンドル
  );

パラメータ

search_handle

[in]   FileFindFirst()  で取得される検索ハンドル

戻り値

なし

注意事項

この関数は、システムリソースを解放するために呼び出されなければなりません。

例:

//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- フィルタ
input string InpFilter="*";
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  string file_name;
  int    i=1;
//--- ローカルフォルダのルートで検索ハンドルを受け取る
  long search_handle=FileFindFirst(InpFilter,file_name);
//--- FileFindFirst() の実行が成功したかをチェックする
  if(search_handle!=INVALID_HANDLE)
    {
    //--- 渡された文字列がファイル名かディレクトリ名かをループでチェックする
    do
       {
        ResetLastError();
        //--- ファイルであれば trueを返し、ディレクトリであればエラーを生成する
        FileIsExist(file_name);
        PrintFormat("%d : %s name = %s",i,GetLastError()==5018 ? "Directory" : "File",file_name);
        i++;
       }
    while(FileFindNext(search_handle,file_name));
    //--- 検索ハンドルを閉じる
    FileFindClose(search_handle);
    }
  else
    Print("Files not found!");
 }

参照

FileFindFirstFileFindNext