FileIsExist

ファイルの存在をチェックします。

bool  FileIsExist(
  const string  file_name,      // ファイル名
  int          common_flag=0    // 検索の場所
  );

パラメータ

file_name

[in]  チェックされているファイルの名称

common_flag=0

[in]  ファイルの場所を決めるフラグ。common_flag = FILE_COMMON の場合、ファイルは全てのクライアント端末の共有フォルダ \Terminal\Common\Files 内に存在します。その他の場合、ファイルはローカルフォルダに存在します。

戻り値

指定されたファイルが存在する場合は true

注意事項

チェックされたファイルはサブディレクトリである可能性があります。この場合 FileIsExist() 関数は false を戻し error 5018 - This is a directory, not a file(これはディレクトリでファイルではありません)が _LastError 変数にログされます。(FileFindFirst 関数の例を参照)。

セキュリティ上の理由から、MQL5 言語ではファイルの扱いは厳しく制御されています。MQL5 手段を用いて操作されるファイルは、ファイルサンドボックスの外に存在することは出来ません。

common_flag = FILE_COMMON の場合、この関数はファイルを全てのクライアント端末の共有フォルダ \Terminal\Common\Files で探します。他の場合、ローカルフォルダ(MQL5\Files またはテストの際には MQL5\Tester\Files)が探されます。

例:

//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- 古いファイルの日付
input datetime InpFilesDate=D'2013.01.01 00:00';
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  string   file_name;     // ファイル名を格納する変数
  string   filter="*.txt"; // ファイル検索フィルタ
  datetime create_date;   // ファイル作成日
  string   files[];       // ファイル名のリスト
  int      def_size=25;   // デフォルトの配列サイズ
  int      size=0;         // ファイル数
//--- 配列へのメモリ追加
  ArrayResize(files,def_size);
//--- ローカルフォルダのルートで検索ハンドルを受け取る
  long search_handle=FileFindFirst(filter,file_name);
//--- FileFindFirst() の実行が成功したかをチェックする
  if(search_handle!=INVALID_HANDLE)
    {
    //--- ループでファイルを検索する
    do
       {
        files[size]=file_name;
        //--- 配列サイズを増やす
        size++;
        if(size==def_size)
          {
           def_size+=25;
          ArrayResize(files,def_size);
          }
        //--- エラー値をリセットする
        ResetLastError();
        //--- 作成日を受け取る
        create_date=(datetime)FileGetInteger(file_name,FILE_CREATE_DATE,false);
        //--- ファイルが古いかをチェックする
        if(create_date<InpFilesDate)
          {
          PrintFormat("%s file deleted!",file_name);
          //--- 古いファイルを削除する
          FileDelete(file_name);
          }
       }
    while(FileFindNext(search_handle,file_name));
    //--- 検索ハンドルを閉じる
    FileFindClose(search_handle);
    }
  else
    {
    Print("Files not found!");
    return;
    }
//--- 何のファイルが残っているかをチェックする
  PrintFormat("Results:");
  for(int i=0;i<size;i++)
    {
    if(FileIsExist(files[i]))
        PrintFormat("%s file exists!",files[i]);
    else
        PrintFormat("%s file deleted!",files[i]);
    }
 }

参照

FileFindFirst