FileReadLong

この関数は、バイナリファイルのファイルポインタの現在位置から long 型( 8 バイト)の値を読み込みます。

long  FileReadLong(
  int  file_handle    // ファイルハンドル
  );

パラメータ

file_handle

[in] FileOpen() から戻されたファイル記述子

戻り値

long 型の値

FileWriteLong 関数の例の実行によって取得されたファイルが使用されます)

//+------------------------------------------------------------------+
//|                                            Demo_FileReadLong.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
#property indicator_buffers 1
#property indicator_plots   1
//---- Label1 をプロットする
#property indicator_label1 "Volume"
#property indicator_type1   DRAW_LINE
#property indicator_color1 clrYellow
#property indicator_style1 STYLE_SOLID
#property indicator_width1  2
#property indicator_separate_window
//--- データ読み込みのパラメータ
input string InpFileName="Volume.bin"; // ファイル名
input string InpDirectoryName="Data"; // ディレクトリ名
//--- グローバル変数
int      ind=0;
int      size=0;
long     volume_buff[];
datetime time_buff[];
//--- 指標バッファ
double   buff[];
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- ファイルを開く
  ResetLastError();
  int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_BIN);
  if(file_handle!=INVALID_HANDLE)
    {
    PrintFormat("%s file is open for writing",InpFileName);
    PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
    //--- 初めに、ファイルのデータ量を読み込む
     size=(int)FileReadLong(file_handle);
    //--- 配列へメモリを割り当てる
    ArrayResize(volume_buff,size);
    ArrayResize(time_buff,size);
    //--- ファイルからデータを読む
    for(int i=0;i<size;i++)
       {
        time_buff[i]=(datetime)FileReadLong(file_handle);
        volume_buff[i]=FileReadLong(file_handle);
       }
    //--- ファイルを閉じる
    FileClose(file_handle);
    PrintFormat("Data is read, %s file is closed",InpFileName);
    }
  else
    {
    PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
    return(INIT_FAILED);
    }
//--- 配列をインデックス0で指標バッファと結合するx
  SetIndexBuffer(0,buff,INDICATOR_DATA);
//---- チャートで表示される指標値を設定する
  PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
  ArraySetAsSeries(time,false);
//--- まだ処理されてないバーのループ
  for(int i=prev_calculated;i<rates_total;i++)
    {
    //--- デフォルトでは 0
     buff[i]=0;
    //--- まだデータがあるかをチェック
    if(ind<size)
       {
        for(int j=ind;j<size;j++)
          {
          //--- 日付が同じならファイルの値を使用する
          if(time[i]==time_buff[j])
             {
              buff[i]=(double)volume_buff[j];
              ind=j+1;
              break;
             }
          }
       }
    }
//--- 次の呼び出しのために prev_calculated の値を返す
  return(rates_total);
 }

参照

整数型FileReadIntegerFileWriteLong