FileWriteString

この関数は、BIN、CSV または TXT ファイルのファイルポインタの現在位置に string 型のパラメータの値を書き込みます。CSV や TXT ファイルに書き込む場合、文字列が、事前に 「\r」 (CR) がない 「\n」 (LF) を含む場合, 「\n」の前に「\r」が加えられます。

uint  FileWriteString(
  int          file_handle,    // ファイルハンドル
  const string  text_string,   // 書かれる文字列
  int          length=-1      // シンボル数
  );

パラメータ

file_handle

[in] FileOpen() から戻されたファイル記述子

text_string

[in]  文字列

length=-1

[in] 書かれる文字数。このオプションはBINファイルに文字列を書き込むために必要です。サイズが指定されていない場合には、トレーラー 0 を含まない文字列全体が書かれます。文字列の長さよりも小さいサイズが指定された場合は、その部分がトレーラー 0 を含まずに書かれます。文字列の長さよりも大きいサイズが指定された場合は、適切な数のゼロが書き足されます。CSV 及び TXT 形式のファイルではこのパラメータは無視され、文字列全体が書かれます。

戻り値

成功の場合、書かれたバイト数。ファイルポインタは、書かれたバイト数によって動きます。

注意事項

FILE_UNICODE フラグ を使用して、もしくは FILE_ANSI フラグなしで開かれたファイルに書き込む場合、書かれたバイト数は書かれた文字数の 2 倍になることにご注意下さい。FILE_ANSI フラグを使用して開かれたファイルに書き込む場合書かれたバイト数は書かれた文字数と同じです。

例:

//+------------------------------------------------------------------+
//|                                         Demo_FileWriteString.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- 端末からデータを受け取るパラメータ
input string             InpSymbolName="EURUSD";           // 通貨ペア
input ENUM_TIMEFRAMES   InpSymbolPeriod=PERIOD_H1;       // 時間軸
input int               InpMAPeriod=14;                   // MA 期間
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE;     // 価格の種類
input datetime           InpDateStart=D'2013.01.01 00:00'; // データコピー開始日
//--- データをファイルに書くパラメータ
input string             InpFileName="RSI.csv";   // ファイル名
input string             InpDirectoryName="Data"; // ディレクトリ名
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  datetime date_finish; // データコピー終了日
  double   rsi_buff[]; // 指標値の配列
  datetime date_buff[]; // 指標日付の配列
  int      rsi_size=0; // 指標配列のサイズ
//--- 終了時刻が現在の時刻
  date_finish=TimeCurrent();
//--- RSI 指標ハンドルを受け取る
  ResetLastError();
  int rsi_handle=iRSI(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpAppliedPrice);
  if(rsi_handle==INVALID_HANDLE)
    {
    //--- 指標ハンドルの受け取りに失敗
    PrintFormat("Error when receiving indicator handle. Error code = %d",GetLastError());
    return;
    }
//--- 指標が全ての値を計算するまでループ内にとどまる
  while(BarsCalculated(rsi_handle)==-1)
    Sleep(10); // 指標が全ての値を計算出来るように一時停止
//--- 一定期間の指標値を複製する
  ResetLastError();
  if(CopyBuffer(rsi_handle,0,InpDateStart,date_finish,rsi_buff)==-1)
    {
    PrintFormat("Failed to copy indicator values. Error code = %d",GetLastError());
    return;
    }
//--- 指標値に適切な時間を複製する
  ResetLastError();
  if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
    {
    PrintFormat("Failed to copy time values. Error code = %d",GetLastError());
    return;
    }
//--- 指標で使用されたメモリを解放する
  IndicatorRelease(rsi_handle);
//--- バッファサイズを受け取る
  rsi_size=ArraySize(rsi_buff);
//--- 指標値を書き込むためにファイルを開く(ファイルが存在しない場合は自動的に作成される)
  ResetLastError();
  int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV|FILE_ANSI);
  if(file_handle!=INVALID_HANDLE)
    {
    PrintFormat("%s file is available for writing",InpFileName);
    PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
    //--- 追加の変数を準備する
    string str="";
    bool   is_formed=false;
    //--- 買われ過ぎと売られ過ぎ領域を作る日付を書く
    for(int i=0;i<rsi_size;i++)
       {
        //--- 指標値をチェックする
        if(rsi_buff[i]>=70 || rsi_buff[i]<=30)
          {
          //--- これが領域の初めの値の場合
          if(!is_formed)
             {
              //--- 値と日付を加える
              str=(string)rsi_buff[i]+"\t"+(string)date_buff[i];
              is_formed=true;
             }
          else
              str+="\t"+(string)rsi_buff[i]+"\t"+(string)date_buff[i];
          //--- 次のループ反復に移る
          continue;
          }
        //--- フラグをチェックする
        if(is_formed)
          {
          //--- 文字列が用意できたのでファイルに書く
          FileWriteString(file_handle,str+"\r\n");
           is_formed=false;
          }
       }
    //--- ファイルを閉じる
    FileClose(file_handle);
    PrintFormat("Data is written, %s file is closed",InpFileName);
    }
  else
    PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
 }

参照

String Type, StringFormat