FileWriteLong

この関数は、ファイルポインタの現在位置から開始して、バイナリファイルに long 型のパラメータの値を書き込みます。

uint  FileWriteLong(
  int  file_handle,    // ファイルハンドル
  long  value            // 書かれる値
  );

パラメータ

file_handle

[in] FileOpen() から戻されたファイル記述子

value

[in] long 型の値

戻り値

成功の場合、書かれたバイト数(sizeof(long)=8)。ファイルポインタは、書かれたバイト数によって動きます。

例:

//+------------------------------------------------------------------+
//|                                           Demo_FileWriteLong.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- 端末からデータを受け取るパラメータ
input string         InpSymbolName="EURUSD";           // 通貨ペア
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_H1;       // 時間軸
input datetime       InpDateStart=D'2013.01.01 00:00'; // データコピー開始日
//--- データをファイルに書くパラメータ
input string         InpFileName="Volume.bin"; // ファイル名
input string         InpDirectoryName="Data"; // ディレクトリ名
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  datetime date_finish=TimeCurrent();
  long     volume_buff[];
  datetime time_buff[];
  int      size;
//--- エラー値をリセットする
  ResetLastError();
//--- バーにティックボリュームを複製する
  if(CopyTickVolume(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,volume_buff)==-1)
    {
    PrintFormat("Failed to copy values of the tick volume. Error code = %d",GetLastError());
    return;
    }
//--- バーに時間を複製する
  if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
    {
    PrintFormat("Failed to copy time values. Error code = %d",GetLastError());
    return;
    }
//--- バッファサイズを受け取る
  size=ArraySize(volume_buff);
//--- 指標値を書き込むためにファイルを開く(ファイルが存在しない場合は自動的に作成される)
  ResetLastError();
  int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
  if(file_handle!=INVALID_HANDLE)
    {
    PrintFormat("%s file is available for writing",InpFileName);
    PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
    //--- 初めにデータサンプルサイズを書く
    FileWriteLong(file_handle,(long)size);
    //--- 時間とボリューム値をファイルに書く
    for(int i=0;i<size;i++)
       {
        FileWriteLong(file_handle,(long)time_buff[i]);
        FileWriteLong(file_handle,volume_buff[i]);
       }
    //--- ファイルを閉じる
    FileClose(file_handle);
    PrintFormat("Data is written, %s file is closed",InpFileName);
    }
  else
    PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
 }

参照

整数型FileWriteInteger