//+------------------------------------------------------------------+
//| Demo_FileWriteDouble.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
//--- mostramos la ventana de parámetros de entrada al iniciar el script
#property script_show_inputs
//--- parámetros para obtener datos desde el terminal
input string InpSymbolName="EURJPY"; // par de divisas
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_M15; // período de tiempo
input int InpMAPeriod=10; // período de suavizado
input int InpMAShift=0; // desplazamiento del indicador
input ENUM_MA_METHOD InpMAMethod=MODE_SMA; // tipo de suavizado
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE; // tipo del precio
input datetime InpDateStart=D'2013.01.01 00:00'; // fecha de inicio del copiado de datos
//--- parámetros para la escritura de datos en el archivo
input string InpFileName="MA.csv"; // nombre del archivo
input string InpDirectoryName="Data"; // nombre de la carpeta
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date_finish=TimeCurrent();
double ma_buff[];
datetime time_buff[];
int size;
//--- obtenemos el indicador del manejador MA
ResetLastError();
int ma_handle=iMA(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpMAShift,InpMAMethod,InpAppliedPrice);
if(ma_handle==INVALID_HANDLE)
{
//--- fallo al obtener el manejador del indicador
PrintFormat("Fallo al obtener el manejador del indicador. Código del error = %d",GetLastError());
return;
}
//--- seguimos en el ciclo hasta que el indicador no termine de calcular todos sus valores
while(BarsCalculated(ma_handle)==-1)
Sleep(20); // retardo para que al indicador le de tiempo a calcular sus valores
PrintFormat("En el archivo serán escritos los valores del indicador a partir del %s",TimeToString(InpDateStart));
//--- copiamos los valpres del indicador
ResetLastError();
if(CopyBuffer(ma_handle,0,InpDateStart,date_finish,ma_buff)==-1)
{
PrintFormat("Fallo al copiar los valores del indicador. Código del error = %d",GetLastError());
return;
}
//--- copiamos el tiempo de aparición de barras correspondientes
ResetLastError();
if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
{
PrintFormat("Fallo al copiar los valores del tiempo. Código del error = %d",GetLastError());
return;
}
//--- obtenemos el tamaño del búfer
size=ArraySize(ma_buff);
//--- liberamos la memoria que ocupa el indicador
IndicatorRelease(ma_handle);
//--- abrimos el archivo para escribir los valores del indicador (si no existe, se crea automáticamente)
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("El archivo %s está abierto para la escritura",InpFileName);
PrintFormat("Ruta del archivo: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- primero escribimos el tamaño de la muestra de datos
FileWriteDouble(file_handle,(double)size);
//--- escribimos en el archivo el tiempo y los valores del indicador
for(int i=0;i<size;i++)
{
FileWriteDouble(file_handle,(double)time_buff[i]);
FileWriteDouble(file_handle,ma_buff[i]);
}
//--- cerramos el archivo
FileClose(file_handle);
PrintFormat("Datos grabados, el archivo %s cerrado",InpFileName);
}
else
PrintFormat("Fallo al abrir el archivo %s, Código del error = %d",InpFileName,GetLastError());
}
|